nametrac_waqtel.F

Go to the documentation of this file.

!                     **************************
                      SUBROUTINE nametrac_waqtel
!                     **************************
!
     &  (nametrac,ntrac,process)
!
!
!***********************************************************************
! WAQTEL      V8P2
!***********************************************************************
!
!brief    Gives names to tracers added by the water quality
!
!
!history  R.ATA
!+        12/09/2014
!+        V7P0
!+        CREATION
!
!history  M.JODEAU
!+        05/2016
!+        V7P3
!+        AED2 coupling
!
!history  S.E. BOURBAN (HRW)
!+        07/06/2017
!+        V7P3
!+        Re-working NAMETRAC to avoid conflicting naming convention
!+        between user defined tracers, water quality processes and
!+        ice processes.
!
!history  S.E. BOURBAN (HRW)
!+        21/09/2017
!+        V7P3
!+        WAQPROCESS is now a prime number, so that multiple processes
!+        can be called by multiplication of the prime numbers.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NAMETRAC       |<->| ARRAY OF NAMES OF TRACERS
!| NTRAC          |-->| MODIFYING NUMBER OF TRACER IF NECESARY
!| PROCESS        |-->| USED TO FILTER ACCESS TO WATER QUALITY PROCESSES
!|                |   | PROCESS CAN BE DIFFERENT FROM WAQPROCESS, AND
!|                |   | IF 1, THEN ONLY THE INITIAL SETTING IS DONE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      USE declarations_waqtel
      USE interface_waqtel, ex_nametrac_waqtel => nametrac_waqtel
#if defined HAVE_AED2
      USE t3d_aed2
