precd9.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE precd9
!                   *****************
!
     &(x1,x2,x3,a11,a12,a13,a21,a22,a23,a31,a32,a33,
     & b1,b2,b3,d1,d2,d3,mesh,precon,prexsm,diadon)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    DIAGONAL PRECONDITIONING OF A SYSTEM A X = B
!+               (SEE EXPLANATIONS IN PRECDT).
!+
!+            A IS A 9-MATRIX BLOCK HERE.
!
!history  J-M HERVOUET (LNHE)
!+        06/07/2009
!+        V5P0
!+   First version (of the header...)
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        08/12/2015
!+        V7P1
!+   Rebuilding the diagonal with MESH%IFAC in parallel in case of
!+   diagonal preconditioning and DIADON=FALSE.
!+   Correction of a bug in parallel with preconditioning 5.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A11            |<->| TERM (1,1) OF MATRIX
!| ...            |<->| ...
!| A33            |<->| TERM (3,3) OF MATRIX
!| B1             |<->| FIRST RIGHT-HAND SIDE
!| B2             |<->| SECOND RIGHT-HAND SIDE
!| B3             |<->| THIRD RIGHT-HAND SIDE
!| D1             |<--| DIAGONAL MATRIX
!| D2             |<--| DIAGONAL MATRIX
!| D3             |<--| DIAGONAL MATRIX
!| DIADON         |-->| .TRUE. : DIAGONALS ARE GIVEN
!| MESH           |-->| MESH STRUCTURE
!| PRECON         |-->| CHOICE OF PRECONDITIONING
!| PREXSM         |-->| .TRUE. : PRECONDITIONING X1,X2 AND B1,B2
!| X1             |<->| FIRST INITIAL GUESS
!| X2             |-->| SECOND INITIAL GUESS
!| X3             |-->| THIRD INITIAL GUESS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_precd9 => precd9
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: PRECON
      LOGICAL, INTENT(IN) :: PREXSM,DIADON
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!  VECTOR STRUCTURES
!
      TYPE(bief_obj), INTENT(INOUT) :: X1,X2,X3,B1,B2,B3,D1,D2,D3
!
!-----------------------------------------------------------------------
!
!  MATRIX STRUCTURES
!
      TYPE(bief_obj), INTENT(INOUT) :: A11,A12,A13,A21
      TYPE(bief_obj), INTENT(INOUT) :: A22,A23,A31,A32,A33
!
!-----------------------------------------------------------------------
!
!  MESH STRUCTURE
!
      TYPE(bief_mesh), INTENT(INOUT) :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I
!
!-----------------------------------------------------------------------
!
!  PREPARES THE DIAGONALS:
!
      IF(.NOT.diadon) THEN
!
!       COPY
!
        CALL os( 'X=Y     ' , x=d1 , y=a11%D )
        CALL os( 'X=Y     ' , x=d2 , y=a22%D )
        CALL os( 'X=Y     ' , x=d3 , y=a33%D )
!
!       PARALLEL MODE: COMPLETE DIAGONAL BEFORE GOING FURTHER
!
        IF(ncsize.GT.1) THEN
          CALL parcom(d1,2,mesh)
          CALL parcom(d2,2,mesh)
          CALL parcom(d3,2,mesh)
        ENDIF
!
!       POSSIBLY ABSOLUTE VALUES
!
        IF(precon.EQ.5) THEN
          CALL os( 'X=ABS(Y)' , x=d1 , y=d1 )
          CALL os( 'X=ABS(Y)' , x=d2 , y=d2 )
          CALL os( 'X=ABS(Y)' , x=d3 , y=d3 )
        ENDIF
!
!       SQUARE ROOTS
!
        CALL os( 'X=SQR(Y)' , x=d1 , y=d1 )
        CALL os( 'X=SQR(Y)' , x=d2 , y=d2 )
        CALL os( 'X=SQR(Y)' , x=d3 , y=d3 )
!
!-----------------------------------------------------------------------
!                                                    -1
!  CHANGE OF VARIABLES (D1,D2 AND D3 ACTUALLY HOLD D1 ,...)
!
        IF(prexsm) THEN
          CALL os( 'X=XY    ' , x=x1 , y=d1 )
          CALL os( 'X=XY    ' , x=x2 , y=d2 )
          CALL os( 'X=XY    ' , x=x3 , y=d3 )
        ENDIF
!
!-----------------------------------------------------------------------
!
!  COMPUTES THE INVERSE OF THE SQUARE ROOTS OF THE DIAGONALS
!  THIS GIVES BACK TRUE D1,D2,D3 AND NOT D1,D2,D3 INVERTED
!
        CALL os( 'X=1/Y   ', x=d1, y=d1, iopt=2,
     &                       infini=1.d0, zero=1.d-10)
        CALL os( 'X=1/Y   ', x=d2, y=d2, iopt=2,
     &                       infini=1.d0, zero=1.d-10)
        CALL os( 'X=1/Y   ', x=d3, y=d3, iopt=2,
     &                       infini=1.d0, zero=1.d-10)
!
      ELSE
