na_flux3d_lim.f

Go to the documentation of this file.

!                   ************************
                    SUBROUTINE na_flux3d_lim
!                   ************************
!
     &(w,flulim,nseg2d,nelem,nelmax,nelem2,nelmax2,eltseg)
!
!***********************************************************************
! BIEF   V6P2                                   24/08/2012
!***********************************************************************
!
!brief    LIMITS 3D HORIZONTAL FLUXES IN A NON ASSEMBLED ELEMENT BY
!         ELEMENT ARRAY. FOR PRISMS. FIRST THE FLUXES ARE COMPUTED
!         WITH THE FINITE ELEMENT FLUXES. THEN LIMITATION IS DONE,
!         THEN FINITE ELEMENT FLUXES ARE REASSEMBLED.
!
!history  J-M HERVOUET (LNHE)
!+        23/08/2012
!+        V6P2
!+  First version.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ELTSEG         |-->| ELEMENTS THAT FORM A TRIANGLE
!| FLULIM         |-->| LIMITING FACTOR OF 2D SEGMENTS
!| NELEM          |-->| NUMBER OF ELEMENTS IN 3D
!| NELEM2         |-->| NUMBER OF ELEMENTS IN 2D
!| NSEG2D         |-->| NUMBER OF SEGMENTS IN 2D
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS IN 3D
!| NELMAX2        |-->| MAXIMUM NUMBER OF ELEMENTS IN 2D
!| W              |-->| FINITE ELEMENT FLUXES (I.E. LEAVING POINTS)
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER, INTENT(IN)             :: NSEG2D,NELMAX
      INTEGER, INTENT(IN)             :: NELEM,NELEM2,NELMAX2
      INTEGER, INTENT(IN)             :: ELTSEG(nelmax2,3)
      DOUBLE PRECISION, INTENT(INOUT) :: W(nelmax,6)
      DOUBLE PRECISION, INTENT(IN)    :: FLULIM(nseg2d)
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER IELEM,IELEM2
      DOUBLE PRECISION F12,F23,F31,A1,A2,A3,F1,F2,F3
!
!-----------------------------------------------------------------------
!
!     LIMITS 3D HORIZONTAL FLUXES BY COEFFICIENT OF 2D FLUXES
!
!     POINT TO POINT FLUXES ARE COMPUTED
!     SEE FLUX_EF_VF IN BIEF, OPTION 2
!     THEN THEY ARE REGROUPED ON POINTS
!
!-----------------------------------------------------------------------
!
!     HORIZONTAL SEGMENTS
!
      DO ielem=1,nelem
!
        ielem2=mod(ielem-1,nelem2)+1
!
!       LOWER LEVEL (SUM OF 3 W MUST BE 0, IT IS WITH VC04PP)
!
        f1 = w(ielem,1)
        f2 = w(ielem,2)
        f3 = w(ielem,3)
        a1 = abs(f1)
        a2 = abs(f2)
        a3 = abs(f3)
        f12=0.d0
        f23=0.d0
        f31=0.d0
        IF(a1.GE.a2.AND.a1.GE.a3) THEN
!         ALL FLOW TO AND FROM NODE 1
          f12 = - f2
          f31 = + f3
        ELSEIF(a2.GE.a1.AND.a2.GE.a3) THEN
!         ALL FLOW TO AND FROM NODE 2
          f12 = + f1
          f23 = - f3
        ELSE
!         ALL FLOW TO AND FROM NODE 3
          f23 = + f2
          f31 = - f1
        ENDIF
!       LIMITATION
        f12=f12*flulim(eltseg(ielem2,1))
        f23=f23*flulim(eltseg(ielem2,2))
        f31=f31*flulim(eltseg(ielem2,3))
!       REGROUPING
        w(ielem,1)=f12-f31
        w(ielem,2)=f23-f12
        w(ielem,3)=f31-f23
!
!       UPPER LEVEL (SUM OF 3 W MUST BE 0, IT IS WITH VC04PP)
!
        f1 = w(ielem,4)
        f2 = w(ielem,5)
        f3 = w(ielem,6)
        a1 = abs(f1)
        a2 = abs(f2)
        a3 = abs(f3)
        f12=0.d0
        f23=0.d0
        f31=0.d0
        IF(a1.GE.a2.AND.a1.GE.a3) THEN
!         ALL FLOW TO AND FROM NODE 1
          f12 = - f2
          f31 = + f3
        ELSEIF(a2.GE.a1.AND.a2.GE.a3) THEN
!         ALL FLOW TO AND FROM NODE 2
          f12 = + f1
          f23 = - f3
        ELSE
!         ALL FLOW TO AND FROM NODE 3
          f23 = + f2
          f31 = - f1
        ENDIF
!       LIMITATION
        f12=f12*flulim(eltseg(ielem2,1))
        f23=f23*flulim(eltseg(ielem2,2))
        f31=f31*flulim(eltseg(ielem2,3))
!       REGROUPING
        w(ielem,4)=f12-f31
        w(ielem,5)=f23-f12
        w(ielem,6)=f31-f23
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END