partel_prelim.F

Go to the documentation of this file.

!                   *********************
                    PROGRAM partel_prelim
!                   *********************
!
!***********************************************************************
! PARALLEL   V6P2                                   20/02/2012
!***********************************************************************
!
!BRIEF    PREPROCESSING STEP BEFORE A PARALLEL COMPUTATION
!HISTORY   R. KOPMANN (BAW)
!+
!+
!+         FIRST  VERSION JANUARY-MARCH 2000
!
!HISTORY   JAJ
!+      12/12/2000
!+      SECOND VERSION PINXIT
!+     PARTITIONING OF GEOMETRY AND 2D RESULT FILES POSSIBLE

!HISTORY   JAJ
!+      22/02/2002
!+      THIRD VERSION
!+     ERRORS IN BC VALUES IN DECOMPOSED BC FILES REMOVED
!+     ERRONEOUS TREATMENT OF ISLANDS DEBUGGED
!
!HISTORY   J-M HERVOUET ; JAJ
!+      17/04/2002
!+     FOURTH VERSION
!+     PARTITIONING FOR 3D RESULT FILES DONE BY JMH
!+     INCLUDING BOTH PARTITIONING METHODS AND BEAUTIFYING BY JAJ
!
!HISTORY  J-M HERVOUET
!+     21/01/2003
!+     FIFTH VERSION
!+     CORRECTED A WRONG DIMENSION OF THE ARRAY CUT, AN ERROR
!+     OCCURING BY A LARGER NUMBER OF PROCESSORS
!
!HISTORY  JAJ; MATTHIEU GONZALES DE LINARES
!+        27/01/2003
!+        SIXTH VERSION
!+    CORRECTED A WRONG DIMENSION OF THE ARRAY ALLVAR
!
!HISTORY  J-M HERVOUET
!+       12/03/2003
!+      SEVENTH VERSION
!+      ALGORITHM CHANGED : A SEGMENT IS IN A SUBDOMAIN IF IT BELONGS
!+      TO AN ELEMENT IN THE SUBDOMAIN NOT IF THE 2 POINTS OF THE
!+      SEGMENT BELONG TO THE SUBDOMAIN.
!+       SPECIFIC ELEBD INCLUDED, ALL REFERENCE TO MPI OR BIEF REMOVED
!
!HISTORY  J-M HERVOUET
!+        01/09/2003
!+      EIGHTH VERSION
!+      UBOR AND VBOR INVERTED LINE 613 WHEN READING THE CLI FILE.
!
!HISTORY   C. MOULINEC, P. VEZOLLE, O. BOITEAU
!+
!+      NEXT VERSION
!+      SOME CHANGES
!
!HISTORY   C. DENIS (EDF-SINETICS)
!+        31/05/2010
!+      V6P2
!+      FURTHER DEVELOPPED IN ORDER TO DECREASE THE AMOOUT OF MEMORY
!
!HISTORY  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/02/2012
!+        V6P2
!+   CREATION OF DOXYGEN TAGS FOR AUTOMATED DOCUMENTATION AND
!+   CROSS-REFERENCING OF THE FORTRAN SOURCES
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!   MAXIMUM GEOMETRICAL MULTIPLICITY OF A NODE (VARIABLE AUSSI
!   PRESENTE DANS LA BIEF, NE PAS CHANGER L'UNE SANS L'AUTRE)
      INTEGER, PARAMETER :: NBMAXNSHARE =  10
!
      INTEGER, PARAMETER :: MAXNPROC = 100000 ! MAX PARTITION NUMBER [00000..99999]
      INTEGER, PARAMETER :: MAXADDCH = 10 ! MAX ADDED SUFFIX LENGTH
      INTEGER, PARAMETER :: MAXVAR = 100  ! MAX NUMBER OF VARIABLES
      INTEGER, PARAMETER :: MAXALLVARLENGTH = 3200 ! MAXVAR*32 FOR ALLVAR
!
      INTEGER NVAR, NPLAN
      INTEGER NELEM, NPOIN, NDP, NELEM2, NPOIN2, NDUM
      INTEGER IB(10)
!
      INTEGER, ALLOCATABLE :: IKLES(:)
      INTEGER, ALLOCATABLE :: IKLES3D(:)
      INTEGER, ALLOCATABLE :: IRAND(:)
!
      REAL, ALLOCATABLE    :: F(:,:)
!
      REAL TIMES
!
      INTEGER :: NINP=10
      INTEGER TIME(3), DATE(3)
