normab.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE normab
!                   *****************
!
     &(xnebor,ynebor,xsgbor,ysgbor,disbor,surfac,nelmax,
     & nelbor,nulone,lgseg,nptfr,mesh,xel,yel,iklbor,nelebx,neleb)
!
!***********************************************************************
! BIEF   V7P0                                   21/08/2010
!***********************************************************************
!
!warning  XSGBOR(*,2) and XSGBOR(*,4) should not be used anymore
!+        could be removed (with care...).
!
!brief    1) COMPUTES THE COMPONENTS OF THE OUTGOING NORMAL VECTOR
!+
!+               - FOR THE BOUNDARY POINTS      (XNEBOR,YNEBOR)
!+
!+               - FOR THE BOUNDARY SEGMENTS    (XSGBOR,YSGBOR)
!+
!+            2) DISTANCE TO THE BOUNDARY OF THE FIRST ELEMENT POINTS
!+
!+            3) LENGTH OF THE BOUNDARY SEGMENTS
!+
!+            4) DISTANCE TO THE BOUNDARY OF THE FIRST INTERNAL POINTS
!code
!+  BEWARE:  XSGBOR AND YSGBOR DIMENSION IS (NPTFR,4):
!+
!+           (K,1) : NORMALISED    , SEGMENT FOLLOWING K
!+           (K,2) : NORMALISED    , SEGMENT PRECEDING K
!+           (K,3) : NOT NORMALISED, SEGMENT FOLLOWING K
!+           (K,4) : NOT NORMALISED, SEGMENT PRECEDING K
!+
!+           XSGBOR(K,1) AND YSGBOR(K,1) ARE THE COMPONENTS
!+           FOR THE SEGMENT FOLLOWING POINT K.
!+
!+           XSGBOR(K,2) AND YSGBOR(K,2) ARE THE COMPONENTS
!+           FOR THE SEGMENT PRECEDING POINT K.
!
!history  J-M HERVOUET (LNHE)
!+        26/06/2008
!+        V5P9
!+   Modifications for parallelism.
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        10/01/2013
!+        V6P3
!+   LGSEG now computed with coordinates per element (XEL and YEL)
!+   This is important in spherical coordinates.
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        13/03/2014
!+        V7P0
!+   Now written to enable different numbering of boundary points and
!+   boundary segments.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DISBOR         |<--| DISTANCE FROM BOUNDARY POINT TO CLOSER
!|                |   | INNER POINT
!| IKLBOR         |-->| CONNECTIVITY TABLE FOR BOUNDARY ELEMENTS
!| LGSEG          |<--| LENGTH OF BOUNDARY SEGMENTS
!| MESH           |-->| MESH STRUCTURE
!| NELBOR         |-->| FOR THE KTH BOUNDARY EDGE, GIVES THE CORRESPONDING
!|                |   | ELEMENT.
!| NULONE         |-->| NUMBER OF FIRST POINT OF SEGMENT IN ADJACENT ELEMENT
!| NELMAX         |-->| NUMBER OF ELEMENTS
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| SURFAC         |-->| AREA OF TRIANGLES
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| XNEBOR         |<--| COMPONANT ALONG X OF VECTOR NORMAL TO POINT
!| XSGBOR         |<--| COMPONANT ALONG X OF VECTOR NORMAL TO SEGMENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!| XNEBOR         |<--| COMPONANT ALONG Y OF VECTOR NORMAL TO POINT
!| YSGBOR         |<--| COMPONANT ALONG Y OF VECTOR NORMAL TO SEGMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_normab => normab
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NPTFR,NELMAX,NELEBX,NELEB
      INTEGER, INTENT(IN) :: NELBOR(nelebx)
      INTEGER, INTENT(IN) :: NULONE(nelebx,2),IKLBOR(nelebx,2)
