parcom2i_seg.f

Go to the documentation of this file.

!                   ***********************
                    SUBROUTINE parcom2i_seg
!                   ***********************
!
     &( x1 , x2 , x3 , nseg , nplan , icom , ian , mesh , opt , ielm )
!
!***********************************************************************
! BIEF   V7P0                                   21/08/2010
!***********************************************************************
!
!brief    COMPLEMENTS A VECTOR OF SEGMENT AT THE INTERFACES
!+                BETWEEN SUB-DOMAINS.
!+
!+            X CAN BE A BLOCK OF VECTORS. IN THIS CASE, ALL THE
!+                VECTORS IN THE BLOCK ARE TREATED.
!
!note     IN 3D, THE FINITE VOLUME SEGMENTS IN PRISMS ARE
!+         CONSIDERED HERE, I.E. HORIZONTAL FIRST : NSEG*NPLAN
!+         THEN, VERTICAL : NPOIN2*(NPLAN-1).
!
!warning  IF THE VECTORS HAVE A SECOND DIMENSION, IT IS
!+            IGNORED FOR THE TIME BEING
!
!history  J-M HERVOUET (LNHE)
!+        19/11/2013
!+        V7P0
!+   Mere copy of PARCOM2_SEG for integers.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IAN            |-->| NUMBER OF VECTORS TO BE TREATED (X1, X2, X3)
!| ICOM           |-->| COMMUNICATION MODE
!|                |   | = 1 : VALUE WITH MAXIMUM ABSOLUTE VALUE TAKEN
!|                |   | = 2 : CONTRIBUTIONS ADDED
!|                |   | = 3 : MAXIMUM CONTRIBUTION RETAINED
!|                |   | = 4 : MINIMUM CONTRIBUTION RETAINED
!| IELM           |-->| TYPE OF ELEMENT (11: LINEAR TRIANGLE, ETC.)
!| MESH           |-->| MESH STRUCTURE
!| NPLAN          |-->| NUMBER OF PLANES
!| NSEG           |-->| NUMBER OF 2D SEGMENTS
!| OPT            |-->| 1 : HORIZONTAL AND VERTICAL SEGMENTS ONLY
!|                |   | 2 : ALL SEGMENTS
!| X1             |<->| INTEGER VECTOR TO BE COMPLETED, SEE IAN
!| X2             |<->| INTEGER VECTOR TO BE COMPLETED, SEE IAN
!| X3             |<->| INTEGER VECTOR TO BE COMPLETED, SEE IAN
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_parcom2i_seg => parcom2i_seg
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: ICOM,NSEG,NPLAN,IAN,OPT,IELM
!
!     STRUCTURES: VECTORS OR BLOCKS
!
      TYPE(bief_mesh) , INTENT(INOUT) :: MESH
!
!     IN 2D X1(NSEG)
!     IN 3D X1(NSEG*NPLAN+NPOIN2*(NPLAN-1))
!
      INTEGER, INTENT(INOUT) :: X1(*),X2(*),X3(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER NPOIN2,IDEB,IFIN,IPLAN,NPL
!
!-----------------------------------------------------------------------
!
      IF(nplan.GT.1) THEN
!
!       1) HORIZONTAL FLUXES
!
        DO iplan=1,nplan
          ideb=1+nseg*(iplan-1)
          ifin=  nseg* iplan
          CALL paracoi(x1(ideb:ifin),x2(ideb:ifin),x3(ideb:ifin),
     &                 nseg,icom,ian,1,
     &                 mesh%NB_NEIGHB_SEG,mesh%NB_NEIGHB_PT_SEG%I,
     &                 mesh%LIST_SEND_SEG%I,mesh%NH_COM_SEG%I,
     &                 mesh%NH_COM_SEG%DIM1,mesh%BUF_SEND%I,
     &                 mesh%BUF_RECV%I,mesh%BUF_SEND%DIM1)
        ENDDO
!
!       2) VERTICAL FLUXES
!
        npoin2=mesh%NPOIN
        DO iplan=1,nplan-1
          ideb=nseg*nplan + npoin2*(iplan-1) + 1
          ifin=nseg*nplan + npoin2* iplan
          CALL parcom2i(x1(ideb:ifin),x2(ideb:ifin),x3(ideb:ifin),
     &                  npoin2,1,icom,ian,mesh)
        ENDDO
!
!       3) CROSSED FLUXES
!
        IF(opt.EQ.2) THEN
          DO iplan=1,nplan-1
            IF(ielm.EQ.41) THEN
!             TWO CROSSED FLUXES (PER RECTANGLE OF PRISM)
              npl=2
              ideb=nseg*nplan+npoin2*(nplan-1)+2*nseg*(iplan-1) + 1
              ifin=nseg*nplan+npoin2*(nplan-1)+2*nseg* iplan
            ELSEIF(ielm.EQ.51) THEN
!             ONE CROSSED FLUX (PER ORIGINAL RECTANGLE OF PRISM)
              npl=1
              ideb=nseg*nplan+npoin2*(nplan-1)+nseg*(iplan-1) + 1
              ifin=nseg*nplan+npoin2*(nplan-1)+nseg* iplan
            ELSE
              WRITE(lu,*) 'UNKNOWN ELEMENT IN PARCOM2_SEG: ',ielm
              CALL plante(1)
              stop
            ENDIF
            CALL paracoi(x1(ideb:ifin),x2(ideb:ifin),x3(ideb:ifin),
     &                   nseg,icom,ian,npl,
     &                   mesh%NB_NEIGHB_SEG,mesh%NB_NEIGHB_PT_SEG%I,
     &                   mesh%LIST_SEND_SEG%I,mesh%NH_COM_SEG%I,
     &                   mesh%NH_COM_SEG%DIM1,mesh%BUF_SEND%I,
     &                   mesh%BUF_RECV%I,mesh%BUF_SEND%DIM1)
          ENDDO
        ENDIF
!
      ELSE
!
        CALL paracoi(x1,x2,x3,
     &               nseg,icom,ian,1,
     &               mesh%NB_NEIGHB_SEG,mesh%NB_NEIGHB_PT_SEG%I,
     &               mesh%LIST_SEND_SEG%I,mesh%NH_COM_SEG%I,
     &               mesh%NH_COM_SEG%DIM1,mesh%BUF_SEND%I,
     &               mesh%BUF_RECV%I,mesh%BUF_SEND%DIM1)
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END