puog.f

Go to the documentation of this file.

!                   ***************
                    SUBROUTINE puog
!                   ***************
!
     &(x, a,b ,ditr,mesh,copy)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE VECTOR X = U B     (ELEMENT BY ELEMENT).
!+
!+            REVERSE OF WHAT GOUP DOES, HENCE THE NAME.
!code
!+            MATRIX U IS HERE THE RESULT OF A DECOMPOSITION
!+            PERFORMED IN SUBROUTINE DECLDU.
!+
!+            EACH ELEMENTARY MATRIX WAS FACTORISED IN THE FORM:
!+
!+            LE X DE X UE
!+
!+            LE : LOWER TRIANGULAR WITH 1 ON THE DIAGONAL
!+            DE : DIAGONAL
!+            UE : UPPER TRIANGULAR WITH 1 ON THE DIAGONAL
!+
!+                                                T
!+            IF THE MATRIX IS SYMMETRICAL : LE =  UE
!
!code
!+-----------------------------------------------------------------------
!+  MEANING OF IELM :
!+
!+  TYPE OF ELEMENT      NUMBER OF POINTS      CODED IN THIS SUBROUTINE
!+
!+  11 : P1 TRIANGLE            3                       YES
!+  12 : QUASI-BUBBLE TRIANGLE  4                       YES
!+  21 : Q1 QUADRILATERAL       4                       YES
!+  41 : TELEMAC-3D PRISMS      6                       YES
!+
!+-----------------------------------------------------------------------
!
!history  J-M HERVOUET (LNH)
!+        23/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |<--| MATRIX IN LDU FORM
!| B              |<--| RIGHT-HAND SIDE OF THE LINEAR SYSTEM TO BE SOLVED
!| COPY           |-->| IF .TRUE. B IS COPIED INTO X TO START WITH
!| DITR           |-->| CHARACTER, IF  'D' : DIRECT MATRIX A CONSIDERED
!|                |   |                'T' : TRANSPOSED MATRIX A CONSIDERED
!| MESH           |-->| MESH STRUCTURE
!| X              |<--| SOLUTION OF THE SYSTEM AX = B
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_puog => puog
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=1), INTENT(IN) :: DITR
!
      LOGICAL, INTENT(IN) :: COPY
!
!-----------------------------------------------------------------------
!
!  VECTORS STRUCTURES
!
      TYPE(bief_obj), INTENT(INOUT) :: X
      TYPE(bief_obj), INTENT(INOUT) :: B
!
!-----------------------------------------------------------------------
!
!  MESH STRUCTURE
!
      TYPE(bief_mesh), INTENT(INOUT) :: MESH
!
!-----------------------------------------------------------------------
!
!  MATRIX STRUCTURE
!
      TYPE(bief_obj), INTENT(IN) :: A
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER S,SA,I
!
!-----------------------------------------------------------------------
!
      IF(x%TYPE.EQ.4) THEN
        s = x%N
      ELSE
        s = 0
      ENDIF
!
!     CASE WHERE THE SYSTEM IS A BLOCK BUT ONLY ONE PRECONDITIONING
!     MATRIX IS USED
!
      IF(a%TYPE.EQ.3) THEN
        sa = 0
      ELSEIF(a%TYPE.EQ.4) THEN
        sa = a%N
      ELSE
        WRITE(lu,400) a%TYPE
400     FORMAT(1x,'PUOG (BIEF) :',1i6,' UNEXPECTED TYPE FOR A.')
        CALL plante(0)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(s.EQ.0.AND.sa.EQ.0) THEN
!
!     CASE WHERE A IS A SIMPLE MATRIX AND X A SIMPLE VECTOR
!
        CALL puog1(x, a,b ,ditr,mesh,copy)
!
      ELSEIF(s.GT.0.AND.s.EQ.sa) THEN
!
!     CASE WHERE THE BLOCK A ONLY CONTAINS DIAGONALS
!
        DO i=1,s
          CALL puog1( x%ADR(i)%P,
     &                a%ADR(i)%P,
     &                b%ADR(i)%P,
     &                ditr,mesh,copy)
        ENDDO ! I
!
      ELSEIF(s.GT.0.AND.s**2.EQ.sa) THEN
!
!     CASE WHERE THE BLOCK A CONTAINS AS MANY MATRICES AS THERE ARE
!     IN THE WHOLE SYSTEM: ONLY TAKES THE DIAGONALS
!
        DO i=1,s
          CALL puog1(x%ADR(i)%P,
     &                a%ADR(1+(s+1)*(i-1))%P,
     &                b%ADR(i)%P,
     &                ditr,mesh,copy)
        ENDDO ! I
!
!     CASE WHERE A IS A SINGLE MATRIX AND X A BLOCK
!
      ELSEIF(s.GT.0.AND.sa.EQ.0) THEN
!
        DO i=1,s
          CALL puog1( x%ADR(i)%P,
     &                a,
     &                b%ADR(i)%P,
     &                ditr,mesh,copy)
        ENDDO ! I
!
      ELSE
        WRITE(lu,401)
401     FORMAT(1x,'PUOG (BIEF) : UNEXPECTED CASE')
        CALL plante(0)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END