!
      CHARACTER(LEN=80)  :: TITLE
      CHARACTER(LEN=32)  :: VARI
      CHARACTER(LEN=PATH_LEN)  :: NAMEINP
!
      INTEGER I, J, K, ERR
      INTEGER ISTOP, ISTART, ILOOP
      INTEGER I_LEN, I_S, I_SP, I_LENINP
!
      LOGICAL IS
!
!   METISOLOGY
!
      INTEGER NPARTS
      INTEGER, ALLOCATABLE :: EPART(:), NPART(:)
!
!----------------------------------------------------------------------
!
      lng=2 ! JE NE PARLE FRANCAIS, JE SUIS BARBARIEN
      lu=6  ! FORTRAN STANDARD OUPUT CHANNEL
!
! INTRODUCE YOURSELF
!
!      IF (ID .EQ. 0) THEN
!       WRITE(LU,*) ' '
!       WRITE(LU,*) '+-------------------------------------------------+'
!       WRITE(LU,*) '  PRELIMINARY TASK FOR PARTEL                    '
!       WRITE(LU,*) '  PARALLEL VERSION DEVELOPPED BY                   '
!       WRITE(LU,*) '  CHRISTOPHE DENIS  (SINETICS)'
!       WRITE(LU,*) '  PARTEL (C) COPYRIGHT 2000-2002 '
!       WRITE(LU,*) '  BUNDESANSTALT FUER WASSERBAU, KARLSRUHE'
!       WRITE(LU,*) ' '
!       WRITE(LU,*) '  METIS 4.0.1 (C) COPYRIGHT 1998 '
!       WRITE(LU,*) '  REGENTS OF THE UNIVERSITY OF MINNESOTA '
!       WRITE(LU,*) ' '
!       WRITE(LU,*) '  BIEF 5.9 (C) COPYRIGHT 2010 EDF'
!       WRITE(LU,*) '+-------------------------------------------------+'
!       WRITE(LU,*) '    LUN MAI 31 17:21:20 CEST 2010               '
!       WRITE(LU,*) ' '
!       WRITE(LU,*) '+-----------------------------------------------+'
!      END IF
!
!----------------------------------------------------------------------
! NAMES OF THE INPUT FILES:
      INQUIRE (file='RESULT_SEQ_METIS',exist=is)
      IF (is) THEN
        CALL plante(0)
        stop
      END IF
      OPEN(unit=72,file='PARTEL.PAR')
      READ(72,*) nameinp
      READ(72,*)
      READ(72,*) nparts
      READ(72,*)
      CLOSE(72)
!
      INQUIRE (file=nameinp,exist=is)
      IF (.NOT.is) THEN
        WRITE (lu,'('' FILE DOES NOT EXIST: '',A30)') nameinp
        CALL plante(1)
        stop
      END IF
!
      i_s  = len(nameinp)
      i_sp = i_s + 1
      DO i=1,i_s
        IF (nameinp(i_sp-i:i_sp-i) .NE. ' ') EXIT
      ENDDO
      i_len=i_sp - i
      i_leninp = i_len
!
      IF (i_leninp > path_len) THEN
        WRITE(lu,*) ' '
        WRITE(lu,*) 'ATTENTION:'
        WRITE(lu,*) 'THE NAME OF THE INPUT FILE:'
        WRITE(lu,*) nameinp
        WRITE(lu,*) 'IS LONGER THAN ',path_len,' CHARACTERS'
        WRITE(lu,*) 'WHICH IS THE LONGEST APPLICABLE NAME FOR TELEMAC '
        WRITE(lu,*) 'INPUT AND OUTPUT FILES. STOPPED. '
        CALL plante(1)
        stop
      ENDIF
!
      OPEN(ninp,file=nameinp,status='OLD',form='UNFORMATTED')
      rewind ninp
!
      READ (ninp) title
      READ (ninp) i, j
      nvar = i + j
      istart = 42
      DO i=1,nvar
        READ(ninp) vari
        DO j=1,32
          IF(vari(j:j).EQ.' ') vari(j:j) = '-'
        END DO
        istop = istart+20
        IF (istop.GT.maxallvarlength) THEN
          WRITE(lu,*) 'VARIABLE NAMES TOO LONG FOR STRIN ALLVAR'
          WRITE(lu,*) 'STOPPED.'
          CALL plante(1)
          stop
        ENDIF
        istart=istop+1
      ENDDO
