qwind3.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE qwind3
!                       *****************
!
     &( tstot , tsder , f     , xk    , usold , usnew , twold , twnew ,
     &  nf    , ndire , npoin2, betan , betao , dirn  , diro  )
!
!**********************************************************************
! TOMAWAC   V6P1                                   27/06/2011
!**********************************************************************
!
!brief    COMPUTES THE CONTRIBUTION OF THE WAVE GENERATION
!+               (BY WIND) SOURCE TERM BASED ON THE YAN PARAMETRISATION
!+               (1987) AND USING THE COEFFICIENTS PROPOSED BY WESTHUYSEN
!+               ET AL. (2007)
!
!reference  YAN (1987) : AN IMPROVED WIND INPUT SOURCE TERM FOR
!+                THIRD GENERATION OCEAN WAVE MODELLING, REP NO 87-8,
!+                ROYAL DUTCH METEOR. INST., 20 PP.
!
!reference  WESTHUYSEN ET AL. (2007) : NONLINEAR SATURATION-BASED
!+                WHITECAPPING DISSIPATION IN SWAN FOR DEEP AND SHALLOW
!+                WATER, COASTAL ENG., VOL 54, 151-170.
!
!history  E. GAGNAIRE-RENOU (EDF/LNHE)
!+        09/2010
!+        V6P0
!+
!
!history  G.MATTAROLO (EDF - LNHE)
!+        27/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| BETAN          |<--| WORK TABLE
!| BETAO          |<--| WORK TABLE
!| DIRN           |<--| WORK TABLE
!| DIRO           |<--| WORK TABLE
!| F              |-->| DIRECTIONAL SPECTRUM
!| FREQ           |-->| DISCRETIZED FREQUENCIES
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| TETA           |-->| DISCRETIZED DIRECTIONS
!| TSDER          |<->| DERIVED PART OF THE SOURCE TERM CONTRIBUTION
!| TSTOT          |<->| TOTAL PART OF THE SOURCE TERM CONTRIBUTION
!| TWNEW          |-->| WIND DIRECTION AT TIME N+1
!| TWOLD          |-->| WIND DIRECTION AT TIME N
!| USNEW          |-->| FRICTION VELOCITY AT TIME N+1
!| USOLD          |-->| FRICTION VELOCITY AT TIME N
!| XK             |-->| DISCRETIZED WAVE NUMBER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  APPELS :    - PROGRAMME(S) APPELANT  : SEMIMP
!  ********    - PROGRAMME(S) APPELE(S) :    -
!
!**********************************************************************
!
      USE declarations_tomawac, ONLY : deupi,cimpli, freq, teta,
     &                                 coefwd, coefwe, coefwf, coefwh 
!FROM TOMAWAC MODULE
! CIMPLI          IMPLICITATION COEFFICIENT FOR SOURCE TERMS
! COEFWD          COEFFICIENT D OF YAN WIND GENERATION MODEL
! COEFWE          COEFFICIENT E OF YAN WIND GENERATION MODEL
! COEFWF          COEFFICIENT F OF YAN WIND GENERATION MODEL
! COEFWH          COEFFICIENT H OF YAN WIND GENERATION MODEL
!
      USE interface_tomawac, ex_qwind3 => qwind3
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)   ::    NF  , NDIRE        , NPOIN2
      DOUBLE PRECISION, INTENT(IN)   :: TWOLD(npoin2), TWNEW(npoin2)
      DOUBLE PRECISION, INTENT(IN)   :: USOLD(npoin2), USNEW(npoin2)
      DOUBLE PRECISION, INTENT(IN)   :: F(npoin2,ndire,nf),XK(npoin2,nf)
      DOUBLE PRECISION, INTENT(INOUT):: DIRO(npoin2) , DIRN(npoin2)
      DOUBLE PRECISION, INTENT(INOUT):: BETAN(npoin2), BETAO(npoin2)
      DOUBLE PRECISION, INTENT(INOUT):: TSTOT(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(INOUT):: TSDER(npoin2,ndire,nf)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  JP    , IFF   , IP
      DOUBLE PRECISION DIREC , CONST
      DOUBLE PRECISION INTERO, INTERN , CPHAS  , DIMPLI
!
!
      dimpli= 1.0d0-cimpli
!
!
!.....LOOP ON THE DISCRETISED DIRECTIONS
!     """"""""""""""""""""""""""""""""""""""""""""
      DO jp=1,ndire
!
!.......PRECOMPUTES THE DIRECTIONAL DEPENDENCES
!       """"""""""""""""""""""""""""""""""""""""""""""
        direc=teta(jp)
        DO ip=1,npoin2
          diro(ip)=cos(direc-twold(ip))
          dirn(ip)=cos(direc-twnew(ip))
        ENDDO
!
!.......LOOP ON THE DISCRETISED FREQUENCIES
!       """"""""""""""""""""""""""""""""""""""""""""
        DO iff = 1,nf
          const=deupi*freq(iff)
!
!.........COMPUTES THE PROPORTIONALITY COEFFICIENTS BETA
!         """"""""""""""""""""""""""""""""""""""""""""""""
          DO ip = 1,npoin2
            cphas = const / xk(ip,iff)
            intero=usold(ip)/cphas
            betao(ip)=(coefwd*intero**2*diro(ip)+coefwe*intero*diro(ip)
     &      +coefwf*diro(ip)+coefwh)*const
            intern=usnew(ip)/cphas
            betan(ip)=(coefwd*intern**2*dirn(ip)+coefwe*intern*dirn(ip)
     &      +coefwf*dirn(ip)+coefwh)*const
          ENDDO
!
!.........TAKES INTO ACCOUNT THE SOURCE TERM
!         """"""""""""""""""""""""""""""""
          DO ip = 1,npoin2
            tstot(ip,jp,iff) = tstot(ip,jp,iff)
     &           + max((dimpli*betao(ip)+cimpli*betan(ip))*f(ip,jp,iff)
     &                 ,0.d0)
            tsder(ip,jp,iff) = tsder(ip,jp,iff) + max(betan(ip),0.d0)
          ENDDO
!
        ENDDO
!
      ENDDO
!
      RETURN
      END