mxptel.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mxptel
!                   *****************
!
     &(mxptvs,mxelvs,ikles,ielm,npoin,nelem,ndp,ipobo,listin)
!
!***********************************************************************
! BIEF   V7P0                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE MAXIMUM NUMBER OF POINTS AND ELEMENTS
!+                NEIGHBOURING A POINT FOR A GIVEN TRIANGULAR MESH.
!
!note     ALLOCATES ITRAV HERE, INTERNALLY.
!+         IT'S A LOCAL WORKING VARIABLE ANYWAY.
!+         COULD ALSO PASS THE ELEMENT TYPE IN ARGUMENT TO TREAT
!+         THE 3D SPECIFICALLY.
!
!history  J-M HERVOUET (LNH)
!+        24/08/95
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        18/04/2014
!+        V7P0
!+   Automatic array ITRAV now allocatable.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IELM           |-->| TYPE OF ELEMENT
!| IKLES          |-->| LIKE CONNECTIVITY TABLE BUT IN SELAFIN FORMAT
!|                |   | IKLES(3,NELEM) INSTEAD OF IKLE(NELEM,3)
!| IPOBO          |-->| 0 FOR INNER POINTS
!|                |   | NOT 0 FOR BOUNDARY POINTS (THEIR RANK ACTUALLY)
!| LISTIN         |-->| IF YES : MXELVS AND MXPTVS WILL BE PRINTED
!| MXELVS         |-->| MAXIMUM NUMBER OF NEIGHBOURING ELEMENTS
!| MXPTVS         |-->| MAXIMUM NUMBER OF NEIGHBOURS OF A POINT
!| NDP            |-->| NUMBER OF POINTS PER ELEMENT
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mxptel => mxptel
      USE interface_parallel
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(INOUT) :: MXPTVS,MXELVS
      INTEGER, INTENT(IN)    :: IELM,NDP,NPOIN,NELEM
      INTEGER, INTENT(IN)    :: IKLES(ndp,nelem),IPOBO(npoin)
      LOGICAL, INTENT(IN)    :: LISTIN
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,J,IELEM
      INTEGER, ALLOCATABLE :: ITRAV(:)
      ALLOCATE(itrav(npoin))
!
!-----------------------------------------------------------------------
!
! 1) INITIALISES THE NUMBER OF NEIGHBOURING ELEMENTS TO 0:
!
      DO i = 1 , npoin
        itrav(i) = 0
      ENDDO
!
! 2) COUNTS THE NUMBER OF NEIGHBOURING ELEMENTS PER ASSEMBLY OPERATION:
!
      DO j = 1, ndp
        DO ielem = 1 , nelem
          itrav(ikles(j,ielem)) = itrav(ikles(j,ielem)) + 1
        ENDDO
      ENDDO
!
! 3) LOOKS FOR THE MAXIMUM :
!
      mxelvs = itrav(1)
      DO i = 2 , npoin
        mxelvs = max(mxelvs,itrav(i))
      ENDDO
!
! 4) NUMBER OF NEIGHBOURING POINTS: NEED TO ADD 1 TO THIS NUMBER
!                                   FOR BOUNDARY NODES.
!    SIMULTANEOUSLY LOOKS FOR THE MAXIMUM
!
      IF(ielm.EQ.31) THEN
        CALL mxptel31(nelem,npoin,mxelvs,ikles,mxptvs)
      ELSE
        mxptvs = mxelvs
        DO i = 1 , npoin
          IF(ipobo(i).NE.0) mxptvs = max(mxptvs,itrav(i)+1)
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(ncsize.GT.1) THEN
        mxptvs=p_max(mxptvs)
        mxelvs=p_max(mxelvs)
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(listin) THEN
        WRITE(lu,98) mxelvs,mxptvs
        IF(ncsize.GT.1) THEN
          WRITE(lu,*) '(GLOBAL MESH)'
        ENDIF
      ENDIF
98    FORMAT(1x,'MXPTEL (BIEF) : MAXIMUM NUMBER OF ELEMENTS AROUND A POI
     &NT: ',1i3,/,1x,
     &          '                MAXIMUM NUMBER OF POINTS AROUND A POINT
     &: ',1i3)
!
!-----------------------------------------------------------------------
!
      DEALLOCATE(itrav)
!
!-----------------------------------------------------------------------
!
      RETURN
      END