!
!  READ THE REST OF THE SELAFIN FILE
!  10 INTEGERS, THE FIRST IS THE NUMBER OF RECORDS (TIMESTEPS)
!
      READ (ninp) (ib(i), i=1,10)
      IF (ib(8).NE.0.OR.ib(9).NE.0) THEN
        WRITE(lu,*) 'THIS IS A PARTIAL OUTPUT FILE'
        WRITE(lu,*) 'MAYBE MEET GRETEL BEFORE...'
      ENDIF
      nplan = ib(7)
!
      IF (ib(10).EQ.1) THEN
        READ(ninp) date(1), date(2), date(3), time(1), time(2), time(3)
      ENDIF
!
      READ (ninp) nelem,npoin,ndp,ndum
      IF (nplan.GT.1) THEN
        npoin2 = npoin/nplan
        nelem2 = nelem/(nplan-1)
        IF (mod(npoin,nplan).NE.0) THEN
          WRITE (lu,*) 'BUT NPOIN2 /= NPOIN3/NPLAN!'
          CALL plante(1)
          stop
        ENDIF
        IF (mod(nelem,(nplan-1)).NE.0) THEN
          WRITE (lu,*) 'BUT NELEM2 /= NELEM3/NPLAN!'
          CALL plante(1)
          stop
        ENDIF
      ELSE
        npoin2 = npoin
        nelem2 = nelem
      ENDIF
!
      IF (ndp.EQ.3) THEN
!         WRITE(LU,*) 'THE INPUT FILE ASSUMED TO BE 2D SELAFIN'
      ELSEIF (ndp.EQ.6) THEN
!         WRITE(LU,*) 'THE INPUT FILE ASSUMED TO BE 3D SELAFIN'
      ELSE
!         WRITE(LU,*) 'THE ELEMENTS ARE NEITHER TRIANGLES NOR PRISMS!'
!         WRITE(LU,*) 'NDP = ',NDP
        CALL plante(1)
        stop
      ENDIF
!
! NOW LET US ALLOCATE
!
      ALLOCATE (ikles(nelem2*3),stat=err)
      CALL check_allocate (err, 'IKLES')
      IF(nplan.GT.1) THEN
        ALLOCATE (ikles3d(nelem*ndp),stat=err)
        CALL check_allocate (err, 'IKLES3D')
      ENDIF
      ALLOCATE (irand(npoin),stat=err)
      CALL check_allocate (err, 'IRAND')
!   NVAR+2 : FIRST TWO FUNCTIONS ARE X AND Y
!   NPOIN IS 3D HERE IN 3D
      ALLOCATE (f(npoin,nvar+2),stat=err)
      CALL check_allocate (err, 'IRAND')
!
! CONNECTIVITY TABLE:
!
      IF(nplan.EQ.0) THEN
        READ(ninp) ((ikles((k-1)*ndp+j),j=1,ndp),k=1,nelem)
      ELSE
        READ(ninp) ((ikles3d((k-1)*ndp+j),j=1,ndp),k=1,nelem)
        DO j=1,3
          DO k=1,nelem2
            ikles((k-1)*3+j)=ikles3d((k-1)*6+j)
          ENDDO
        ENDDO
      ENDIF
!
      READ(ninp) (irand(j),j=1,npoin)
      READ(ninp) (f(j,1),j=1,npoin)
      READ(ninp) (f(j,2),j=1,npoin)
!
      iloop = 0
!      DO
!
!  READ THE TIME STEP
!
      READ(ninp) times
      iloop = iloop + 1
!
! READ THE TIME VARIABLES; NO 1 AND 2 ARE X,Y
!
      DO k=3,nvar+2
        READ(ninp) (f(j,k), j=1,npoin)
      END DO
!     END DO
!     STOP
      CLOSE (ninp)
!
      ALLOCATE (epart(nelem2),stat=err)
      CALL check_allocate (err, 'EPART')
      ALLOCATE (npart(npoin2),stat=err)
      CALL check_allocate (err, 'NPART')
      !WRITE(*,*) NELEM2,NPOIN2,NPARTS
!
      CALL partitioner(1, nelem2, npoin, 3, nparts, ikles, epart, npart)
!
      OPEN(unit=256,file='RESULT_SEQ_METIS')
      DO i=1,nelem2
        WRITE(256,*) epart(i)
      END DO

      !WRITE(*,*) 'END OF THE PRELIMINARY PART OF PARTEL'
!
      END PROGRAM partel_prelim