mw0303.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mw0303
!                   *****************
!
     &(op, x , da,typdia,xas,typext, y,c,
     & iklem1,dimikm,limvoi,mxptvs,npmax,npoin,trav)
!
!***********************************************************************
! BIEF   V6P3                                   21/08/2010
!***********************************************************************
!
!brief    FRONTAL MATRIX VECTOR PRODUCT FOR P1 TRIANGLES.
!code
!+   OP IS A STRING OF 8 CHARACTERS, WHICH INDICATES THE OPERATION TO BE
!+   PERFORMED ON VECTORS X,Y AND MATRIX M.
!+
!+   THE RESULT IS VECTOR X.
!+
!+   THESE OPERATIONS ARE DIFFERENT DEPENDING ON THE DIAGONAL TYPE
!+   AND THE TYPE OF EXTRADIAGONAL TERMS.
!+
!+   IMPLEMENTED OPERATIONS:
!+
!+      OP = 'X=AY    '  : X = AY
!+      OP = 'X=-AY   '  : X = -AY
!+      OP = 'X=X+AY  '  : X = X + AY
!+      OP = 'X=X-AY  '  : X = X - AY
!+      OP = 'X=X+CAY '  : X = X + C AY
!+      OP = 'X=TAY   '  : X = TA Y (TRANSPOSE OF A)
!+      OP = 'X=-TAY  '  : X = - TA Y (- TRANSPOSE OF A)
!+      OP = 'X=X+TAY '  : X = X + TA Y
!+      OP = 'X=X-TAY '  : X = X - TA Y
!+      OP = 'X=X+CTAY'  : X = X + C TA Y
!
!history  J-M HERVOUET (LNH)    ; F LEPEINTRE (LNH)
!+        05/02/91
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        11/03/2013
!+        V6P3
!+   Dimension of LIMVOI now set to 11.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| C              |-->| A GIVEN CONSTANT
!| DA             |-->| MATRIX DIAGONAL
!| DIMIKM         |-->| FIRST DIMENSION OF IKLEM1
!| IKLEM1         |-->| DATA STRUCTURE FOR MATRIX-VECTOR PRODUCT
!|                |   | GIVES THE ADRESSES OF OFF-DIAGONAL TERMS
!|                |   | IN XAS AND NEIGHBOUR POINTS IN Y.
!|                |   | IKLEM1(*,*,1) : NON SYMMETRIC MATRIX
!|                |   | IKLEM1(*,*,2) : SYMMETRIC MATRIX
!|                |   | FIRST DIMENSION: NPMAX
!|                |   | 2ND DIM.: 1 : DIRECT PRODUCT, ADDRESS IN XAS
!|                |   |           2 : DIRECT PRODUCT, ADDRESS IN Y
!|                |   |           3 : TRANSPOSED PRODUCT, ADDRESS IN XAS
!|                |   |           4 : TRANSPOSED PRODUCT, ADDRESS IN Y
!| LIMVOI         |-->|
!| MXPTVS         |-->| MAXIMUM NUMBER OF NEIGHBOURS OF A POINT
!| NPMAX          |-->| MAXIMUM NUMBER OF POINTS.
!| NPOIN          |-->| NUMBER OF POINTS
!| OP             |-->| OPERATION TO BE DONE (SEE ABOVE)
!| TRAV           |-->| WORK ARRAY
!| TYPDIA         |-->| TYPE OF DIAGONAL:
!|                |   | TYPDIA = 'Q' : ANY VALUE
!|                |   | TYPDIA = 'I' : IDENTITY
!|                |   | TYPDIA = '0' : ZERO
!| TYPEXT         |-->| TYPE OF OFF-DIAGONAL TERMS
!|                |   | TYPEXT = 'Q' : ANY VALUE
!|                |   | TYPEXT = 'S' : SYMMETRIC
!|                |   | TYPEXT = '0' : ZERO
!| X              |<->| RESULT IN ASSEMBLED FORM
!| XAS            |-->| OFF-DIAGONAL TERMS OF MATRIX
!| Y              |-->| VECTOR USED IN THE OPERATION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mw0303 => mw0303
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: DIMIKM,MXPTVS,NPMAX,NPOIN
!                                                      11: SEE ALMESH
!                                                          AND OPTASS
      INTEGER, INTENT(IN) :: IKLEM1(dimikm,4,2),LIMVOI(11,2)
