read_fic_conc.f

Go to the documentation of this file.

!                   ************************
                    SUBROUTINE read_fic_conc
!                   ************************
!
     &(cgl , what , at , nfic , found )
!
!***********************************************************************
! TELEMAC2D   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    READS AND INTERPOLATES VALUES FROM THE LIQUID BOUNDARY FILE.
!
!history  J-M HERVOUET (LNHE)
!+        10/08/2009
!+        V6P0
!+
!
!history  J-M HERVOUET (LNHE)
!+        28/06/2010
!+        V6P0
!+   SIZE OF LIGN PARAMETERIZED (SEE SIZELIGN)
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AT             |-->| TIME_RFC IN SECONDS
!| NFIC           |-->| LOGICAL UNIT OF FILE
!| CGL            |<--| VARIABLE READ AND INTERPOLATED
!| FOUND          |<--| IF FALSE: VARIABLE NOT FOUND
!| WHAT           |-->| VARIABLE TO LOOK FOR IN 8 CHARACTERS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_sisyphe, ONLY : deja_rfc,infic_rfc,time_rfc,
     &                                 choix_rfc,il1_rfc,il2_rfc,
     &                                 tl1_rfc,tl2_rfc,nvalue_rfc,
     &                                 lastwhat_rfc,lastat_rfc,nlig_rfc,
     &                                 maxval_rfc
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=8)     , INTENT(IN)       :: WHAT
      DOUBLE PRECISION, INTENT(IN)       :: AT
      DOUBLE PRECISION, INTENT(INOUT)    :: CGL
      INTEGER         , INTENT(IN)       :: NFIC
      LOGICAL         , INTENT(OUT)      :: FOUND
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     MAXIMUM NUMBER OF CHARACTERS PER LIGN (MAY BE CHANGED)
!
      INTEGER, PARAMETER :: SIZELIGN = 3000
!
      INTEGER IVALUE,ILIG,OK,J,IWHAT,IDEB,IFIN
      DOUBLE PRECISION TETA
      DOUBLE PRECISION, PARAMETER :: TOL = 1.d-3
!
      CHARACTER(LEN=SIZELIGN) :: LIGNE
!
!
      INTRINSIC abs
!
!-----------------------------------------------------------------------
!
!     1) (AT FIRST CALL)
!        READS THE LIQUID BOUNDARY FILE
!        INITIALISES CURRENT LINES AND INTERVAL OF TIME_RFC
!
      IF(.NOT.deja_rfc) THEN
        rewind(nfic)
!       SKIPS COMMENTS
1       READ(nfic,fmt='(A)',err=10) ligne
        GO TO 20
10      CONTINUE
        WRITE(lu,*) 'READ ERROR IN THE'
        WRITE(lu,*) 'LIQUID BOUNDARIES FILE FOR CONC'
        WRITE(lu,*) 'PROBABLY A PROBLEM OF FORMAT'
        WRITE(lu,*) 'ANY WINDOWS CARRIAGE RETURNS ON UNIX OR LINUX'
        WRITE(lu,*) 'GUILTY LINE:'
        WRITE(lu,*) ligne
        CALL plante(1)
        stop
20      CONTINUE
        IF(ligne(1:1).EQ.'#') GO TO 1
!
!       FINDS OUT WHAT AND HOW MANY VALUES ARE GIVEN IN THE FILE
!
        nvalue_rfc = -1
        ifin = 1
40      ideb = ifin
!
!       IDENTIFIES FIRST CHARACTER OF NAME
50      IF(ligne(ideb:ideb).EQ.' '.AND.ideb.LT.sizelign) THEN
          ideb=ideb+1
          GO TO 50
        ENDIF
!       IDENTIFIES LAST CHARACTER OF NAME
        ifin = ideb
60      IF(ligne(ifin:ifin).NE.' '.AND.ifin.LT.sizelign) THEN
          ifin=ifin+1
          GO TO 60
        ENDIF
!
        IF(ideb.EQ.ifin) GO TO 4
!
        nvalue_rfc = nvalue_rfc + 1
        IF(nvalue_rfc.EQ.0) THEN
          IF(ligne(ideb:ifin-1).NE.'T') THEN
          WRITE(lu,*) 'FIRST VALUE MUST BE TIME_RFC, DENOTED T'
          WRITE(lu,*) 'IN FILE OF LIQUID BOUNDARIES'
          CALL plante(1)
          stop
          ENDIF
        ELSEIF(nvalue_rfc.LE.maxval_rfc) THEN
          choix_rfc(nvalue_rfc)='        '
          choix_rfc(nvalue_rfc)(1:ifin-ideb+1)=ligne(ideb:ifin-1)
        ELSE
          WRITE(lu,*) 'INCREASE MAXVAL_RFC IN DECLARATIONS_SISYPHE'
          CALL plante(1)
          stop
        ENDIF
        IF(ifin.LT.sizelign) GO TO 40
