prenl2.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE prenl2
!                       *****************
!
     &( iangnl, coefnl, ndire , nf    , raisf , xlamd , xmu   )
!
!***********************************************************************
! TOMAWAC   V6P1                                   22/06/2011
!***********************************************************************
!
!brief   PREPARES THE COMPUTATION FOR THE NON-LINEAR INTERACTION
!+                SOURCE TERM BETWEEN QUADRUPLETS USING THE MDIA METHOD
!+                ("MULTIPLE DISCRETE INTERACTION APPROXIMATION")
!+                PROPOSED BY TOLMAN (2004)
!+
!+
!+            PROCEDURE SPECIFIC TO THE CASE WHERE THE FREQUENCIES
!+                FOLLOW A GEOMETRICAL PROGRESSION AND THE DIRECTIONS
!+                ARE EVENLY DISTRIBUTED OVER [0;2.PI].
!
!+note    THIS SUBROUTINE IS TO BE USED IN CONJONCT
!+          SUBROUTINE QNLIN2, WHICH IT OPTIMISES.
!
!reference   TOLMAN H.L. (2004):
!+             "INVERSE MODELING OF DISCRETE INTERACTION APPROXIMATIONS
!+             FOR NONLINEAR INTERACTIONS IN WIND WAVES". OCEAN
!+             MODELLING, 6, 405-422
!
!history  E. GAGNAIRE-RENOU
!+        04/2011
!+        V6P1
!+   CREATED
!
!history  G.MATTAROLO (EDF - LNHE)
!+        22/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COEFNL         |<--| COEFFICIENTS USED FOR DIA METHOD
!| IANGNL         |<--| ANGUAR INDICES TABLE
!| NF             |-->| NUNMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| RAISF          |-->| FREQUENTIAL RATIO
!| XLAMD          |-->| DIA STANDARD CONFIGURATION LAMBDA COEFFICIENT
!| XMU            |-->| COEFFICIENTS FOR MDIA METHOD
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!                                                                     !
!  APPELS :    - PROGRAMME(S) APPELANT  :  WAC                        !
!  ********    - PROGRAMME(S) APPELE(S) :  ANGLES, INTANG             !
!                                                                     !
!
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """""""""""""""""""""
      INTEGER, INTENT(IN)             :: NDIRE , NF
      INTEGER, INTENT(INOUT)          :: IANGNL(ndire,16)
      DOUBLE PRECISION, INTENT(IN)    :: RAISF , XLAMD , XMU
      DOUBLE PRECISION, INTENT(INOUT) :: COEFNL(32)

!.....LOCAL VARIABLES
!     """"""""""""""""""
      INTEGER  JP
      DOUBLE PRECISION DELTA1, DELTA2, DTMOIN, DTPLUS, DTETAD, XXXX
      DOUBLE PRECISION APLUS , AMOIN , BPLUS , BMOIN , FPLUS , FMOIN
!
!
!
!     ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!     ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!     ++++      COMPUTATION FOR K1 AND K2 WITH THE MU VALUE     ++++
!     ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!     ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
      xxxx=xmu
!
!=====!---------------------------------------------------!
!  1  ! COMPUTATIONS RELATED TO ANGULAR INTERPOLATION     !
!=====!---------------------------------------------------!
!
!.....1.1 DETERMINES RESONANT DIRECTIONS
!         (WITH THE CONVENTION  0 < DTPLUS < DTMOIN)
!     """""""""""""""""""""""""""""""""""""""""""""
      CALL  angles( xxxx  , dtplus, dtmoin)
!
!.....1.2 DETERMINES ANGULAR INDICES FOR THE 'STANDARD' CONFIGURATION
!         (CORRESPONDING TO (-DTPLUS,DTMOIN))
!     """"""""""""""""""""""""""""""""""""""""""""""""""""""""
      IF (xxxx.GT.1.d-6) THEN
        delta1=-dtplus
        delta2= dtmoin
        DO jp=1,ndire
          CALL intang(iangnl(jp, 2), iangnl(jp, 1), jp , ndire , delta1)
          CALL intang(iangnl(jp, 3), iangnl(jp, 4), jp , ndire , delta2)
        ENDDO
      ELSE
        DO jp=1,ndire
          iangnl(jp, 1)=jp
          iangnl(jp, 2)=jp-1
          IF (jp.EQ.1) iangnl(jp, 2)=ndire
          iangnl(jp, 3)=jp
          iangnl(jp, 4)=jp+1
          IF (jp.EQ.ndire) iangnl(jp, 4)=1
        ENDDO
      ENDIF
