qgl.f

Go to the documentation of this file.

!                   *****************************
                    DOUBLE PRECISION FUNCTION qgl
!                   *****************************
!
     &(i,at)
!
!***********************************************************************
! SISYPHE
!***********************************************************************
!
!brief    PRESCRIBES THE SOLID DISCHARGE FOR  IMPOSED
!+                LIQUID BOUNDARIES.
!
!history  J-M HERVOUET (LNHE)
!+        17/08/1994
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C. COULET (ARTELIA GROUP)
!+        08/11/2011
!+        V6P2
!+   Modification size FCT due to modification of TRACER numbering
!
!history  P. TASSI (EDF)
!+        17/03/2017
!+        V7P3
!+   Modification of the error message when the prescribed number
!+   of solid discharge(s) is not enough
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| I              |-->| NUMBER OF LIQUID BOUNDARY
!| N              |-->| GLOBAL NUMBER OF POINT
!|                |   | IN PARALLEL NUMBER IN THE ORIGINAL MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_sisyphe
      USE declarations_special
!
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: I
      DOUBLE PRECISION, INTENT(IN):: AT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=9) FCT
!
!-----------------------------------------------------------------------
!
!     IF THE LIQUID BOUNDARY FILE EXISTS, ATTEMPTS TO FIND
!     THE VALUE IN IT. IF YES, OK REMAINS TO .TRUE. FOR NEXT CALLS
!                      IF  NO, OK IS SET  TO .FALSE.
!
      IF(okqgl(i).AND.sis_files(sisliq)%NAME(1:1).NE.' ') THEN
!
!       FCT WILL BE QGL(1), QGL(2), ETC, QGL(9), DEPENDING ON I
        fct='QG(      '
        IF(i.LT.10) THEN
          WRITE(fct(4:4),fmt='(I1)') i
          fct(5:5)=')'
        ELSEIF(i.LT.100) THEN
          WRITE(fct(4:5),fmt='(I2)') i
          fct(6:6)=')'
        ELSE
          WRITE(lu,*)'I=',i
          WRITE(lu,*) 'QGL NOT PROGRAMMED FOR MORE THAN 99 BOUNDARIES'
          CALL plante(1)
          stop
        ENDIF
!
        CALL read_fic_conc(qgl,fct,at,sis_files(sisliq)%LU,
     &                     okqgl(i))
!
      ENDIF
!
      IF(.NOT.okqgl(i).OR.sis_files(sisliq)%NAME(1:1).EQ.' ') THEN
!       USER DEFINED
        CALL user_qgl(qgl,i,at)
      ENDIF
!
!
!-----------------------------------------------------------------------
!
      RETURN
      END