osdb.f

Go to the documentation of this file.

!                   ***************
                    SUBROUTINE osdb
!                   ***************
!
     & ( op , x , y , z , c , mesh )
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    OPERATIONS ON VECTORS.
!code
!+   OP IS A STRING OF 8 CHARACTERS, WHICH INDICATES THE OPERATION TO BE
!+   PERFORMED ON VECTORS X,Y AND Z AND CONSTANT C.
!+
!+   HERE X IS A VECTOR DEFINED IN THE DOMAIN.
!+   Y AND Z ARE VECTORS DEFINED ON THE BOUNDARY.
!+   X, Y AND Z MUST BE STRUCTURES.
!+   Y SHOULD NOT BE A DUMMY STRUCTURE.
!+   Z NOT YET IMPLEMENTED.
!+
!+   THE RESULT IS VECTOR X.
!+
!+   OP = 'X=Y     '     :  COPIES Y IN X
!+   OP = 'X=+Y    '     :  IDEM
!+   OP = 'X=X+Y   '     :  ADDS Y TO X
!+   OP = 'X=X-Y   '     :  SUBTRACTS Y FROM X
!+   OP = 'X=CY    '     :  MULTIPLIES Y BY C
!
!history  J-M HERVOUET (LNH)
!+        06/12/94
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| C              |-->| A GIVEN CONSTANT USED IN OPERATION OP
!| MESH           |-->| MESH STRUCTURE
!| OP             |-->| OPERATION TO BE DONE (SEE ABOVE)
!| X              |<--| RESULTING VECTOR
!| Y              |-->| VECTOR USED IN OPERATION OP
!| Z              |-->| VECTOR USED IN OPERATION OP
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_osdb => osdb
!
      USE declarations_special
      IMPLICIT NONE
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      DOUBLE PRECISION, INTENT(IN)  :: C
      CHARACTER(LEN=8), INTENT(IN)  :: OP
      TYPE(bief_obj), INTENT(INOUT) :: X
      TYPE(bief_obj), INTENT(IN)    :: Y,Z
      TYPE(bief_mesh), INTENT(IN)   :: MESH
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER NPTFR,IELMX,IELMY
!
!-----------------------------------------------------------------------
!
      IF(x%TYPE.NE.2.OR.y%TYPE.NE.2) THEN
        WRITE(lu,101)
101     FORMAT(1x,'OSDB (BIEF) : X AND Y ARE NOT VECTORS')
        CALL plante(1)
        stop
      ENDIF
!
      ielmx = x%ELM
      ielmy = y%ELM
!
      IF((dimens(ielmx).NE.2.OR.dimens(ielmy).NE.1).AND.
     &   (dimens(ielmx).NE.3.OR.dimens(ielmy).NE.2)) THEN
        WRITE(lu,103)
103     FORMAT(1x,'OSDB (BIEF) : X AND Y HAVE WRONG DIMENSIONS')
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      nptfr = y%DIM1
!
!     3D MESH
!
      IF(ielmx.EQ.11.OR.ielmx.EQ.21.OR.ielmx.EQ.31.OR.ielmx.EQ.61.OR.
     &   ielmx.EQ.12.OR.ielmx.EQ.41.OR.ielmx.EQ.51.OR.ielmx.EQ.81) THEN
!       ARRAY NBOR
        CALL ovdb( op , x%R , y%R , z%R , c , mesh%NBOR%I , nptfr )
      ELSEIF(ielmx.EQ.10.OR.ielmx.EQ.20.OR.
     &       ielmx.EQ.40.OR.ielmx.EQ.50.OR.ielmx.EQ.80) THEN
!       ARRAY NELBOR
        CALL ovdb( op , x%R , y%R , z%R , c , mesh%NELBOR%I , nptfr )
      ELSE
        WRITE(lu,105)
105     FORMAT(1x,'OSDB (BIEF) : DISCRETIZATIONS NOT IMPLEMENTED')
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END