qbrek2.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE qbrek2
!                   *****************
!
     & ( tstot , f     , fcar  , varian, nf    , ndire , npoin2)
!
!***********************************************************************
! TOMAWAC   V6P1                                   23/06/2011
!***********************************************************************
!
!brief    COMPUTES THE CONTRIBUTION OF THE DEPTH-INDUCED
!+                BREAKING SOURCE TERM BASED ON THORNTON AND GUZA (1983).
!
!note     THIS SOURCE TERM IS LINEAR IN F(FREQ,TETA), AND THE LINEAR
!+          COEFFICIENT DOES NOT VARY WITH TIME.
!
!reference  THORNTON AND GUZA (1983) :
!+                     "TRANSFORMATION OF WAVE HEIGHT DISTRIBUTION".
!
!history  F. BECQ; M. BENOIT (EDF/DER/LNH)
!+        14/02/96
!+        V1P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        23/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| BORETG         |-->| COEFFICIENT B OF WAVE BREAKING TG MODEL
!| DEPTH          |-->| WATER DEPTH
!| F              |-->| DIRECTIONAL SPECTRUM
!| FCAR           |-->| CHARACTERISTIC FREQUENCY
!| GAMATG         |-->| GAMMA CONSTANT OF WAVE BREAKING TG MODEL
!| IWHTG          |-->| WEIGHT. FUN.SELECTION OF WAVE BREAKING TG MODEL
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| TSTOT          |<->| TOTAL PART OF THE SOURCE TERM CONTRIBUTION
!| VARIAN         |-->| SPECTRUM VARIANCE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : deupi, boretg, gamatg, iwhtg,
     & depth, betabr
!
      USE interface_tomawac, ex_qbrek2 => qbrek2
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)            :: NF, NDIRE, NPOIN2
      DOUBLE PRECISION, INTENT(IN)   :: F(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(IN)   :: VARIAN(npoin2), FCAR(npoin2)
      DOUBLE PRECISION, INTENT(INOUT):: TSTOT(npoin2,ndire,nf)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  JP    , IFF   , IP
      DOUBLE PRECISION COEF  , GAMMA2
!
      gamma2 = gamatg**2
      coef   = -24.d0*sqrt(deupi)*boretg**3/gamma2
!
      IF (iwhtg.EQ.1) THEN
!
!.......COMPUTES THE LINEAR COEFFICIENT BETABR : QBREK2 = BETABR * F
!       WITH THE WEIGHT FUNCTION W(H) = CONSTANT
!       """""""""""""""""""""""""""""""""""""""""""""""""""""""
        DO ip = 1,npoin2
          betabr(ip) = coef*8.d0*sqrt(varian(ip)**5)*fcar(ip)
     &             /(gamma2*depth(ip)**5)
          DO iff = 1,nf
            DO jp = 1,ndire
              tstot(ip,jp,iff) = tstot(ip,jp,iff)
     &             +betabr(ip)*f(ip,jp,iff)
            ENDDO               ! JP
          ENDDO                 ! IFF
        ENDDO
!
      ELSEIF (iwhtg.EQ.2) THEN
!
!.......COMPUTES THE LINEAR COEFFICIENT BETA : QBREK2 = BETABR * F
!       WITH THE WEIGHT FUNCTION W(H) != CONSTANT
!       """""""""""""""""""""""""""""""""""""""""""""""""""""""
        DO ip = 1,npoin2
          betabr(ip) = (coef*sqrt(varian(ip)**3)*fcar(ip)/
     &              depth(ip)**3)*(1.d0-1.d0/(1.d0+varian(ip)*8.d0
     &              /(gamma2*depth(ip)*depth(ip)))**2.5d0)
          DO iff = 1,nf
            DO jp = 1,ndire
              tstot(ip,jp,iff) = tstot(ip,jp,iff)
     &             +betabr(ip)*f(ip,jp,iff)
            ENDDO               ! JP
          ENDDO                 ! IFF
        ENDDO ! IP
      ENDIF
!
      RETURN
      END