noudon.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE noudon
!                   *****************
!
     &     (f1,name1,mode1, f2,name2,mode2,f3,name3,mode3,
     &     npoin,ndon,fformat,at,tv1,tv2,
     &     f11,f12,f21,f22,f31,f32,indic,chdon,nvar,texte,
     &     trouve,unitime,phastime)
!
!***********************************************************************
!     TOMAWAC   V6P3                                  21/06/2011
!***********************************************************************
!
!     brief    COMPUTES THE CURRENT / WIND VELOCITY
!     +                FOR THE CURRENT TIME STEP AND ON THE COMPUTATION MESH.
!     +
!     +           (INSPIRED FROM SUBROUTINE FOND IN TELEMAC2D)
!
!     history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!     +        13/07/2010
!     +        V6P0
!     +   Translation of French comments within the FORTRAN sources into
!     +   English comments
!
!     history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!     +        21/08/2010
!     +        V6P0
!     +   Creation of DOXYGEN tags for automated documentation and
!     +   cross-referencing of the FORTRAN sources
!
!     history  G.MATTAROLO (EDF - LNHE)
!     +        20/06/2011
!     +        V6P1
!     +   Translation of French names of the variables in argument
!
!     history  J-M HERVOUET (EDF - LNHE)
!     +        16/11/2012
!     +        V6P3
!     +   Only SELAFIN format with same mesh kept. Arguments removed.
!
!     history  E. GAGNAIRE-RENOU & J-M HERVOUET (EDF - LNHE)
!     +        16/05/2013
!     +        V6P3
!     +   In the case where a new record is not read, array TROUVE must be
!     +   however built.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!     | AT             |-->| COMPUTATION TIME
!     | FFORMAT         |-->| DATA FILE FORMAT
!     | CHDON          |-->| NAME OF THE VARIABLE READ FROM THE DATA FILE
!     | F1             |<--| FIRST VARIABLE TO READ
!     | F2             |<--| SECOND VARIABLE TO READ
!     | F3             |<--| THIRD VARIABLE TO READ
!     | F11            |<->| DATA VALUES AT TIME TV1 IN THE DATA FILE FOR F1
!     | F12            |<->| DATA VALUES AT TIME TV2 IN THE DATA FILE FOR F1
!     | F21            |<->| DATA VALUES AT TIME TV1 IN THE DATA FILE FOR F2
!     | F22            |<->| DATA VALUES AT TIME TV2 IN THE DATA FILE FOR F2
!     | F31            |<->| DATA VALUES AT TIME TV1 IN THE DATA FILE FOR F3
!     | F32            |<->| DATA VALUES AT TIME TV2 IN THE DATA FILE FOR F3
!     | INDIC          |-->| FILE FORMAT
!     | MODE1          |-->| MODE: 0= DO NOT READ
!     |                |   |       1= READ IF PRESENT
!     | MODE2          |-->| LIKE MODE1 FOR SECOND VARIABLE
!     | MODE3          |-->| LIKE MODE1 FOR THIRD VARIABLE
!     | NAME1          |-->| NAME OF FIRST VARIABLE
!     | NAME2          |-->| NAME OF SECOND VARIABLE
!     | NAME3          |-->| NAME OF THIRD VARIABLE
!     | NDON           |-->| LOGICAL UNIT NUMBER OF THA DATA FILE
!     | NPOIN          |-->| NUMBER OF POINTS IN 2D MESH
!     | NVAR           |-->| NUMBER OF VARIABLES TO BE READ
!     | PHASTIME       |-->| TIME SHIFT IN FILE
!     | TV1            |<->| TIME T1 IN THE DATA FILE
!     | TV2            |<->| TIME T2 IN THE DATA FILE
!     | UNITIME        |-->| UNIT OF TIME IN FILE
!     | X              |-->| ABSCISSAE OF POINTS IN THE MESH
!     | Y              |-->| ORDINATES OF POINTS IN THE MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_tomawac,ONLY: debug
      USE interface_tomawac, ex_noudon => noudon
      USE interface_hermes
      USE declarations_special
      IMPLICIT NONE
