qveg.f

Go to the documentation of this file.

!                   ***************
                    SUBROUTINE qveg
!                   ***************
!
     & ( tstot , tsder , f , varian , fmoy , xkmoy , nf    , ndire  ,
     &   npoin2   )
!
!***********************************************************************
! TOMAWAC   V7P0
!***********************************************************************
!
!brief    Takes into account the friction due to vegetation
!
!history  VITO BACCHI (EDF - LNHE)
!+        12/09/2014
!+        V7P0
!+   First version, on birthday eve...
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DEPTH          |-->| WATER DEPTH
!| F              |-->| DIRECTIONAL SPECTRUM
!| FMOY           |-->| MEAN SPECTRAL FRQUENCY FMOY (relative frequency)
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| TSDER          |<->| DERIVED PART OF THE SOURCE TERM CONTRIBUTION
!| TSTOT          |<->| TOTAL PART OF THE SOURCE TERM CONTRIBUTION
!| VARIAN         |-->| ENERGY SPECTRUM VARIANCE
!| XKMOY          |-->| AVERAGE WAVE NUMBER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_tomawac, ONLY : deupi,gravit,pi, depth
!
      USE interface_tomawac, ex_qveg => qveg
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NF,NDIRE,NPOIN2
      DOUBLE PRECISION, INTENT(IN)    :: XKMOY(npoin2),VARIAN(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: TSTOT(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(INOUT) :: TSDER(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(IN)    :: F(npoin2,ndire,nf),FMOY(npoin2)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER  JP    , JF    , IP
      DOUBLE PRECISION C1,CVEG,CD,NV,BV,ALFA,KH,AKH,RO,DV
      DOUBLE PRECISION AUX,NUM,DENUM,SHAKH, BETA
!
!-----------------------------------------------------------------------
!
!     DISSIPATION COEFFICIENTS OF VEGETATION
      ro = 1.d0
!     NUMBER OF PLANTS*SQM
      nv = 20.d0
!     PLANT AREA PER UNINT HEIGHT
      bv = 0.25d0
!     BULK DRAG COEFFICIENT
      cd = 0.2d0
!     VEGETATION HEIGHT
      dv = 2.d0
!TF   NEXT LINE USELESS
!      ALFA = 0.9D0
      c1 = - sqrt(2.d0/pi)*gravit**2
      cveg = c1*cd*bv*nv/(deupi**3)
!
!     VEGETATION OVER A CONSTANT DEPTH
!     COMPUTES THE BETA COEFFICIENT : QVEG1 = BETA * F
!
      DO ip=1,npoin2
        alfa = dv/depth(ip)
        kh = xkmoy(ip)*depth(ip)
        akh = alfa*kh
        shakh = sinh(akh)
        num = shakh*(shakh**2 + 3.d0)
        denum = 3.d0*xkmoy(ip)*cosh(kh)**3
        aux = (xkmoy(ip)/fmoy(ip))**3
        beta = ro*cveg*aux*(num/denum)*sqrt(varian(ip))
!
!     LOOP OVER THE DISCRETISED FREQUENCIES
!
!     TAKES THE SOURCE TERM INTO ACCOUNT
!
        DO jf=1,nf
          DO jp=1,ndire
            tstot(ip,jp,jf) = tstot(ip,jp,jf)+beta*f(ip,jp,jf)
            tsder(ip,jp,jf) = tsder(ip,jp,jf)+beta
          ENDDO
        ENDDO

      ENDDO

!
!-----------------------------------------------------------------------
!
      RETURN
      END