read_submit.f

Go to the documentation of this file.

!                   **********************
                    SUBROUTINE read_submit
!                   **********************
!
     &(files,nfiles,submit,nmot)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    READS THE FILES CHARACTERISTICS DECLARED IN THE STEERING FILE
!         AND STORES THEM IN BIEF_FILE STRUCTURE CALLED FILES
!
!note     THE STEERING AND DICTIONNARY FILES ARE OPENED AND
!+         CLOSED IN LECDON.
!
!history  J-M HERVOUET (LNHE)
!+        27/03/2009
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FILES          |<--| FILES STRUCTURES
!| NFILES         |-->| NUMBER OF FILES IN ARRAY FILES
!| NMOT           |-->| SECOND DIMENSION OF SUBMIT AND MOTCAR
!| SUBMIT         |-->| CHARACTER STRINGS STEMMING FROM DICTIONARY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_read_submit => read_submit
      USE declarations_telemac
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER           , INTENT(IN) :: NFILES,NMOT
      TYPE(bief_file), INTENT(INOUT) :: FILES(nfiles)
      CHARACTER(LEN=PATH_LEN), INTENT(IN) :: SUBMIT(4,nmot)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,ICOL,I1,CANAL
!
      CHARACTER(LEN=9) :: LITECR
!
      INTEGER  PREVAL,INTLU
      EXTERNAL preval,intlu
!
!-----------------------------------------------------------------------
!
      DO i=1,nfiles
        files(i)%LU=0
        files(i)%TELNAME=repeat(' ', 6)
        files(i)%NAME(1:path_len)= repeat(' ', path_len)
      ENDDO
      canal = 0
!
!-----------------------------------------------------------------------
!
!     DECODES THE SUBMIT STRING FOR THE FILES DECLARED IN THE
!     STEERING FILE
!
      DO i=1,nmot
!
! EXAMPLE SUBMIT STRING : 'NGEO-READ;T2DGEO;OBLIG;BIN;LIT;SELAFIN-GEOM'
!
        IF(     submit(4,i).NE.' '
     &     .AND.submit(4,i)(1:7).NE.'INUTILE'  ) THEN
!         SCANS FOR CHANNEL FORTRAN NAME (FOR EXAMPLE NGEO)
          icol=preval(1,submit(4,i),'-','-','-')
!         SCANS FOR THE READ OR WRITE OR READWRITE STRING
!         LOCATED BEFORE THE NEXT - SIGN
          i1=icol+1
          icol=preval(i1,submit(4,i),';',';',';')
          litecr=submit(4,i)(i1:icol-1)
!         READS THE CHANNEL AFTER THE - SIGN
          canal = canal + 1
          IF(canal.GT.nfiles) THEN
            WRITE(lu,*) 'READ_SUBMIT: NFILES TOO SMALL : ',nfiles
            WRITE(lu,*) '             IT SHOULD BE AT LEAST ',canal
            CALL plante(1)
            stop
          ENDIF
          files(canal)%LU=canal
          files(canal)%ACTION=litecr
!
!         READS THE NAME OF THE FILE TO BE COPIED TO THE TMP FOLDER
          i1=preval(icol+1,submit(4,i),';',';',';')
          files(canal)%TELNAME=submit(4,i)(icol+1:i1-1)
!         SKIPS ;FACUL; OR ;OBLIG;
          icol=preval(i1+1,submit(4,i),';',';',';')
!         BINARY OR ASCII
          files(canal)%BINASC=submit(4,i)(icol+1:icol+3)
!         NOTE : SUBMIT(4,I)(ICOL+5:ICOL+7) CONTAINS LIT OU ECR
!                NOT USED HERE
!         MODE SELAFIN-GEOM, PARAL, SCAL, ETC.
          files(canal)%TYPE=
     &       trim(submit(4,i)(icol+9:min(path_len,icol+20)))
!
        ENDIF
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END