!
!
!     +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NDON,NPOIN,INDIC
      INTEGER, INTENT(INOUT)          :: NVAR
      INTEGER, INTENT(IN)             :: MODE1,MODE2,MODE3
      DOUBLE PRECISION, INTENT(INOUT) :: F1(npoin),F2(npoin),F3(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: F11(npoin),F21(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: F12(npoin),F22(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: F31(npoin),F32(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: AT,UNITIME,PHASTIME
      DOUBLE PRECISION, INTENT(INOUT) :: TV1,TV2
      CHARACTER(LEN=8), INTENT(IN)    :: FFORMAT
      CHARACTER(LEN=7), INTENT(IN)    :: CHDON
      CHARACTER(LEN=32),INTENT(IN)    :: NAME1,NAME2,NAME3
      CHARACTER(LEN=32),INTENT(IN)    :: TEXTE(30)
      LOGICAL, INTENT(INOUT)          :: TROUVE(3)
!
!     +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,J,MODE(3)
      DOUBLE PRECISION COEF
      CHARACTER(LEN=32) NAME(3),FULL_NAME(3)
      CHARACTER(LEN=16), ALLOCATABLE :: VAR_NAME(:), VAR_UNIT(:)
      CHARACTER(LEN=32) COMPONENT
      LOGICAL :: COUUT=.false., venut=.false., marut=.false.
      INTEGER :: RECORD1,RECORD2
      DOUBLE PRECISION :: TIME1,TIME2
      INTEGER :: IERR
!
!-----------------------------------------------------------------------
!
      mode(1)=mode1
      mode(2)=mode2
      mode(3)=mode3
      name(1)=name1
      name(2)=name2
      name(3)=name3
      DO j=1,3
        trouve(j)=.false.
      ENDDO
!
!-----------------------------------------------------------------------
!
      IF(at.GT.tv2) THEN
!
        IF(debug.GT.0) THEN
          WRITE(lu,*) '   NOUDON : READING A NEW RECORD'
        ENDIF
!
        IF(indic.EQ.3) THEN
!
!     ------------------------------------------------------------------
!     READS A SELAFIN FILE OF TYPE: TELEMAC
!     ------------------------------------------------------------------
!
!
!     The test is useless as fields have already been checked for the initial value
!
          CALL get_data_nvar(fformat,ndon,nvar,ierr)
          CALL check_call(ierr,'NOUDON:GET_DATA_NVAR')
!
          ALLOCATE(var_name(nvar),stat=ierr)
          CALL check_allocate(ierr,'NOUDON:VAR_NAME')
          ALLOCATE(var_unit(nvar),stat=ierr)
          CALL check_allocate(ierr,'NOUDON:VAR_UNIT')
        CALL get_data_var_list(fformat,ndon,nvar,var_name,var_unit,ierr)
          CALL check_call(ierr,'NOUDON:GET_DATA_VAR_LIST')
          DO i=1,nvar
            component(1:16) = var_name(i)
            component(17:32) = var_unit(i)
! CHECK IF THE VARIABLE ARE IN THE FILE
            DO j=1,3
              IF((component.EQ.name(j)).AND.
     &             mode(j).GT.0) THEN
                trouve(j) = .true.
                full_name(j) = name(j)
              ENDIF
            ENDDO
          ENDDO
          DEALLOCATE(var_name)
          DEALLOCATE(var_unit)
!
!     Look for the two record before and after at for the interpolation
          record1 = 0
          record2 = 1
          CALL get_data_time(fformat,ndon,record1,time1,ierr)
          CALL check_call(ierr,'NOUDON:GET_DATA_TIME')
          tv1=(time1-phastime)*unitime
          DO
            CALL get_data_time(fformat,ndon,record2,time2,ierr)
            CALL check_call(ierr,'NOUDON:GET_DATA_TIME')
            tv2=(time2-phastime)*unitime
            IF(tv2.LT.at) THEN
              IF(debug.GT.0) THEN
                WRITE(lu,*) ' NOUDON: JUMP OF 1 DATA RECORD'
              ENDIF
              record1 = record2
              record2 = record2 + 1
              tv1 = tv2
            ELSE
              EXIT
            ENDIF
          ENDDO
!     Check if all the variables are found for record1
          DO j=1,3
            IF(mode(j).EQ.2.AND..NOT.trouve(j)) THEN
              WRITE(lu,*) 'NOUDON: VARIABLE ',name1,' NOT FOUND'
              WRITE(lu,*) trim(name(j)(1:16))
              CALL plante(1)
              stop
            ELSEIF(mode(j).GT.0.AND.trouve(j)) THEN
              IF(debug.GT.0) THEN
                WRITE(lu,*) 'VARIABLE ',j,' READ (',
     &               trim(name(j)(1:16)),') AT TIME ',tv1
              ENDIF
!     Read the data for varialbe j on record1
              IF(j.EQ.1) THEN
                CALL get_data_value(fformat,ndon,record1,
     &               full_name(j),f11,npoin,ierr)
              ELSEIF(j.EQ.2) THEN
                CALL get_data_value(fformat,ndon,record1,
     &               full_name(j),f21,npoin,ierr)
              ELSEIF(j.EQ.3) THEN
                CALL get_data_value(fformat,ndon,record1,
     &               full_name(j),f31,npoin,ierr)
              ENDIF
            ENDIF
          ENDDO
!     Read the variables
!
!     Check if all the variables are found for record2
          DO j=1,3
            IF(mode(j).EQ.2.AND..NOT.trouve(j)) THEN
              WRITE(lu,*) 'NOUDON: VARIABLE ',name1,' NOT FOUND'
              WRITE(lu,*) name(j)
              CALL plante(1)
              stop
            ELSEIF(mode(j).GT.0.AND.trouve(j)) THEN
              IF(debug.GT.0) THEN
                WRITE(lu,*) 'VARIABLE ',j,' READ (',
     &               trim(name(j)(1:16)),') AT TIME ',tv2
              ENDIF
!     Read the data for varialbe j on record2
              IF(j.EQ.1) THEN
                CALL get_data_value(fformat,ndon,record2,
     &               full_name(j),f12,npoin,ierr)
              ELSEIF(j.EQ.2) THEN
                CALL get_data_value(fformat,ndon,record2,
     &               full_name(j),f22,npoin,ierr)
              ELSEIF(j.EQ.3) THEN
                CALL get_data_value(fformat,ndon,record2,
     &               full_name(j),f32,npoin,ierr)
              ENDIF
            ENDIF
          ENDDO
!
        ELSEIF (indic.EQ.4) THEN
!
!     ---------------------------------------------------------------------
!     READS A USER-DEFINED FILE FORMAT
!     ---------------------------------------------------------------------
!
          IF(chdon(1:1).EQ.'C') THEN
            trouve(1)=.true.
            trouve(2)=.true.
            couut=.true.
            CALL couuti(ndon,fformat)
          ELSEIF(chdon(1:1).EQ.'V'.OR.chdon(1:1).EQ.'W') THEN
            trouve(1)=.true.
            trouve(2)=.true.
            venut=.true.
            CALL venuti(ndon,fformat)
          ELSEIF(chdon(1:1).EQ.'H') THEN
            trouve(3)=.true.
            marut=.true.
            CALL maruti(ndon,fformat)
          ENDIF
!
        ELSE
!
          WRITE(lu,*) '************************************************'
          WRITE(lu,*)'NOUDON : UNKNOWN INDICATOR OF FORMAT : ',indic
          WRITE(lu,*) '************************************************'
          CALL plante(1)
        ENDIF
!
      ELSE
!
        trouve(1)=.false.
        trouve(2)=.false.
        trouve(3)=.false.
        DO i =1,nvar
          DO j=1,3
            IF((texte(i).EQ.name(j)).AND.
     &           mode(j).GT.0) THEN
              trouve(j)=.true.
            ENDIF
          ENDDO
        ENDDO
        IF(couut.OR.venut) THEN
          trouve(1)=.true.
          trouve(2)=.true.
        ENDIF
        IF(marut) trouve(3)=.true.
!
      ENDIF
!
!     --------------------------------------------------------------
!     INTERPOLATES
!     --------------------------------------------------------------
!
      IF (abs(tv1-tv2).GT.1.d-30)  THEN
        coef=(at-tv1)/(tv2-tv1)
      ELSE
        coef=0
      ENDIF
!
      IF(trouve(1)) THEN
        DO i=1,npoin
          f1(i)=(f12(i)-f11(i))*coef+f11(i)
        ENDDO
      ENDIF
!
      IF(trouve(2)) THEN
        DO i=1,npoin
          f2(i)=(f22(i)-f21(i))*coef+f21(i)
        ENDDO
      ENDIF
!
      IF(trouve(3)) THEN
        DO i=1,npoin
          f3(i)=(f32(i)-f31(i))*coef+f31(i)
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
!
!     IF FAILED TO READ THE FILE ...
!
      WRITE(lu,*)'*********************************************'
      WRITE(lu,*)'  ERROR WHILE READING DATA FILE '
      WRITE(lu,*)'    OR UNEXPECTED END OF FILE           '
      WRITE(lu,*)'*********************************************'
      CALL plante(1)
      stop
!
!-----------------------------------------------------------------------
!
      RETURN
      END