predes.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE predes
!                   *****************
!
     &(llt,aat,yagout,code)
!
!***********************************************************************
! SISYPHE   V6P2                                   01/07/2012
!***********************************************************************
!
!brief    PREPARES THE VARIABLES WHICH WILL BE WRITTEN TO
!+                THE RESULTS FILE OR TO THE LISTING.
!
!history  E. PELTIER; C. LENORMANT; J.-M. HERVOUET
!+        11/09/1995
!+
!+
!
!history  JMH
!+        07/12/2009
!+        V6P0
!+   KS SET TO 0 IF LLT=0
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  P. TASSI (EDF)
!+        01/07/2012
!+        V6P2
!+   Bug correction discharge along y
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AAT            |-->| CURRENT TIME (FOR BUILDING SOLUTIONS)
!| CODE           |-->| NAME OF CALLING PROGRAMME (TELEMAC2D OR 3D)
!| LLT            |-->| LOCAL LT (MAY BE LT-1+PERCOU)
!| YAGOUT         |-->| LOGICAL: IF YES GRAPHIC OUTPUT ANYWAY
!|                |   | (STEERED BY T2D)
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_sisyphe
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER          , INTENT(IN) :: LLT
      DOUBLE PRECISION , INTENT(IN) :: AAT
      CHARACTER(LEN=24), INTENT(IN) :: CODE
      LOGICAL          , INTENT(IN) :: YAGOUT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER LTT,I,J
      LOGICAL IMP,LEO
!
!-----------------------------------------------------------------------
!
!     THE OUTPUT VARIABLES ARE BUILT ONLY IF NECESSARY, HENCE THE
!     FOLLOWING TESTS, WHICH MUST BE THE SAME AS IN DESIMP (BIEF LIBRARY)
!
      imp=.false.
      leo=.false.
      ltt=(llt/lispr)*lispr
      IF(llt.EQ.ltt.AND.llt.GE.ptinil) imp=.true.
      ltt=(llt/leopr)*leopr
      IF(llt.EQ.ltt.AND.llt.GE.ptinig) leo=.true.
!     IF CODE =TELEMAC2D OUTOUT IS MANAGED BY T2D
      IF(code(8:9).EQ.'2D')leo=yagout
!
!     NO PRINTOUTS REUIRED: LEAVING
      IF (.NOT.(leo.OR.imp)) GO TO 1000
!
!=======================================================================
!     COMPUTES SECONDARY VARIABLES
!=======================================================================
!
!     FREE SURFACE: H+ZF
!
      IF((leo.AND.sorleo(4)).OR.(imp.AND.sorimp(4))) THEN
        CALL os('X=Y+Z   ',x=z,y=hn,z=zf)
      ENDIF
!
!     DISCHARGE
!
      IF((leo.AND.sorleo(6)).OR.(imp.AND.sorimp(6))) THEN
        DO i=1,npoin
          q%R(i)=hn%R(i)*sqrt(u2d%R(i)**2+v2d%R(i)**2)
        ENDDO
      ENDIF
!
!     DISCHARGE ALONG X
!
      IF((leo.AND.sorleo(7)).OR.(imp.AND.sorimp(7))) THEN
        CALL os('X=YZ    ',x=qu,y=u2d,z=hn)
      ENDIF
!
!     DISCHARGE ALONG Y
!
      IF((leo.AND.sorleo(8)).OR.(imp.AND.sorimp(8))) THEN
        CALL os('X=YZ    ',x=qv,y=v2d,z=hn)
      ENDIF
!
!=======================================================================
!
!     VARIABLES WHICH ARE NOT INITIALISED AT THE FIRST CALL OF PREDES
!
      IF(llt.EQ.0) THEN
        IF((leo.AND.sorleo(19)).OR.(imp.AND.sorimp(19))) THEN
          CALL os('X=0     ',x=ks)
        ENDIF
      ENDIF
!
!=======================================================================
! UPDATE THE POINTERS TO THE DIFFERENTIATED VARIABLES
!=======================================================================
!
!     TODO: TRY NOT USING THE HARDCODED NUMBER 28
!
      j = 28+max(4,npriv)+nsicla*(nomblay+4)+2*nomblay+varcl%N
      DO i = 1,nadvar
        IF((leo.AND.sorleo(j)).OR.(imp.AND.sorimp(j))) THEN
          CALL ad_get_sisyphe(i,advar%ADR(i)%P)
          j = j + 1
        ENDIF
      ENDDO
!
!=======================================================================
!
      ! USER FUNCTION
      CALL user_predes(llt,aat,yagout,code,leo,imp)
1000  CONTINUE
!
!=======================================================================
!
      RETURN
      END