prenl1.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE prenl1
!                   *****************
!
     &( iangnl, coefnl, ndire , nf    , raisf , xlamd )
!
!***********************************************************************
! TOMAWAC   V6P1                                   22/06/2011
!***********************************************************************
!
!brief    PREPARES THE COMPUTATION FOR THE NON-LINEAR INTERACTION
!+                SOURCE TERM BETWEEN QUADRUPLETS USING THE DIA METHOD
!+               ("DISCRETE INTERACTION APPROXIMATION") PROPOSED BY
!+                HASSELMANN AND HASSELMANN (1985).
!+
!+
!+            PROCEDURE SPECIFIC TO THE CASE WHERE THE FREQUENCIES
!+                FOLLOW A GEOMETRICAL PROGRESSION AND THE DIRECTIONS
!+                ARE EVENLY DISTRIBUTED OVER [0;2.PI].
!
!note     THIS SUBROUTINE IS TO BE USED IN CONJONCTION WITH THE
!+          SUBROUTINE QNLIN1, WHICH IT OPTIMISES.
!
!reference  HASSELMANN S., HASSELMANN K. ET AL.(1985) :
!+                     "COMPUTATIONS AND PARAMETERIZATIONS OF THE NONLINEAR
!+                      ENERGY TRANSFER IN GRAVITY-WAVE SPECTRUM. PART1 :
!+                      A NEW METHOD FOR EFFICIENT COMPUTATION OF THE EXACT
!+                      NON-LINEAR TRANSFER INTEGRAL". JPO, VOL 15, PP 1369-1377.
!reference    HASSELMANN S., HASSELMANN K. ET AL.(1985) :
!+                     "COMPUTATIONS AND PARAMETERIZATIONS OF THE NONLINEAR
!+                      ENERGY TRANSFER IN GRAVITY-WAVE SPECTRUM. PART2 :
!+                      PARAMETERIZATIONS OF THE NONLINEAR ENERGY TRANSFER
!+                      FOR APPLICATION IN WAVE MODELS". JPO, VOL 15, PP 1378-1391.
!
!history  M. BENOIT
!+        26/06/96
!+        V1P2
!+   CREATED
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        22/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COEFNL         |<--| COEFFICIENTS USED FOR DIA METHOD
!| IANGNL         |<--| ANGULAR INDICES TABLE
!| NF             |-->| NUNMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| RAISF          |-->| FREQUENTIAL RATIO
!| XLAMD          |-->| DIA STANDARD CONFIGURATION LAMBDA COEFFICIENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_tomawac, ex_prenl1 => prenl1
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """""""""""""""""""""
      INTEGER, INTENT(IN)             ::  NDIRE , NF
      INTEGER, INTENT(INOUT)          ::  IANGNL(ndire,8)
      DOUBLE PRECISION, INTENT(IN)    :: RAISF , XLAMD
      DOUBLE PRECISION, INTENT(INOUT) :: COEFNL(16)
!
!.....LOCAL VARIABLES
!     """"""""""""""""""
      INTEGER  JP
      DOUBLE PRECISION DELTA1, DELTA2, DTMOIN, DTPLUS, DTETAD
      DOUBLE PRECISION APLUS , AMOIN , BPLUS , BMOIN , FPLUS , FMOIN
!
!=====C---------------------------------------------------C
!  1  C COMPUTATIONS RELATED TO ANGULAR INTERPOLATION     C
!=====C---------------------------------------------------C
!
!.....1.1 DETERMINES RESONANT DIRECTIONS
!         (WITH THE CONVENTION  0
!     """""""""""""""""""""""""""""""""""""""""""""
      CALL  angles( xlamd , dtplus, dtmoin)
!
!.....1.2 DETERMINES ANGULAR INDICES FOR THE 'STANDARD' CONFIGURATION
!         (CORRESPONDING TO (-DTPLUS,DTMOIN))
!     """"""""""""""""""""""""""""""""""""""""""""""""""""""""
      delta1=-dtplus
      delta2= dtmoin
      DO jp=1,ndire
        CALL intang( iangnl(jp,2) , iangnl(jp,1) , jp , ndire , delta1)
        CALL intang( iangnl(jp,3) , iangnl(jp,4) , jp , ndire , delta2)
      ENDDO ! JP
!
!.....1.3 DETERMINES ANGULAR INDICES FOR THE 'IMAGE' CONFIGURATION
!         (CORRESPONDING TO (DTPLUS,-DTMOIN))
!     """""""""""""""""""""""""""""""""""""""""""""""""""""
      delta1= dtplus
      delta2=-dtmoin
      DO jp=1,ndire
        CALL intang( iangnl(jp,5) , iangnl(jp,6) , jp , ndire , delta1)
        CALL intang( iangnl(jp,8) , iangnl(jp,7) , jp , ndire , delta2)
      ENDDO ! JP
!
!.....1.4 DETERMINES COEFFICIENTS OF ANGULAR INTERPOLATION
!     """""""""""""""""""""""""""""""""""""""""""
      dtetad=360.d0/dble(ndire)
      aplus=dtplus/dtetad-dble(int(dtplus/dtetad))
      amoin=dtmoin/dtetad-dble(int(dtmoin/dtetad))
!
!
!=====C---------------------------------------------------C
!  2  C COMPUTATIONS RELATED TO FREQUENCY INTERPOLATION   C
!=====C---------------------------------------------------C
      fplus=log(1.d0+xlamd)/log(raisf)
      fmoin=log(1.d0-xlamd)/log(raisf)
      bplus=(raisf**(fplus-int(fplus)     )-1.d0)/(raisf-1.d0)
      bmoin=(raisf**(fmoin-int(fmoin)+1.d0)-1.d0)/(raisf-1.d0)
!
!
!=====C---------------------------------------------------C
!  3 C ASSIGNS THE COEFFICIENTS FOR QNLIN1                C
!=====C---------------------------------------------------C
      coefnl( 1)=(1.d0-aplus) * (1.d0-bplus)
      coefnl( 2)=      aplus  * (1.d0-bplus)
      coefnl( 3)=(1.d0-aplus) *       bplus
      coefnl( 4)=      aplus  *       bplus
      coefnl( 5)=(1.d0-amoin) * (1.d0-bmoin)
      coefnl( 6)=      amoin  * (1.d0-bmoin)
      coefnl( 7)=(1.d0-amoin) *       bmoin
      coefnl( 8)=      amoin  *       bmoin
      coefnl( 9)=fplus
      coefnl(10)=fmoin
      coefnl(11)=1.d0/(1.d0+xlamd)**4
      coefnl(12)=1.d0/(1.d0-xlamd)**4
      coefnl(13)=dble(1)
      coefnl(14)=dble(nf+int(1.d0-fmoin))
!
      RETURN
      END