read_dataset.f

Go to the documentation of this file.

!                   ***********************
                    SUBROUTINE read_dataset
!                   ***********************
!
     &(fformat,fid,varsor,npoin,record,at,var_list,trouve,alire,listin,
     & lastrecord,maxvar)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    Reads the results for a given time step and
!+        a given list of variables
!
!history Y AUDOUIN (LNHE)
!+        19/05/2014
!+        V7P1
!+        First version
!
!history  R.ATA (LNHE)
!+        13/12/2016
!+        V7P2
!+        add an additional condition before getting variable values
!+        in the call of GET_DATA_VALUE
!
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FFORMAT        |-->| FORMAT OF THE FILE
!| FID            |-->| LOGICAL UNIT OF FILE
!| VARSOR         |<->| LIST OF ARRAY THAT WILL CONTAINS THE VARIABLE
!|                |   | VALUE ON EACH POINT
!| NPOIN          |-->| NUMBER OF POINT IN THE GEOMETRY MESH
!| RECORD         |-->| TIME STEP OF THE DATASET
!| AT             |<->| TIME OF THE DATASET
!| VAR_LIST       |-->| NAMES AND UNITS OF VARIABLES.
!| TROUVE         |<--| GIVES (TROUVE(K)=1) IF VARIABLES PRESENT IN THE FILE
!|                |   | 0 OTHERWISE
!| ALIRE          |-->| VARIABLES TO BE READ (FOR OTHERS RECORD SKIPPED)
!|                |   | CLANDESTINE VARIABLES ARE SYSTEMATICALLY READ
!| LISTIN         |-->| IF YES, INFORMATIONS PRINTED ON LISTING
!| LASTRECORD     |<->| LASTRECORD = .TRUE. LAST RECORD WILL BE READ
!|                |   | LASTRECORD = .FALSE. : RECORD "RECORD" WILL BE READ
!| MAXVAR         |-->| DIMENSION OF ARRAY RELATED TO VARIABLES: ALIRE,..
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_hermes
      USE bief_def
      USE bief, ONLY: ov
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(INOUT)   :: VARSOR
      INTEGER, INTENT(IN)             :: NPOIN
      INTEGER, INTENT(IN)             :: MAXVAR
      INTEGER, INTENT(IN)             :: FID
      INTEGER, INTENT(INOUT)          :: RECORD
      INTEGER, INTENT(INOUT)          :: TROUVE(maxvar)
      INTEGER, INTENT(IN)             :: ALIRE(maxvar)
      CHARACTER(LEN=8), INTENT(IN)    :: FFORMAT
      CHARACTER(LEN=32), INTENT(IN)   :: VAR_LIST(maxvar)
      DOUBLE PRECISION, INTENT(INOUT) :: AT
      LOGICAL, INTENT(IN)             :: LISTIN,LASTRECORD
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IREC
      INTEGER :: L,IERR,IPLAN,I,IP1,IP2
      LOGICAL :: INTERPOLATE
      INTEGER :: NPOIN_PREV, NPLAN_PREV, NPLAN, NPOIN2
      DOUBLE PRECISION, ALLOCATABLE :: WD(:)
      DOUBLE PRECISION :: TETA,ARG
      CHARACTER(LEN=16), ALLOCATABLE :: VARNAME(:),VARUNIT(:)
      CHARACTER(LEN=80) :: TITLE
      INTEGER :: NVAR,IVAR
      INTRINSIC SIZE
!
!-----------------------------------------------------------------------
!
!     We need the number of points to read the data
!
      CALL get_mesh_npoin(fformat,fid,point_bnd_elt_type,
     &                    npoin_prev,ierr)
      CALL check_call(ierr,'READ_DATASET:GET_MESH_NPOIN')
      CALL get_mesh_nplan(fformat,fid,nplan_prev,ierr)
      CALL check_call(ierr,'READ_DATASET:GET_MESH_NPLAN')
!
!     Printout
!
      CALL get_mesh_title(fformat,fid,title,ierr)
      CALL check_call(ierr,'BIEF_VALIDA:GET_MESH_TITLE')
!
      CALL get_data_nvar(fformat,fid,nvar,ierr)
      CALL check_call(ierr,'BIEF_VALIDA:GET_DATA_NVAR')
!
      ALLOCATE(varname(nvar),stat=ierr)
      CALL check_allocate(ierr,'VARNAME')
      ALLOCATE(varunit(nvar),stat=ierr)
      CALL check_allocate(ierr,'VARUNIT')
!
      CALL get_data_var_list(fformat,fid,nvar,varname,varunit,ierr)
      CALL check_call(ierr,'BIEF_VALIDA:GET_DATA_NVAR')

      IF(listin) WRITE(lu,301) title