!
      DOUBLE PRECISION, INTENT(INOUT) :: X(*),TRAV(*)
      DOUBLE PRECISION, INTENT(IN)    :: DA(*),Y(*)
      DOUBLE PRECISION, INTENT(IN)    :: XAS(*),C
!
      CHARACTER(LEN=8), INTENT(IN)    :: OP
      CHARACTER(LEN=1), INTENT(IN)    :: TYPDIA,TYPEXT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I
      DOUBLE PRECISION Z(1)
!
!-----------------------------------------------------------------------
!
!   TREATMENT SPECIFIC TO THE TRANSPOSITION:
!
      i = 1
      IF(op(3:3).EQ.'T'.OR.op(4:4).EQ.'T'.OR.
     &   op(5:5).EQ.'T'.OR.op(6:6).EQ.'T') i = 3
!
!-----------------------------------------------------------------------
!
!   MATRIX VECTOR PRODUCT, SIMPLE FUNCTION OF THE SHAPE OF THE MATRIX:
!
      IF(typext(1:1).EQ.'S'.OR.typext(1:1).EQ.'Q') THEN
!
        IF(typext(1:1).EQ.'Q') THEN
        CALL opass('X=WY    ',trav,xas,iklem1(1,i,1),
     &             y,iklem1(1,i+1,1),limvoi,mxptvs,npmax)
        ELSEIF(typext(1:1).EQ.'S') THEN
        CALL opass('X=WY    ',trav,xas,iklem1(1,i,2),
     &             y,iklem1(1,i+1,2),limvoi,mxptvs,npmax)
        ENDIF
!
        IF(typdia(1:1).EQ.'Q') THEN
          CALL ov ('X=X+YZ  ', trav , y , da , c , npoin )
        ELSEIF(typdia(1:1).EQ.'I') THEN
          CALL ov ('X=X+Y   ', trav , y , z , c , npoin )
        ELSEIF(typdia(1:1).NE.'0') THEN
          WRITE(lu,2001) typdia
          CALL plante(1)
          stop
        ENDIF
!
      ELSEIF(typext(1:1).EQ.'0') THEN
!
        IF(typdia(1:1).EQ.'Q') THEN
          CALL ov ('X=YZ    ', trav , y , da , c , npoin )
        ELSEIF(typdia(1:1).EQ.'I') THEN
          CALL ov ('X=Y     ', trav , y , z , c , npoin )
        ELSEIF(typdia(1:1).EQ.'0') THEN
          CALL ov ('X=C     ', trav , y , z , 0.d0 , npoin )
        ELSE
          WRITE(lu,2001) typdia
          CALL plante(1)
          stop
        ENDIF
!
      ELSE
!
        WRITE(lu,1001) typext
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!   IMPLEMENTED OPERATIONS:
!
      IF(op(1:8).EQ.'X=AY    '.OR.op(1:8).EQ.'X=TAY   ') THEN
        CALL ov ('X=Y     ', x , trav , z , c , npoin )
      ELSEIF(op(1:8).EQ.'X=-AY   '.OR.op(1:8).EQ.'X=-TAY  ') THEN
        CALL ov ('X=-Y    ', x , trav , z , c , npoin )
      ELSEIF(op(1:8).EQ.'X=X+AY  '.OR.op(1:8).EQ.'X=X+TAY ') THEN
        CALL ov ('X=X+Y   ', x , trav , z , c , npoin )
      ELSEIF(op(1:8).EQ.'X=X-AY  '.OR.op(1:8).EQ.'X=X-TAY ') THEN
        CALL ov ('X=X-Y   ', x , trav , z , c , npoin )
      ELSEIF(op(1:8).EQ.'X=X+CAY '.OR.op(1:8).EQ.'X=X+CTAY') THEN
        CALL ov ('X=X+CY  ', x , trav , z , c , npoin )
      ELSEIF(op(1:8).EQ.'X=CAY   ') THEN
        CALL ov ('X=CY    ', x , trav , z , c , npoin )
      ELSE
        WRITE(lu,3001) op
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
!
1001  FORMAT(1x,'MW0303 (BIEF) : EXTRADIAG. TERMS  UNKNOWN TYPE : ',a1)
2001  FORMAT(1x,'MW0303 (BIEF) : DIAGONAL : UNKNOWN TYPE : ',a1)
3001  FORMAT(1x,'MW0303 (BIEF) : UNKNOWN OPERATION : ',a8)
!
!-----------------------------------------------------------------------
!
      END