!
      DOUBLE PRECISION, INTENT(INOUT) :: XNEBOR(nptfr,2),YNEBOR(nptfr,2)
      DOUBLE PRECISION, INTENT(INOUT) :: XSGBOR(nelebx,4)
      DOUBLE PRECISION, INTENT(INOUT) :: YSGBOR(nelebx,4)
      DOUBLE PRECISION, INTENT(INOUT) :: DISBOR(nptfr),LGSEG(nelebx)
      DOUBLE PRECISION, INTENT(IN)    :: SURFAC(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: XEL(nelmax,3),YEL(nelmax,3)
!
      TYPE(bief_mesh), INTENT(INOUT) :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER K1,K2,IELEM,I1,I2,IELEB
      DOUBLE PRECISION X12,Y12,XNORM,X1,X2,Y1,Y2,Z(1)
!
      INTRINSIC sqrt
!
!-----------------------------------------------------------------------
!
!     COMPUTES THE NORMAL VECTORS AND SEGMENT LENGTHS
!
!     0) INITIALISES LGSEG, XSGBOR AND YSGBOR TO 0
!
      IF(nptfr.GT.0) THEN
!
!       TO START WITH XSGBOR AND YSGBOR IN BOUNDARY NODES NUMBERING
!
        DO k1=1,nptfr
          xsgbor(k1,1) = 0.d0
          ysgbor(k1,1) = 0.d0
          xsgbor(k1,2) = 0.d0
          ysgbor(k1,2) = 0.d0
        ENDDO
!
!       1) NORMALS TO SEGMENTS AND LENGTH OF THE BOUNDARY SEGMENT
!          COMMON VERSION FOR SCALAR/PARALLEL MODES
!          STILL WITH BOUNDARY NODES NUMBERING
!
        DO ieleb=1,neleb
!
          k1=iklbor(ieleb,1)
          k2=iklbor(ieleb,2)
!
          ielem=nelbor(ieleb)
          i1=nulone(ieleb,1)
          i2=nulone(ieleb,2)
          x1=xel(ielem,i1)
          y1=yel(ielem,i1)
          x2=xel(ielem,i2)
          y2=yel(ielem,i2)
          x12 = x2 - x1
          y12 = y2 - y1
!         LENGTH OF THE BOUNDARY SEGMENT
          lgseg(ieleb) = sqrt( x12**2 + y12**2 )
!         NORMAL TO THE SEGMENT FOLLOWING K1:
          xsgbor(k1,1) =  y12
          ysgbor(k1,1) = -x12
!         NORMAL TO THE SEGMENT PRECEDING THE ONE FOLLOWING K1:
          xsgbor(k2,2) =  y12
          ysgbor(k2,2) = -x12
!
        ENDDO
!
      ENDIF
!
!     2) COMPLEMENT IN PARALLEL MODE, WITH PARCOM OPTION 1
!        (VALUE OF GREATER ABSOLUTE VALUE)
!
      IF(ncsize.GT.1) THEN
        IF(nptfr.GT.0) THEN
!         CALL PARCOM_BORD(LGSEG            ,1,MESH)
          CALL parcom_bord(xsgbor(1:nptfr,1),1,mesh)
          CALL parcom_bord(xsgbor(1:nptfr,2),1,mesh)
          CALL parcom_bord(ysgbor(1:nptfr,1),1,mesh)
          CALL parcom_bord(ysgbor(1:nptfr,2),1,mesh)
        ELSE
!         THIS DOES NOTHING FOR THE SUB-DOMAIN, BUT IS
!         NECESSARY TO THE PARALLEL COMMUNICATION
!         IN CASE OF CALL PARCOM_BORD, ALL PROCESSORS MUST CALL IT
!         CALL PARCOM_BORD(Z,1,MESH)
          CALL parcom_bord(z,1,mesh)
          CALL parcom_bord(z,1,mesh)
          CALL parcom_bord(z,1,mesh)
          CALL parcom_bord(z,1,mesh)
        ENDIF
      ENDIF
!
!     3) NORMALS BY NODES, APPROXIMATE DISTANCE FROM THE BOUNDARY
!        THE VECTORS ARE THEN NORMALISED
!
      IF(nptfr.GT.0) THEN
!
      DO k1=1,nptfr