!
!.....1.3 DETERMINES ANGULAR INDICES FOR THE 'IMAGE' CONFIGURATION
!         (CORRESPONDING TO (DTPLUS,-DTMOIN))
!     """""""""""""""""""""""""""""""""""""""""""""""""""""
      IF (xxxx.GT.1.d-6) THEN
        delta1= dtplus
        delta2=-dtmoin
        DO jp=1,ndire
        CALL intang( iangnl(jp, 5), iangnl(jp, 6), jp , ndire , delta1)
        CALL intang( iangnl(jp, 8), iangnl(jp, 7), jp , ndire , delta2)
        ENDDO
      ELSE
        DO jp=1,ndire
          iangnl(jp, 5)=jp
          iangnl(jp, 6)=jp+1
          IF (jp.EQ.ndire) iangnl(jp, 6)=1
          iangnl(jp, 7)=jp
          iangnl(jp, 8)=jp-1
          IF (jp.EQ.1) iangnl(jp, 8)=ndire
        ENDDO
      ENDIF
!
!.....1.4 DETERMINES COEFFICIENTS OF ANGULAR INTERPOLATION
!     """""""""""""""""""""""""""""""""""""""""""
      dtetad=360.d0/dble(ndire)
      aplus=dtplus/dtetad-dble(int(dtplus/dtetad))
      amoin=dtmoin/dtetad-dble(int(dtmoin/dtetad))
!
!
!=====!---------------------------------------------------!
!  2  ! COMPUTATIONS RELATED TO FREQUENCY INTERPOLATION   !
!=====!---------------------------------------------------!
      fplus=log(1.d0+xxxx)/log(raisf)
      fmoin=log(1.d0-xxxx)/log(raisf)
      bplus=(raisf**(fplus-int(fplus)     )-1.d0)/(raisf-1.d0)
      bmoin=(raisf**(fmoin-int(fmoin)+1.d0)-1.d0)/(raisf-1.d0)
!
!
!=====!---------------------------------------------------!
!  3  ! ASSIGNS THE COEFFICIENTS FOR QNLIN2               !
!=====!---------------------------------------------------!
      coefnl( 1)=(1.d0-aplus) * (1.d0-bplus)
      coefnl( 2)=      aplus  * (1.d0-bplus)
      coefnl( 3)=(1.d0-aplus) *       bplus
      coefnl( 4)=      aplus  *       bplus
      coefnl( 5)=(1.d0-amoin) * (1.d0-bmoin)
      coefnl( 6)=      amoin  * (1.d0-bmoin)
      coefnl( 7)=(1.d0-amoin) *       bmoin
      coefnl( 8)=      amoin  *       bmoin
      coefnl( 9)=fplus
      coefnl(10)=fmoin
      coefnl(11)=1.d0/(1.d0+xxxx)**4
      coefnl(12)=1.d0/(1.d0-xxxx)**4
      coefnl(13)=dble(1)
      coefnl(14)=dble(nf+int(1.d0-fmoin))
!
!
!
!     ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!     ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!     ++++    COMPUTATION FOR K1 AND K2 WITH THE LAMDA VALUE    ++++
!     ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!     ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
      xxxx=xlamd
!
!=====!---------------------------------------------------!
!  1  ! COMPUTATIONS RELATED TO ANGULAR INTERPOLATION     !
!=====!---------------------------------------------------!
!
!.....1.1 DETERMINES RESONANT DIRECTIONS
!         (WITH THE CONVENTION  0 < DTPLUS < DTMOIN)
!     """""""""""""""""""""""""""""""""""""""""""""
      CALL  angles( xxxx  , dtplus, dtmoin)
