q.f

Go to the documentation of this file.

!                   ***************************
                    DOUBLE PRECISION FUNCTION q
!                   ***************************
!
     &(i)
!
!***********************************************************************
! TELEMAC2D   V6P2                                   08/11/2011
!***********************************************************************
!
!brief    PRESCRIBES THE DISCHARGE FOR FLOW IMPOSED
!+                LIQUID BOUNDARIES.
!
!history  J-M HERVOUET (LNHE)
!+        09/01/2004
!+        V5P6
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C. COULET (ARTELIA GROUP)
!+        08/11/2011
!+        V6P2
!+   Modification of FCT size due to modification of TRACER numbering
!
!history  J-M HERVOUET (LNHE)
!+        21/05/2012
!+        V6P2
!+   Discharge taken at mid distance between AT-DT AND AT, except
!+   for finite volumes (DT unknown, and AT time of beginning of time
!+   step in this case)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| I              |-->| NUMBER OF THE LIQUID BOUNDARY.
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_special
      USE declarations_telemac
      USE declarations_telemac2d
      USE interface_telemac2d, ex_q => q
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN) :: I
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=9) FCT
      DOUBLE PRECISION Q1,Q2
!
!-----------------------------------------------------------------------
!
!     IF LIQUID BOUNDARY FILE EXISTS, ATTEMPTS TO FIND
!     THE VALUE IN IT. IF YES, OKQ REMAINS TO .TRUE. FOR NEXT CALLS
!                      IF  NO, OKQ IS SET  TO .FALSE.
!
      IF(okq(i).AND.t2d_files(t2dimp)%NAME(1:1).NE.' ') THEN
!
!       FCT WILL BE Q(1), Q(2), ETC, Q(99), DEPENDING ON I
        fct='Q(       '
        IF(i.LT.10) THEN
          WRITE(fct(3:3),fmt='(I1)') i
          fct(4:4)=')'
        ELSEIF(i.LT.100) THEN
          WRITE(fct(3:4),fmt='(I2)') i
          fct(5:5)=')'
        ELSE
          WRITE(lu,*) 'Q NOT PROGRAMMED FOR MORE THAN 99 BOUNDARIES'
          CALL plante(1)
          stop
        ENDIF
        IF(equa(1:15).NE.'SAINT-VENANT VF') THEN
          CALL read_fic_frliq(q1,fct,at-dt,
     &                        t2d_files(t2dimp)%LU,entet,okq(i))
          CALL read_fic_frliq(q2,fct,at   ,
     &                        t2d_files(t2dimp)%LU,entet,okq(i))
          q=(q1+q2)*0.5d0
        ELSE
          CALL read_fic_frliq(q,fct,at   ,
     &                        t2d_files(t2dimp)%LU,entet,okq(i))
        ENDIF
!
      ENDIF
!
      IF(.NOT.okq(i).OR.t2d_files(t2dimp)%NAME(1:1).EQ.' ') THEN
!
!     Q IS TAKEN FROM THE STEERING FILE, BUT MAY BE CHANGED
!
        IF(ndebit.GE.i) THEN
          q = debit(i)
!
          ! USER UPDATE OF VALUE
          CALL user_q(i, q)
        ELSE
          WRITE(lu,401) i
401       FORMAT(1x,/,1x,'Q : MORE PRESCRIBED FLOWRATES',/,
     &                1x,'    ARE REQUIRED IN THE PARAMETER FILE',/,
     &                1x,'    AT LEAST ',1i6,' MUST BE GIVEN')
          CALL plante(1)
          stop
        ENDIF
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END