qbbj78.f

Go to the documentation of this file.

!                   ***************
                    FUNCTION qbbj78
!                   ***************
!
     &( b     , iqbbj )
!
!***********************************************************************
! TOMAWAC   V6P1                                   23/06/2011
!***********************************************************************
!
!brief    COMPUTES THE FRACTION OF BREAKING WAVES: QB.
!+                QB IS USED IN BATTJES AND JANSSEN (1978).
!
!reference  BATTJES AND JANSSEN (1978) :
!+                     "ENERGY LOSS AND SET-UP DUE TO BREAKING
!+                      OF RANDOM WAVES". ICCE'78.
!reference DINGEMANS (1983) :
!+                     "VERIFICATION OF NUMERICAL WAVE PROPAGATION
!+                      MODELS WITH FIELD MEASUREMENTS. CREDIZ
!+                      VERIFICATION HARINGVLIET".
!
!history  F.BECQ; M. BENOIT (EDF/DER/LNH)
!+        14/02/96
!+        V1P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        23/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| B              |-->| (H_RMS/H_MAX)
!| IQBBJ          |-->| INDEX OF THE SLECTED COMPUTATION METHOD
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_tomawac, ex_qbbj78 => qbbj78
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      DOUBLE PRECISION, INTENT(IN) ::  B
      INTEGER, INTENT(IN)     ::  IQBBJ
      DOUBLE PRECISION QBBJ78
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      DOUBLE PRECISION CB,   Q0,   B2, EXPO
!
      IF (b.GE.1.d0) THEN
        qbbj78 = 1.d0
        RETURN
      ENDIF
!
!     IF(IQBBJ.EQ.0) THEN
!     THIS OPTION (SOLVES BY DICHOTOMY) IS NEVER USED
!     AND DOES NOT ALWAYS CONVERGE, IT HAS BEEN DELETED.
!
      IF(iqbbj.EQ.1) THEN
!       ======================================================
!       EXPLICIT FORMULATION 1 (INSPIRED FROM CREDIZ VERSION-1)
!       ======================================================
        cb = 0.5d0
        IF (b.GE.cb) THEN
          qbbj78 = ((b-cb)/(1.d0-cb))**2
        ELSE
          qbbj78 = 0.d0
        ENDIF
!
      ELSEIF(iqbbj.EQ.2) THEN
!       ======================================================
!       EXPLICIT FORMULATION 2 (INSPIRED FROM CREDIZ VERSION-2)
!       ======================================================
        cb = 0.3d0
        IF (b.LT.cb) THEN
          qbbj78 = 0.d0
        ELSEIF (b.LT.0.5d0) THEN
          b2     = b**2
          expo   = exp(-1.d0/b2)
          qbbj78 = b2*expo/(b2-expo)
        ELSEIF (b.LT.0.9d0) THEN
          q0     = (2.d0*b-1.d0)**2
          b2     = b**2
          expo   = exp((q0-1.d0)/b2)
          qbbj78 = q0 - b2*(q0-expo)/(b2-expo)
        ELSE
          qbbj78 = (2.d0*b-1.d0)**2
        ENDIF
!
      ELSEIF(iqbbj.EQ.3) THEN
!       ======================================================
!       EXPLICIT FORMULATION 3 (INSPIRED FROM CREDIZ VERSION-3)
!       ======================================================
        qbbj78 = 2.4d0*b**7
!
      ENDIF
!
      RETURN
      END