qbrek4.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE qbrek4
!                   *****************
!
     &( tstot , f     , fcar  , varian, nf    , ndire , npoin2)
!
!***********************************************************************
! TOMAWAC   V6P1                                   23/06/2011
!***********************************************************************
!
!brief    COMPUTES THE CONTRIBUTION OF THE DEPTH-INDUCED
!+                BREAKING SOURCE TERM BASED ON IZUMIYA ET HORIKAWA (1984).
!
!note     THIS SOURCE TERM IS LINEAR IN F(FREQ,TETA), AND THE LINEAR
!+          COEFFICIENT DOES NOT VARY WITH TIME.
!
!reference  IZUMIYA T., HORIKAWA K. (1984) :
!+                     "WAVE ENERGY EQUATION APPLICABLE IN AND OUTSIDE
!+                      THE SURF ZONE". COASTAL ENGINEERING IN JAPAN, VOL 17, PP 119-137.
!
!history  F. BECQ; M. BENOIT (EDF/DER/LNH)
!+        26/03/96
!+        V1P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        23/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DEPTH          |-->| WATER DEPTH
!| F              |-->| DIRECTIONAL SPECTRUM
!| FCAR           |-->| CHARACTERISTIC FREQUENCY
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| TSTOT          |<->| TOTAL PART OF THE SOURCE TERM CONTRIBUTION
!| VARIAN         |-->| SPECTRUM VARIANCE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : betaih, em2sih, gravit, depth,
     &                betabr
      USE interface_tomawac, ex_qbrek4 => qbrek4
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)   ::          NF    , NDIRE , NPOIN2
      DOUBLE PRECISION, INTENT(IN)   :: F(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(IN)   :: VARIAN(npoin2),FCAR(npoin2)
      DOUBLE PRECISION, INTENT(INOUT):: TSTOT(npoin2,ndire,nf)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  JP    , IFF   , IP
      DOUBLE PRECISION COEF  , XKCAR , DEUKD , GG1   , GG2
!
!
      coef   = -sqrt(gravit)*betaih
!
!.....COMPUTES THE LINEAR COEFFICIENT BETABR : QBREK4 = BETABR * F
!     """""""""""""""""""""""""""""""""""""""""""""""""""""""
      DO ip = 1,npoin2
        CALL wnscou( xkcar, fcar(ip), depth(ip) )
        deukd=2.d0*xkcar*depth(ip)
        IF (deukd.GT.7.d2) THEN
          gg1 = 0.d0
          gg2 = 0.5d0
        ELSE
          gg1 = deukd/sinh(deukd)
          gg2 = 0.5d0*(1.d0+gg1)
        ENDIF
        betabr(ip) = coef/depth(ip)**1.5*sqrt(varian(ip)*gg1)
     &               *sqrt(max(0.d0,gg2*varian(ip)
     &               /(depth(ip)*depth(ip))-em2sih))
        DO iff = 1,nf
          DO jp = 1,ndire
            tstot(ip,jp,iff) = tstot(ip,jp,iff)+betabr(ip)*f(ip,jp,iff)
          ENDDO                 ! JP
        ENDDO                   ! IFF
      ENDDO                     ! IP
!
      RETURN
      END