!
!  CASE WHERE D1,D2,D3 ARE GIVEN, CHANGE OF VARIABLES
!  CHANGE OF VARIABLE (D1,D2,D3 REALLY HOLD D1,D2,D3)
!
        IF(prexsm) THEN
          CALL os( 'X=Y/Z   ' , x=x1 , y=x1 , z=d1 )
          CALL os( 'X=Y/Z   ' , x=x2 , y=x2 , z=d2 )
          CALL os( 'X=Y/Z   ' , x=x3 , y=x3 , z=d3 )
        ENDIF
!
      ENDIF
!
!=======================================================================
! PRECONDITIONING OF A11 :
!=======================================================================
!
      CALL om('M=DMD   ', m=a11, d=d1, mesh=mesh)
!
!=======================================================================
! PRECONDITIONING OF A12 :
!=======================================================================
!
      CALL om('M=DM    ', m=a12, d=d1, mesh=mesh)
      CALL om('M=MD    ', m=a12, d=d2, mesh=mesh)
!
!=======================================================================
! PRECONDITIONING OF A13 :
!=======================================================================
!
      CALL om('M=DM    ', m=a13, d=d1, mesh=mesh)
      CALL om('M=MD    ', m=a13, d=d3, mesh=mesh)
!
!=======================================================================
! PRECONDITIONING OF A21 :
!=======================================================================
!
      CALL om('M=DM    ', m=a21, d=d2, mesh=mesh)
      CALL om('M=MD    ', m=a21, d=d1, mesh=mesh)
!
!=======================================================================
! PRECONDITIONING OF A22 :
!=======================================================================
!
      CALL om('M=DMD   ', m=a22, d=d2, mesh=mesh)
!
!=======================================================================
! PRECONDITIONING OF A23 :
!=======================================================================
!
      CALL om('M=DM    ', m=a23, d=d2, mesh=mesh)
      CALL om('M=MD    ', m=a23, d=d3, mesh=mesh)
!
!=======================================================================
! PRECONDITIONING OF A31 :
!=======================================================================
!
      CALL om('M=DM    ', m=a31, d=d3, mesh=mesh)
      CALL om('M=MD    ', m=a31, d=d1, mesh=mesh)
!
!=======================================================================
! PRECONDITIONING OF A32 :
!=======================================================================
!
      CALL om('M=DM    ', m=a32, d=d3, mesh=mesh)
      CALL om('M=MD    ', m=a32, d=d2, mesh=mesh)
!
!=======================================================================
! PRECONDITIONING OF A33 :
!=======================================================================
!
      CALL om('M=DMD   ', m=a33, d=d3, mesh=mesh)
!
!=======================================================================
!
!     CASES WHERE THE DIAGONALS ARE KNOWN
!     (VALID ONLY WITH ONE SINGLE DOMAIN)
!
      IF(ncsize.LE.1.OR.nptir.EQ.0) THEN
!
!       IF PRECON = 2 OR 3
        IF(2*(precon/2).EQ.precon.AND..NOT.diadon) THEN
          a11%TYPDIA='I'
          a22%TYPDIA='I'
          a33%TYPDIA='I'
        ELSEIF(3*(precon/3).EQ.precon.AND..NOT.diadon) THEN
          a11%TYPDIA='I'
          a22%TYPDIA='I'
          a33%TYPDIA='I'
          a12%TYPDIA='0'
          a13%TYPDIA='0'
          a21%TYPDIA='0'
          a23%TYPDIA='0'
          a31%TYPDIA='0'
          a32%TYPDIA='0'
        ENDIF
!
      ELSE
!
!       CASE OF DIAGONAL=IDENTITY, BUT ONLY AFTER ASSEMBLING
!
        IF((2*(precon/2).EQ.precon.OR.3*(precon/3).EQ.precon).AND.
     &                                                .NOT.diadon) THEN
!         HERE THE DIAGONAL IS REDONE WITH IFAC, SO THAT A MATRIX-VECTOR
!         PRODUCT WILL LEAD TO A SUM OF THE SAME NUMBERS (BUT POSSIBLY
!         NOT IN THE SAME ORDER). OTHERWISE IT IS NOT SURE THAT THE
!         ASSEMBLED DIAGONAL WOULD GIVE EXACT 1.D0.
          DO i=1,a11%D%DIM1
            a11%D%R(i)=mesh%IFAC%I(i)
          ENDDO
          DO i=1,a22%D%DIM1
            a22%D%R(i)=mesh%IFAC%I(i)
          ENDDO
          DO i=1,a33%D%DIM1
            a33%D%R(i)=mesh%IFAC%I(i)
          ENDDO
        ENDIF
!
      ENDIF
!
!=======================================================================
!
! PRECONDITIONING OF THE SECOND MEMBER
!
      IF(prexsm) THEN
        CALL os( 'X=XY    ' , x=b1 , y=d1 )
        CALL os( 'X=XY    ' , x=b2 , y=d2 )
        CALL os( 'X=XY    ' , x=b3 , y=d3 )
      ENDIF
!
!=======================================================================
!
      RETURN
      END