nametrac_khione.f

Go to the documentation of this file.

!                     **************************
                      SUBROUTINE nametrac_khione
!                     **************************
!
     &  (nametrac,ntrac)
!
!
!***********************************************************************
! KHIONE      V7P3
!***********************************************************************
!
!brief    Add tracers needed for the modelling of frazil ice
!
!history  F. SOUILLE (EDF)
!+        30/09/2019
!+        V8P0
!+        Fixed name and unit of frazil (conc to volumic fraction)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NAMETRAC |<->| ARRAY OF NAMES OF TRACERS
!| NTRAC    |<->| MODIFYING NUMBER OF TRACER IF NECESARY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      USE declarations_khione
      USE declarations_telemac
!      USE INTERFACE_KHIONE, EX_NAMETRAC_KHIONE => NAMETRAC_KHIONE
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER          , INTENT(INOUT)::  NTRAC
      CHARACTER(LEN=32), INTENT(INOUT)::  NAMETRAC(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER            :: IFRA,I,K
      CHARACTER(LEN=2)   :: CHAR2
      LOGICAL :: FOUND
!
!-----------------------------------------------------------------------
!
      found = .false.
!
!-----------------------------------------------------------------------
!
!     ADDING TRACERS WHEN RELEVANT
!
!     THERMAL BUDGET
      IF( (thermal_budget) .OR. (clogging) ) THEN
        found = .true.
!
!   ~~> TEMPERATURE
        CALL addtracer(nametrac,ntrac,
     &    ind_t,.true.,
     &    'TEMPERATURE     ',
     &    'TEMPERATURE     ',
     &    '   oC           ')
!
!   ~~> SALINITY
        IF(salinity) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_s,.true.,
     &      'SALINITE        ',
     &      'SALINITY        ',
     &      '   ppt          ' )
        ENDIF
!
!   ~~> FRAZIL MULTI-CLASS
        ifra = 1
        IF(nc_fra.GT.1) THEN
!
          WRITE(lu,*) 'MULTI-CLASS IS NOT VALIDATED YET',
     &                'USE IT AT YOUR OWN RISK'
!
          ind_fra = ntrac+1
          DO i=1,nc_fra
            WRITE(char2,'(I2)') ifra
            ifra = ifra + 1
            CALL addtracer(nametrac,ntrac,k,.true.,
     &        'FRASIL ' //adjustl(char2)//'       ',
     &        'FRAZIL ' //adjustl(char2)//'       ',
     &        'VOLUME FRACTION ')
          ENDDO

!   ~~> FRAZIL MONO-CLASS
        ELSE
          CALL addtracer(nametrac,ntrac,
     &      ind_fra,.true.,
     &      'FRASIL          ',
     &      'FRAZIL          ',
     &      'VOLUME FRACTION ')
        ENDIF
!
!   ~~> FRAZIL PRECIPITATION
        IF(prec) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_pre,.true.,
     &      'FRASIL PRECIPITA',
     &      'FRAZIL PRECIPITA',
     &      'SURFAC FRACTION ')
          CALL addtracer(nametrac,ntrac,
     &      ind_thi,.true.,
     &      'EPAISSEUR COUV. ',
     &      'COVER THICKNESS ',
     &      '   M            ')
        ENDIF
!
!     STATIC ICE COVER
      ELSEIF( (icover_impact) .OR. (bd_ice) ) THEN
!
        found = .true.
!
!   ~~> TEMPERATURE
        CALL addtracer(nametrac,ntrac,
     &    ind_t,.true.,
     &    'TEMPERATURE     ',
     &    'TEMPERATURE     ',
     &    '   oC           ')
!
!   ~~> SALINITY
        IF(salinity) THEN
          CALL addtracer(nametrac,ntrac,
     &      ind_s,.true.,
     &      'SALINITE        ',
     &      'SALINITY        ',
     &      '   ppt          ' )
        ENDIF
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!     UNKNOWN PROCESS
!
      IF(.NOT.found ) THEN
        WRITE(lu,*) 'NAMETRAC_KHIONE: NO ACTIVE PROCESSES'
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE