read_partel_info.f

Go to the documentation of this file.

!                   ***************************
                    SUBROUTINE read_partel_info
!                   ***************************
!
     &(code,nptfr,numliq,boundary_colour,mesh)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    READS IFAPAR AND NACHB
!
!history  Y AUDOUIN (LNHE)
!+        25/05/2015
!+        V7P0
!+   First version.
!
!history  J. GRASSET (Daresbury Lab & EDF)
!+        01/05/2018
!+        Add code for managing concatenated PAR file
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CODE           |-->| 3 LETTER NAME OF THE CODE
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| NUMLIQ         |<->| NUMBER OF LIQUID BOUNDARY
!| BOUNDARY_COLOUR|<->| COLOUR OF BOUNDARY POINTS
!| MESH           |<->| MESH STRUCTURE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=3),   INTENT(IN)    :: CODE
      INTEGER,            INTENT(IN)    :: NPTFR
      INTEGER,            INTENT(INOUT) :: NUMLIQ(nptfr)
      INTEGER,            INTENT(INOUT) :: BOUNDARY_COLOUR(nptfr)
      TYPE(bief_mesh),    INTENT(INOUT) :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER PTIR,I,K,IF1,IF2,IF3,IF4,IF5,IF6,IF7
      INTEGER NPTFR_BND
      INTEGER NPAR, NPAR_IDX
      INTEGER OFFSET_BEGIN
      CHARACTER(LEN=PATH_LEN) NAMEPAR
      CHARACTER(LEN=PATH_LEN) NAMEPAR_IDX
      CHARACTER(LEN=11) EXTENS
      EXTERNAL extens
!
!-----------------------------------------------------------------------
!
!  PARALLEL MODE : READS NPTIR AND NACHB
!
!-----------------------------------------------------------------------
!
      IF(partel_concat)THEN
        namepar = code//'PAR'//'-CONCAT'
        namepar_idx = code//'PAR'//'-INDEX'
      ELSE
        namepar = code//'PAR'//extens(ncsize-1,ipid)
      ENDIF
!     Look for an available unit
      CALL get_free_id(npar)
      OPEN(npar,file=namepar,status='OLD',form='FORMATTED')
      rewind(npar)
      IF(partel_concat)THEN
        CALL get_free_id(npar_idx)
        OPEN(npar_idx,file=namepar_idx,action='READ')
        !GET OUT OFFSET FROM THE INDEX FILE
        READ(npar_idx,*)(offset_begin,k=0,ipid)
        CLOSE(npar_idx)
        !MOVE TO THE BEGINING OF OUR PART
        DO k=1,offset_begin-1
          READ(npar,*)
        ENDDO
      ENDIF
!
      READ(npar,*) nptfr_bnd
      IF(nptfr.NE.nptfr_bnd) THEN
        WRITE(lu,24) nptfr_bnd,nptfr
24      FORMAT(1x,'READ_PARTEL_INFO: ERROR IN THE PARALLEL FILE,',
     &       /,9x,1i5,' LINES INSTEAD OF ',i5,' REQUESTED')
        CALL plante(1)
        stop
      ENDIF
      DO k=1,nptfr_bnd
        READ(npar,*) boundary_colour(k),mesh%NBOR%I(k),mesh%ISEG%I(k),
     &               mesh%XSEG%R(k),mesh%YSEG%R(k),numliq(k)
      ENDDO
!
      READ(npar,*) ptir
      IF(nptir.NE.ptir) THEN
        WRITE(lu,152) nptir,ptir
152     FORMAT(1x,'READ_PARTEL_INFO : DIFFERENCE BETWEEN GEOMETRY ',/,
     &         1x,'         AND BOUNDARY CONDITIONS'   ,/,1x,i6,
     &  ' INTERFACE POINTS IN GEOMETRY',/,1x,i6,
     &  ' INTERFACE POINTS IN CONPAR FILE')
      ENDIF
!     NACHB(NBMAXNSHARE,NPTIR), HERE NACHB(I,K)
!     HERE NACHB IS IN LOCAL NUMBERING
      IF(nptir.GT.0) THEN
        DO k=1,nptir
          READ(npar,*) (mesh%NACHB%I((k-1)*nbmaxnshare+i),
     &                          i=1,nbmaxnshare)
        ENDDO
      ENDIF
!
!     JAJ //// READS THE NEIGHBOURHOODS FOR HALO CELLS ALONG THE INTERFACES
!     FILLING PATTERN: IFAPAR(1:7,K), K=1:NHALO
!                      -> NHALO: NUMBER OF HALO CELLS IN THIS PARTITION
!
!     IFAPAR(1,K)   : HALO ELEMENT -LOCAL- NUMBER IN THIS PARTITION
!     IFAPAR(2:4,K) : PROCESSOR NUMBERS BEHIND THE 3 ELEMENT EDGES
!                     NUMBER FROM 0 TO NCSIZE-1
!     IFAPAR(5:7,K) : -LOCAL- ELEMENT NUMBERS BEHIND THE 3 EDGES
!                     IN THE NUMBERING OF PARTITIONS THEY BELONG TO
!     ACTUALLY, NOT ALL OF THAT IS REQUIRED AND CAN BE OPTIMISED
!     AFTER THE DEVELOPMENT STAGE IS OVER
!
!     IN TELEMAC, IFAPAR IS REORGANISED IN IFAPAR(6,NELEM2)
!                 AND INITIALISED TO 0 IN ALMESH
!
      READ(npar,*) nhalo
      IF(nhalo.GT.2*nptir) THEN ! SEE BIEF LIB, SUBROUTINE ALMESH
        WRITE(lu,*) ' => NHALO>2*NPTIR DETECTED IN BC FILE'
        CALL plante(1)
        stop
      ENDIF
      IF(nhalo.GT.0) THEN
        DO k=1,nhalo
          READ(npar,*) if1,if2,if3,if4,if5,if6,if7
!
!         CORRECTS A BUG (IN IFAPAR THERE IS A CONFUSION BETWEEN PROCESSOR 0
!                         AND LIQUID BOUNDARY BUT
!                         IN CASE OF LIQUID BOUNDARY, THE ELEMENT BEHIND
!                         IS GIVEN AS 0, SO BOTH CASES MAY BE DISTINGUISHED
!                         HERE ALL BOUNDARIES (LIQUID OR SOLID) ARE SET AT -1
!
          IF(if5.EQ.0) if2=-1
          IF(if6.EQ.0) if3=-1
          IF(if7.EQ.0) if4=-1
!
          mesh%IFAPAR%I(6*(if1-1)+1)=if2
          mesh%IFAPAR%I(6*(if1-1)+2)=if3
          mesh%IFAPAR%I(6*(if1-1)+3)=if4
          mesh%IFAPAR%I(6*(if1-1)+4)=if5
          mesh%IFAPAR%I(6*(if1-1)+5)=if6
          mesh%IFAPAR%I(6*(if1-1)+6)=if7
        ENDDO
      ENDIF
!
      CLOSE(npar)
!
!-----------------------------------------------------------------------
!
      RETURN
      END