!
!.....1.2 DETERMINES ANGULAR INDICES FOR THE 'STANDARD' CONFIGURATION
!         (CORRESPONDING TO (-DTPLUS,DTMOIN))
!     """"""""""""""""""""""""""""""""""""""""""""""""""""""""
      IF (xxxx.GT.1.d-6) THEN
        delta1=-dtplus
        delta2= dtmoin
        DO jp=1,ndire
          CALL intang(iangnl(jp,10), iangnl(jp, 9), jp , ndire , delta1)
          CALL intang(iangnl(jp,11), iangnl(jp,12), jp , ndire , delta2)
        ENDDO
      ELSE
        DO jp=1,ndire
          iangnl(jp, 9)=jp
          iangnl(jp,10)=jp-1
          IF (jp.EQ.1) iangnl(jp,10)=ndire
          iangnl(jp,11)=jp
          iangnl(jp,12)=jp+1
          IF (jp.EQ.ndire) iangnl(jp,12)=1
        ENDDO
      ENDIF
!
!.....1.3 DETERMINES ANGULAR INDICES FOR THE 'IMAGE' CONFIGURATION
!         (CORRESPONDING TO (DTPLUS,-DTMOIN))
!     """""""""""""""""""""""""""""""""""""""""""""""""""""
      IF (xxxx.GT.1.d-6) THEN
        delta1= dtplus
        delta2=-dtmoin
        DO jp=1,ndire
          CALL intang(iangnl(jp,13), iangnl(jp,14), jp , ndire , delta1)
          CALL intang(iangnl(jp,16), iangnl(jp,15), jp , ndire , delta2)
        ENDDO
      ELSE
        DO jp=1,ndire
          iangnl(jp,13)=jp
          iangnl(jp,14)=jp+1
          IF (jp.EQ.ndire) iangnl(jp,14)=1
          iangnl(jp,15)=jp
          iangnl(jp,16)=jp-1
          IF (jp.EQ.1) iangnl(jp,16)=ndire
        ENDDO
      ENDIF
!
!.....1.4 DETERMINES COEFFICIENTS OF ANGULAR INTERPOLATION
!     """""""""""""""""""""""""""""""""""""""""""
      dtetad=360.d0/dble(ndire)
      aplus=dtplus/dtetad-dble(int(dtplus/dtetad))
      amoin=dtmoin/dtetad-dble(int(dtmoin/dtetad))
!
!
!=====!---------------------------------------------------!
!  2  ! COMPUTATIONS RELATED TO FREQUENCY INTERPOLATION   !
!=====!---------------------------------------------------!
      fplus=log(1.d0+xxxx)/log(raisf)
      fmoin=log(1.d0-xxxx)/log(raisf)
      bplus=(raisf**(fplus-int(fplus)     )-1.d0)/(raisf-1.d0)
      bmoin=(raisf**(fmoin-int(fmoin)+1.d0)-1.d0)/(raisf-1.d0)
!
!
!=====!---------------------------------------------------!
!  3  ! ASSIGNS THE COEFFICIENTS FOR QNLIN2               !
!=====!---------------------------------------------------!
      coefnl(17)=(1.d0-aplus) * (1.d0-bplus)
      coefnl(18)=      aplus  * (1.d0-bplus)
      coefnl(19)=(1.d0-aplus) *       bplus
      coefnl(20)=      aplus  *       bplus
      coefnl(21)=(1.d0-amoin) * (1.d0-bmoin)
      coefnl(22)=      amoin  * (1.d0-bmoin)
      coefnl(23)=(1.d0-amoin) *       bmoin
      coefnl(24)=      amoin  *       bmoin
      coefnl(25)=fplus
      coefnl(26)=fmoin
      coefnl(27)=1.d0/(1.d0+xxxx)**4
      coefnl(28)=1.d0/(1.d0-xxxx)**4
      coefnl(29)=dble(1)
      coefnl(30)=dble(nf+int(1.d0-fmoin))
!
!
      RETURN
      END