!
!       NORMAL AT THE POINT: AVERAGE OF 2 NOT NORMALISED NORMALS
!       ASSOCIATED WITH THE 2 ADJACENT SEGMENTS
!
!       NOT NORMALISED VERSION XNEBOR(*,2) AND YNEBOR(*,2)
        xnebor(k1,2)=(xsgbor(k1,1)+xsgbor(k1,2))*0.5d0
        ynebor(k1,2)=(ysgbor(k1,1)+ysgbor(k1,2))*0.5d0
!
!       NOT NORMALISED VERSION XSGBOR(*,3) AND XSGBOR(*,4)
!                              YSGBOR(*,3) AND YSGBOR(*,4)
        xsgbor(k1,3)=xsgbor(k1,1)
        xsgbor(k1,4)=xsgbor(k1,2)
        ysgbor(k1,3)=ysgbor(k1,1)
        ysgbor(k1,4)=ysgbor(k1,2)
!
!       NORMALISED VERSION XNEBOR(*,1) AND YNEBOR(*,1)
        xnorm=sqrt(xnebor(k1,2)**2+ynebor(k1,2)**2)
        xnebor(k1,1)=xnebor(k1,2)/xnorm
        ynebor(k1,1)=ynebor(k1,2)/xnorm
!
!       NORMALISED VERSION OF XSGBOR AND YSGBOR FOR FOLLOWING SEGMENT
        xnorm=sqrt(xsgbor(k1,1)**2+ysgbor(k1,1)**2)
        xsgbor(k1,1)=xsgbor(k1,1)/xnorm
        ysgbor(k1,1)=ysgbor(k1,1)/xnorm
!
!       NORMALISED VERSION OF XSGBOR AND YSGBOR FOR PRECEDING SEGMENT
        xnorm=sqrt(xsgbor(k1,2)**2+ysgbor(k1,2)**2)
        xsgbor(k1,2)=xsgbor(k1,2)/xnorm
        ysgbor(k1,2)=ysgbor(k1,2)/xnorm
!
!       INITIALISATION FOR NEXT LOOP
!
        disbor(k1)=0.d0
!
      ENDDO
!
!     DISTANCE TO BOUNDARY
!
      DO ieleb=1,neleb
!
        k1=iklbor(ieleb,1)
!
!       THIS CAN BE APPROXIMATION OF THE MESH SIZE AT THE BOUNDARY
!       AND IS USED FOR LOG LAW AT THE BOUNDARIES
        disbor(k1) = 2.d0*surfac(nelbor(ieleb))/lgseg(ieleb)
!
      ENDDO
!
      ENDIF
!
!     DISBOR IS POSITIVE, CAN TAKE THE MAX
      IF(ncsize.GT.1) THEN
        CALL parcom_bord(disbor,3,mesh)
      ENDIF
!
!-----------------------------------------------------------------------
!
!     NOW, XSGBOR, YSGBOR AND DISBOR ARE GIVEN THEIR SEGMENT NUMBERING
!
!     IN THIS LOOP IELEB ALWAYS SMALLER OR EQUAL TO K1
!     SO NOTHING IS ERASED PREMATURELY
!
!     IN SCALAR MODE THE NUMBERING IS THE SAME SO NOTHING TO DO
!
      IF(ncsize.GT.1) THEN
!
        DO ieleb=1,neleb
!
          k1=iklbor(ieleb,1)
!
          xsgbor(ieleb,1)= xsgbor(k1,1)
          xsgbor(ieleb,2)= xsgbor(k1,2)
          xsgbor(ieleb,3)= xsgbor(k1,3)
          xsgbor(ieleb,4)= xsgbor(k1,4)
          ysgbor(ieleb,1)= ysgbor(k1,1)
          ysgbor(ieleb,2)= ysgbor(k1,2)
          ysgbor(ieleb,3)= ysgbor(k1,3)
          ysgbor(ieleb,4)= ysgbor(k1,4)
!         DISBOR(IELEB)  = DISBOR(K1)
!
        ENDDO
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END