#endif
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!
      INTEGER          , INTENT(IN   )::  PROCESS
      INTEGER          , INTENT(INOUT)::  NTRAC
      CHARACTER(LEN=32), INTENT(INOUT)::  NAMETRAC(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
! AED2
#if defined HAVE_AED2
      CHARACTER(LEN=16),ALLOCATABLE :: NAMESAED2(:)
#endif
      INTEGER I
      LOGICAL :: FOUND
!
!-----------------------------------------------------------------------
!
      found = .false.
!
!-----------------------------------------------------------------------
!
!     INITIALISATION
!
      IF( process.EQ.1 ) THEN
        found = .true.

        waqtr = 0
        ranktr = 0
!
!     SORTING INDICES BY GROUPS
!
        rank_oxygn = 0 ! GROUP O2 TRACERS
        rank_bioma = 0 ! GROUP BIOMASS TRACERS
        rank_eutro = 0 ! GROUP EUTRO TRACERS
        rank_micro = 0 ! GROUP MICROPOL TRACERS
        rank_therm = 0 ! GROUP THERMIC TRACER
!
        nwaq_aed2 = 0
        rank_aed2 = 0  ! GROUP AED2 TRACERS
!
        nwaq_degra = 0
        rank_degra = 0 ! GROUP TRACERS WITH A DEGRADATION LAW
!
!     INDICES OF UNIQUE TRACERS
!
        ind_t = 0     ! TEMPERATURE
        ind_s = 0     ! SALINITY
        ind_o2 = 0    ! DISSOLVED O2
        ind_ol = 0    ! ORGANIC LOAD
        ind_nh4 = 0   ! NH4 LOAD
        ind_phy = 0   ! PHYTO BIOMASS
        ind_po4 = 0   ! DISSOLVED PO4
        ind_por = 0   ! POR NON ASSIM
        ind_no3 = 0   ! DISSOLVED NO3
        ind_nor = 0   ! NOR NON ASSIM
        ind_ss = 0    ! SUSPENDED LOAD
        ind_sf = 0    ! BED SEDIMENTS
        ind_c = 0     ! MICRO POLLUTANT
        ind_css = 0   ! ABS. SUSP. LOAD.
        ind_csf = 0   ! ABSORB. BED SED.

!
      ELSE IF( process*int(waqprocess/process).NE.waqprocess ) THEN
        WRITE(lu,21) process,waqprocess
21    FORMAT(1x,'NAMETRAC_WAQTEL: PROCESS CALLED ',i4,
     &       ' IS NOT A MULTIPLYING VALUE OF WAQ: ',i4)
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
!     THERMIC MODULE
!
      IF( 11*int(process/11).EQ.process ) THEN
        found = .true.
!
!       1. ~~> TEMPERATURE
        IF( ind_t.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_t,.true.,
     &      'TEMPERATURE     ','TEMPERATURE     ','   oC           ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_t
        ENDIF
        rank_therm(1) = ind_t
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!     AED2 COUPLING
!
      IF( 13*int(process/13).EQ.process ) THEN
#if defined HAVE_AED2
        found = .true.
!
!       1. ~~> TEMPERATURE
        IF( ind_t.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_t,.true.,
     &      'TEMPERATURE     ','TEMPERATURE     ','   oC           ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_t
        ENDIF
!
!       2. ~~> SALINITY
        IF( ind_s.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_s,.true.,
     &      'SALINITE        ','SALINITY        ','   g/l          ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_s
        ENDIF
!
        CALL names_var_aed2(nwqvars,namesaed2)
!       I. ~~> AED2 VARIABLES
        nwaq_aed2 = nwqvars
        DO i = 1,nwqvars
          IF( namesaed2(i) == 'CAR_pH          ' ) THEN
            CALL addtracer(nametrac,ntrac,
     &        rank_aed2(i),.true.,
     &        namesaed2(i),namesaed2(i),'   -/m3         ')
          ELSE
            CALL addtracer(nametrac,ntrac,
     &        rank_aed2(i),.true.,
     &        namesaed2(i),namesaed2(i),'   mmol/m3      ')
          ENDIF
          IF( rank_aed2(i).EQ.ntrac ) THEN
            waqtr = waqtr + 1
            ranktr(waqtr) = rank_aed2(i)
          ENDIF
        ENDDO
!
#else
        WRITE(lu,*) 'ERROR: AED2 LIBRARY NOT COMPILED'
        CALL plante(1)
        stop
#endif
      ENDIF
!
!-----------------------------------------------------------------------
!
!     O2 MODULE
!
      IF( 2*int(process/2).EQ.process ) THEN
        found = .true.
!
!       1. ~~> DISSOLVED O2
        IF( ind_o2.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_o2,.true.,
     &      'O2 DISSOUS      ','DISSOLVED O2    ','   mgO2/l       ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_o2
        ENDIF
        rank_oxygn(1) = ind_o2
!
!       2. ~~> ORGANIC LOAD
        IF( ind_ol.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_ol,.true.,
     &      'CHARGE ORGANIQUE','ORGANIC LOAD    ','   mgO2/l       ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_ol
        ENDIF
        rank_oxygn(2) = ind_ol
!
!       3. ~~> NH4 LOAD
        IF( ind_nh4.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_nh4,.true.,
     &      'CHARGE NH4      ','NH4 LOAD        ','   mgNH4/l      ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_nh4
        ENDIF
        rank_oxygn(3) = ind_nh4
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!     BIOMASS MODULE
!
      IF( 3*int(process/3).EQ.process ) THEN
        found = .true.
!
!       1. ~~> PHYTO BIOMASS
        IF( ind_phy.EQ.0 ) THEN
          CALL addtracer(nametrac, ntrac,
     &      ind_phy,.true.,
     &      'BIOMASSE PHYTO  ','PHYTO BIOMASS   ',' micro_g/l      ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_phy
        ENDIF
        rank_bioma(1) = ind_phy
!
!       2. ~~> DISSOLVED PO4
        IF( ind_po4.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_po4,.true.,
     &      'PO4 DISSOUS     ','DISSOLVED PO4   ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_po4
        ENDIF
        rank_bioma(2) = ind_po4
!
!       3. ~~> POR NON ASSIM
        IF( ind_por.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_por,.true.,
     &      'POR NON ASSIMILE','POR NON ASSIM   ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_por
        ENDIF
        rank_bioma(3) = ind_por
!
!       4. ~~> DISSOLVED NO3
        IF( ind_no3.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_no3,.true.,
     &      'NO3 DISSOUS     ','DISSOLVED NO3   ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_no3
        ENDIF
        rank_bioma(4) = ind_no3
!
!       5. ~~> NOR NON ASSIM
        IF( ind_nor.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_nor,.true.,
     &      'NOR NON ASSIMILE','NOR NON ASSIM   ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_nor
        ENDIF
        rank_bioma(5) = ind_nor
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!     EUTRO MODULE
!
      IF( 5*int(process/5).EQ.process ) THEN
        found = .true.
!
!       1. ~~> PHYTO BIOMASS
        IF( ind_phy.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_phy,.true.,
     &      'BIOMASSE PHYTO  ','PHYTO BIOMASS   ',' micro_g/l      ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_phy
        ENDIF
        rank_eutro(1) = ind_phy
!
!       2. ~~> DISSOLVED PO4
        IF( ind_po4.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_po4,.true.,
     &      'PO4 DISSOUS     ','DISSOLVED PO4   ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_po4
        ENDIF
        rank_eutro(2) = ind_po4
!
!       3. ~~> POR NON ASSIMIL
        IF( ind_por.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_por,.true.,
     &      'POR NON ASSIMILE','POR NON ASSIMIL ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_por
        ENDIF
        rank_eutro(3) = ind_por
!
!       4. ~~> DISSOLVED NO3
        IF( ind_no3.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_no3,.true.,
     &      'NO3 DISSOUS     ','DISSOLVED NO3   ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_no3
        ENDIF
        rank_eutro(4) = ind_no3
!
!       5. ~~> NOR NON ASSIM
        IF( ind_nor.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_nor,.true.,
     &      'NOR NON ASSIMILE','NOR NON ASSIM   ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_nor
        ENDIF
        rank_eutro(5) = ind_nor
!
!       6. ~~> NH4 LOAD
        IF( ind_nh4.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_nh4,.true.,
     &      'CHARGE NH4      ','NH4 LOAD        ','   mgNH4/l      ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_nh4
        ENDIF
        rank_eutro(6) = ind_nh4
!
!       7. ~~> ORGANIC LOAD
        IF( ind_ol.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_ol,.true.,
     &      'CHARGE ORGANIQUE','ORGANIC LOAD    ','   mgO2/l       ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_ol
        ENDIF
        rank_eutro(7) = ind_ol
!
!       8. ~~> DISSOLVED O2
        IF( ind_o2.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_o2,.true.,
     &      'O2 DISSOUS      ','DISSOLVED O2    ','   mgO2/l       ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_o2
        ENDIF
        rank_eutro(8) = ind_o2
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!     MICROPOL MODULE
!
      IF( 7*int(process/7).EQ.process ) THEN
        found = .true.
!
!       1. ~~> SUSPENDED LOAD
        IF( ind_ss.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_ss,.true.,
     &      'MAT. EN SUSP.   ','SUSPENDED LOAD  ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_ss
        ENDIF
        rank_micro(1) = ind_ss
!
!       2. ~~> BED SEDIMENTS
        IF( ind_sf.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_sf,.true.,
     &      'SEDIMENT DU FOND','BED SEDIMENTS   ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_sf
        ENDIF
        rank_micro(2) = ind_sf
!
!       3. ~~> MICRO POLLUTANT
        IF( ind_c.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_c,.true.,
     &      'MICRO POLLUANT  ','MICRO POLLUTANT ','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_c
        ENDIF
        rank_micro(3) = ind_c
!
!       4. ~~> ABS. SUSP. LOAD.
        IF( ind_css.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_css,.true.,
     &      'MES ABSORBEE    ','ABS. SUSP. LOAD.','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_css
        ENDIF
        rank_micro(4) = ind_css
!
!       5. ~~> ABSORB. BED SED.
        IF( ind_csf.EQ.0 ) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_csf,.true.,
     &      'SED. FOND. ABS. ','ABSORB. BED SED.','   mg/l         ')
          waqtr = waqtr + 1
          ranktr(waqtr) = ind_csf
        ENDIF
        rank_micro(5) = ind_csf
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!     DEGRADATION LAW
!
      IF( 17*int(process/17).EQ.process ) THEN
        found = .true.
!
        DO i = 1,ntrac
          waqtr = waqtr + 1
          ranktr(waqtr) = waqtr
          nwaq_degra = nwaq_degra + 1
          rank_degra(nwaq_degra) = i
        ENDDO
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!     GHOST PROCESS IN WAITING FOR THE MERGE WITH ICE PROCESS
!
      IF( 19*int(process/19).EQ.process ) THEN
        found = .true.
      ENDIF
!
!-----------------------------------------------------------------------
!
!     UNKNOWN PROCESS
!
      IF( .NOT.found ) THEN
        WRITE(lu,20) process
20    FORMAT(1x,'NAMETRAC_WAQTEL: UNKNOWN WAQ MODULE: ',i4)
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE nametrac_waqtel