parcom_bord.f

Go to the documentation of this file.

!                   **********************
                    SUBROUTINE parcom_bord
!                   **********************
!
     &( x , icom , mesh )
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPLEMENTS A VECTOR AT THE INTERFACES BETWEEN
!+                SUB-DOMAINS. HERE BOUNDARY VECTOR OF TYPE 1.
!
!history  J-M HERVOUET (LNHE)
!+        24/10/2008
!+        V5P9
!+   First version, inspired from parcom.
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ICOM           |-->| COMMUNICATION MODE
!|                |   | = 1 : VALUE WITH MAXIMUM ABSOLUTE VALUE TAKEN
!|                |   | = 2 : CONTRIBUTIONS ADDED
!|                |   | = 3 : MAXIMUM CONTRIBUTION RETAINED
!|                |   | = 4 : MINIMUM CONTRIBUTION RETAINED
!| MESH           |-->| MESH STRUCTURE
!| X              |<->| VECTOR OR BLOCK OF VECTORS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_parcom_bord => parcom_bord
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: ICOM
!
!     STRUCTURES: VECTORS OR BLOCKS
!
      TYPE(bief_mesh), INTENT(INOUT)  :: MESH
      DOUBLE PRECISION, INTENT(INOUT) :: X(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER NPTFR,I,TELM,TDIM1,TDIM2,TDIMDISC
!
!***********************************************************************
!
      nptfr=bief_nbpts(1,mesh)
!
      telm     = mesh%T%ELM
      tdim1    = mesh%T%DIM1
      tdim2    = mesh%T%DIM2
      tdimdisc = mesh%T%DIMDISC
!
      mesh%T%ELM     = 11
      mesh%T%DIM1    = bief_nbpts(11,mesh)
      mesh%T%DIM2    = 1
      mesh%T%DIMDISC = 0
!
      CALL os('X=0     ',x=mesh%T)
!
      DO i=1,nptfr
        mesh%T%R(mesh%NBOR%I(i))=x(i)
      ENDDO
!
      CALL parcom(mesh%T,icom,mesh)
!
      DO i=1,nptfr
        x(i)=mesh%T%R(mesh%NBOR%I(i))
      ENDDO
!
      mesh%T%ELM     = telm
      mesh%T%DIM1    = tdim1
      mesh%T%DIM2    = tdim2
      mesh%T%DIMDISC = tdimdisc
!
!-----------------------------------------------------------------------
!
      RETURN
      END