301   FORMAT(1x,//,1x,'TITLE OF PREVIOUS COMPUTATION: ',a72,/)
!
      DO ivar=1,nvar
        IF(listin) WRITE(lu,111) varname(ivar),varunit(ivar)
111     FORMAT(1x,'NAME: ',a16,'  UNIT: ' ,a16)
      ENDDO ! IVAR
      DEALLOCATE(varname,varunit)
!
!     INTERPOLATES ?
!
      interpolate=.false.
      IF(npoin_prev.NE.npoin) THEN
        interpolate=.true.
        npoin2=npoin_prev/nplan_prev
        nplan=npoin/npoin2
        ALLOCATE(wd(npoin_prev),stat=ierr)
        CALL check_allocate(ierr,'READ_DATASET:WD')
      ENDIF
!
!     GET THE NUMBER OF TIME STEPS
!
      IF(lastrecord) THEN
        CALL get_data_ntimestep(fformat,fid,irec,ierr)
        CALL check_call(ierr,'READ_DATASET:GET_DATA_NTIMESTEP')
!       Records go from 0 to ntimestep - 1
        irec = irec - 1
        record = irec
      ELSE
        irec = record
      ENDIF
!
!     GET THE TIME ASSOCIATED WITH THE RECORD
!
      CALL get_data_time(fformat,fid,irec,at,ierr)
!
!     Check if the record is in the file
!
      IF(ierr.EQ.hermes_record_unknown_err) THEN
        WRITE(lu,76) irec
        CALL plante(1)
      ELSE
        CALL check_call(ierr,'READ_DATASET:GET_DATA_TIME')
      ENDIF
!
      DO l=1,min(maxvar,varsor%N)
!
        IF((alire(l).EQ.1)               .AND.
     &     (ASSOCIATED(varsor%ADR(l)%P)) .AND.
     &     (var_list(l)(1:1).NE.' ')    ) THEN
!
!         To avoid cases where dim1=0
          IF(varsor%ADR(l)%P%DIM1.GE.npoin_prev) THEN
!           Interpolate the results if necessary
            IF(interpolate) THEN
              CALL get_data_value(fformat,fid,irec,var_list(l)(1:16),
     &                            wd,npoin_prev,ierr)
!             If the variable is not in the file
              IF(ierr.EQ.hermes_var_unknown_err) THEN
                trouve(l) = 0
                CONTINUE
              ELSE
                CALL check_call(ierr,'READ_DATASET:GET_DATA_VALUE')
                trouve(l) = 1
              ENDIF
!             COPIES BOTTOM AND FREE SURFACE
              CALL ov('X=Y     ', x=varsor%ADR(l)%P%R, y=wd,dim1=npoin2)
              CALL ov('X=Y     ',
     &                x=varsor%ADR(l)%P%R(npoin-npoin2+1:npoin),
     &                y=wd(npoin_prev-npoin2+1:npoin_prev),
     &                dim1=npoin2)
!             INTERPOLATES OTHER PLANES
              IF(nplan.GT.2) THEN
                DO iplan=2,nplan-1
                  arg=(nplan_prev-1)*float(iplan-1)/float(nplan-1)
                  teta=arg-int(arg)
!                 IP1 : LOWER PLANE NUMBER - 1
                  ip1=int(arg)
!                 IP2 : UPPER PLANE NUMBER - 1
                  ip2=ip1+1
                  DO i=1,npoin2
                    varsor%ADR(l)%P%R(i+npoin2*(iplan-1))=
     &              teta *wd(i+npoin2*ip2)+(1.d0-teta)*wd(i+npoin2*ip1)
                  ENDDO
                ENDDO
              ENDIF
!           NO INTERPOLATION
            ELSE
!
              CALL get_data_value(fformat,fid,irec,var_list(l)(1:16),
     &                            varsor%ADR(l)%P%R,npoin_prev,ierr)
!
!             If the variable is not in the file
              IF(ierr.EQ.hermes_var_unknown_err) THEN
                trouve(l) = 0
              ELSE
                CALL check_call(ierr,'READ_DATASET:GET_DATA_VALUE')
                trouve(l) = 1
              ENDIF
            ENDIF
          ENDIF
!
        ELSE
          ! if the record is not in the file
          trouve(l) = 0
        ENDIF
!
      ENDDO ! L
      IF(interpolate) DEALLOCATE(wd)
!
      IF(listin) WRITE(lu,131) irec+1
131   FORMAT(/,1x,'READ_DATASET : READ OF RECORD ',1i5)
!
      IF(listin) WRITE(lu,141) at
141   FORMAT(//,1x,'TIME OF RECORD: ',g16.7,' S')
!
!-----------------------------------------------------------------------
!
76      FORMAT(/,1x,'TIME STEP : ',i16,/,1x,'IS NOT IN THE FILE')
!
!-----------------------------------------------------------------------
!
      RETURN
      END