!
!       SKIPS THE LINE WITH UNITS OR NAMES
4       READ(nfic,fmt='(A)',err=10) ligne
        IF(ligne(1:1).EQ.'#') GO TO 4
!
!       COUNTS LINES OF DATA
        nlig_rfc = 0
998     READ(nfic,*,end=1000,err=999) ligne
        IF(ligne(1:1).NE.'#') nlig_rfc=nlig_rfc+1
        GO TO 998
999     CONTINUE
        WRITE(lu,*) 'READING ERROR ON THE LIQUID BOUNDARIES FILE'
        WRITE(lu,*) 'AT LINE OF DATA : ',nlig_rfc
        WRITE(lu,*) '(COMMENTS EXCLUDED)'
        CALL plante(1)
        stop
1000    CONTINUE
!
!       DYNAMICALLY ALLOCATES TIME_RFC AND INFIC_RFC
!
        ALLOCATE(time_rfc(nlig_rfc),stat=ok)
        IF(ok.NE.0) WRITE(lu,*) 'MEMORY ALLOCATION ERROR FOR TIME_RFC'
        ALLOCATE(infic_rfc(nvalue_rfc,nlig_rfc),stat=ok)
        IF(ok.NE.0) WRITE(lu,*) 'MEMORY ALLOCATION ERROR FOR INFIC_RFC'
!
!       FINAL READ OF TIME_RFC AND INFIC_RFC
!
        rewind(nfic)
!       SKIPS COMMENTS AND FIRST TWO MANDATORY LINES
2       READ(nfic,fmt='(A)') ligne
        IF(ligne(1:1).EQ.'#') GO TO 2
        READ(nfic,fmt='(A)') ligne
!
        DO ilig=1,nlig_rfc
3         READ(nfic,fmt='(A)') ligne
          IF(ligne(1:1).EQ.'#') THEN
            GO TO 3
          ELSE
            backspace(nfic)
            READ(nfic,*) time_rfc(ilig),
     &                  (infic_rfc(ivalue,ilig),ivalue=1,nvalue_rfc)
          ENDIF
        ENDDO
!
        CLOSE(nfic)
        deja_rfc = .true.
!
        il1_rfc = 1
        il2_rfc = 2
        tl1_rfc = time_rfc(1)
        tl2_rfc = time_rfc(2)
!
        WRITE(lu,*) 'THE LIQUID BOUNDARIES FILE CONTAINS'
        WRITE(lu,*) nlig_rfc,' LINES WITH:'
        WRITE(lu,*) (choix_rfc(ivalue),ivalue=1,nvalue_rfc)
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!     2) INTERPOLATES THE DATA TO GET THE CORRECT TIME_RFC
!
!     2.A) FINDS THE ADDRESS IN THE ARRAY OF STORED DATA
!
!     2.B) INTERPOLATES DATA FROM THE ARRAY INFIC_RFC
!
!-----------------------------------------------------------------------
!
!
!     WHICH VARIABLE ?
      iwhat = 0
      DO j=1,nvalue_rfc
        IF(what.EQ.choix_rfc(j)) iwhat=j
      ENDDO
      IF(iwhat.EQ.0) THEN
        found=.false.
        RETURN
      ENDIF
!
!
!
70    IF(at.GE.tl1_rfc-tol.AND.at.LE.tl2_rfc+tol) THEN
        teta = (at-tl1_rfc)/(tl2_rfc-tl1_rfc)
      ELSE
        DO j=1,nlig_rfc-1
          IF(at.GE.time_rfc(j)-tol.AND.at.LE.time_rfc(j+1)+tol) THEN
            tl1_rfc=time_rfc(j)
            tl2_rfc=time_rfc(j+1)
            il1_rfc=j
            il2_rfc=j+1
            GO TO 70
          ENDIF
        ENDDO
        il1_rfc=il2_rfc
        il2_rfc=il2_rfc+1
        IF(il2_rfc.GT.nlig_rfc) THEN
          WRITE(lu,*) 'T=',at,' OUT OF RANGE'
          WRITE(lu,*) 'OF THE FILE OF LIQUID BOUNDARIES'
          CALL plante(1)
          stop
        ENDIF
        tl1_rfc=time_rfc(il1_rfc)
        tl2_rfc=time_rfc(il2_rfc)

        GO TO 70
      ENDIF
!
      cgl = (1.d0-teta)*infic_rfc(iwhat,il1_rfc)
     &  +       teta *infic_rfc(iwhat,il2_rfc)
!
      found=.true.

      lastat_rfc=at
      lastwhat_rfc=what
!
!-----------------------------------------------------------------------
!
      RETURN
      END