mxptel31.f

Go to the documentation of this file.

!                   *******************
                    SUBROUTINE mxptel31
!                   *******************
!
     & (nelem,npoin,mxelvs,ikles,mxptvs)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    FOR TETRAHEDRA, GIVES THE MAXIMUM NUMBER OF NEIGHBOURS
!+                FOR A GIVEN MESH NODE.
!
!history  LAM MINH-PHUONG; F. DECUNG
!+        31/08/2009
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLES          |-->| LIKE CONNECTIVITY TABLE BUT IN SELAFIN FORMAT
!|                |   | IKLES(4,NELEM) INSTEAD OF IKLE(NELEM,4)
!| MXELVS         |-->| MAXIMUM NUMBER OF NEIGHBOURING ELEMENTS
!| MXPTVS         |<--| MAXIMUM NUMBER OF NEIGHBOURS OF A POINT
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mxptel31 => mxptel31
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)                       :: NELEM
      INTEGER, INTENT(IN)                       :: NPOIN
      INTEGER, INTENT(IN)                       :: MXELVS
      INTEGER, INTENT(IN), DIMENSION(4,NELEM)   :: IKLES
      INTEGER, INTENT(OUT)                      :: MXPTVS
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER                            :: IPOIN,I,J,K,IKLJ,IKL
      INTEGER                            :: NVOIS
      INTEGER,DIMENSION(:),ALLOCATABLE   :: VOIS
      INTEGER,DIMENSION(:,:),ALLOCATABLE :: IND_ELEM
!
      ALLOCATE(vois(3*mxelvs))
      ALLOCATE(ind_elem(npoin,mxelvs+1))
!
!-----------------------------------------------------------------------
!
! IND_ELEM GIVES THE NUMBER OF ELEMENTS AROUND A NODE AND THEIR NUMBERS
! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      DO i = 1, npoin
        ind_elem(i,1) = 0
      ENDDO
!
      DO j=1, 4
        DO i=1,nelem
          ikl = ikles(j,i)
          ind_elem(ikl,1)=ind_elem(ikl,1)+1
          ind_elem(ikl,ind_elem(ikl,1)+1)=i
        ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!-----------------------------------------------------------------------
!
      mxptvs = 0
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
! LOOP ON ALL THE NODES OF THE MESH      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!
      DO ipoin = 1, npoin
!
        nvois   = 1
        vois(1) = ipoin
!
!       INITIALISES VOIS TO 0
!
        DO i = 1, 3*mxelvs
          vois(i) = 0
        ENDDO
!
!       FILLS IN VOIS, WHICH CONTAINS THE NUMBERS OF ALL THE NODES
!       NEIGHBOURING IPOIN
!
        DO j = 1,4
          DO i = 2, ind_elem(ipoin,1)+1
            iklj = ikles(j,ind_elem(ipoin,i))
            DO k = 1, nvois
              IF ( vois(k) == iklj ) EXIT
            ENDDO
            IF( k > nvois ) THEN
              nvois       = nvois + 1
              vois(nvois) = iklj
            ENDIF
          ENDDO
        ENDDO
!
        nvois = nvois - 1
        IF( mxptvs < nvois) mxptvs = nvois
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      DEALLOCATE (vois)
      DEALLOCATE (ind_elem)
!
!-----------------------------------------------------------------------
!
      RETURN
      END