presel.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE presel
!                       *****************
!
     &(ikle,trav1,nelem,nelmax,ndp,texte,nbfond,sorleo,color,
     & nsfond,nvarin,nvarou,maille)
!
!***********************************************************************
! PROGICIEL : STBTEL V5.2    07/12/88    J-M HERVOUET (LNH) 30 87 80 18
!                            19/02/93    J-M JANIN    (LNH) 30 87 72 84
!                                        A   WATRIN
!***********************************************************************
!
!  FONCTION  :  PREPARATION DE DONNEES AVANT L'APPEL DE FMTSEL
!
!-----------------------------------------------------------------------
!                             ARGUMENTS
! .________________.____.______________________________________________
! |      NOM       |MODE|                   ROLE
! |________________|____|______________________________________________
! |________________|____|______________________________________________
! MODE : -->(DONNEE NON MODIFIEE), <--(RESULTAT), <-->(DONNEE MODIFIEE)
!-----------------------------------------------------------------------
!
! APPELE PAR : PREDON
! APPEL DE : -
!
!***********************************************************************
!
      USE declarations_special
      IMPLICIT NONE
!
      INTEGER, INTENT(IN) :: NDP,NELEM,NELMAX,NBFOND,NVARIN
      INTEGER, INTENT(INOUT) :: NSFOND,NVAROU
      INTEGER, INTENT(INOUT) :: TRAV1(nelem,ndp)
      INTEGER, INTENT(IN) :: IKLE(nelmax,ndp)
      CHARACTER(LEN=32), INTENT(INOUT) :: TEXTE(26)
      CHARACTER(LEN=9), INTENT(IN) :: MAILLE
      LOGICAL, INTENT(INOUT) :: SORLEO(26),COLOR
!
      INTEGER I,IDP,IELEM
!
!-----------------------------------------------------------------------
!
!  IKLE EST REFAIT EN FONCTION DU NOMBRE DEFINITIF D'ELEMENTS
!  LE RESULTAT EST MIS DANS TRAV1.
!
      DO ielem = 1 , nelem
        DO idp = 1 , ndp
          trav1(ielem,idp) = ikle(ielem,idp)
        ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!
!  NOMS DES VARIABLES QUI SERONT DANS LE FICHIER DE GEOMETRIE
!  TABLEAUX INDIQUANT SI ELLES SERONT ECRITES.
!
      DO i = 1 , 26
        sorleo(i) = .false.
      ENDDO
!
      nvarou = nvarin
      IF (nvarou.GT.0) THEN
        DO i = 1 , nvarou
          sorleo(i) = .true.
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
!  RAJOUT DU FOND PUIS DE LA COULEUR DES NOEUDS PUIS D'UNE VARIABLE
!  BIDON SI NECESSAIRE DANS LES VARIABLES DE SORTIE
!
      IF (nbfond.GT.0.AND.nsfond.EQ.0.AND.nvarou.LT.26) THEN
        nvarou = nvarou + 1
        sorleo(nvarou) = .true.
        IF (lng.EQ.lng_fr)
     &    texte(nvarou)='FOND                            '
        IF (lng.EQ.lng_en)
     &    texte(nvarou)='BOTTOM                          '
        nsfond = nvarou
      ELSEIF (nbfond.EQ.0) THEN
        nsfond = 0
      ENDIF
!
      IF (color) THEN
        IF (nvarou.LT.26) THEN
          nvarou = nvarou + 1
          sorleo(nvarou) = .true.
          texte(nvarou) = 'COULEUR                         '
        ELSE
          color = .false.
        ENDIF
      ENDIF
!
      IF(nvarou.EQ.0) THEN
        sorleo(1) = .true.
        IF(maille.NE.'ADCIRC') THEN
          texte(1) = 'MAILLAGE                        '
        ELSE
          IF (lng.EQ.lng_fr) texte(1)='FOND                            '
          IF (lng.EQ.lng_en) texte(1)='BOTTOM                          '
        ENDIF
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END