mult_interface_seg.f

Go to the documentation of this file.

!                   *****************************
                    SUBROUTINE mult_interface_seg
!                   *****************************
!
     &(fseg,nh_com_seg,dim1nhcom,nb_neighb_seg,
     & nb_neighb_pt_seg,list_send,nseg)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    Shares a function defined on segments between sub-domains.
!
!history  J-M HERVOUET (LNHE)
!+        27/02/2009
!+        V5P9
!+   First version.
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        12/06/2015
!+        V7P1
!+   Now one sub-domain receives all, the others nothing.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DIM1NHCOM       |-->| FIRST DIMENSION OF NH_COM_SEG
!| FSEG            |<->| THE FUNCTION DEFINED ON SEGMENTS
!| LIST_SEND       |-->| RANKS OF NEIGHBOURING SUB-DOMAINS
!| NB_NEIGHB_PT_SEG|-->| NUMBER OF SEGMENTS SHARED WITH A NEIGHBOUR
!|                 |   | PROCESSOR
!| NB_NEIGHB_SEG   |-->| NUMBER OF NEIGHBOUR PROCESSORS (FOR SEGMENTS)
!| NH_COM_SEG      |-->| ADDRESSES OF INTERFACE SEGMENTS
!| NSEG            |-->| NUMBER OF SEGMENTS
!| XMUL            |-->| THE CONSTANT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: DIM1NHCOM,NB_NEIGHB_SEG,NSEG
      INTEGER, INTENT(INOUT) :: NH_COM_SEG(dim1nhcom,nb_neighb_seg)
      INTEGER, INTENT(IN)    :: NB_NEIGHB_PT_SEG(nb_neighb_seg)
      INTEGER, INTENT(IN)             :: LIST_SEND(nb_neighb_seg)
      DOUBLE PRECISION, INTENT(INOUT) :: FSEG(nseg)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER ISEG,IPROC,IADSEG
!
!-----------------------------------------------------------------------
!
!     DONE ONLY IF THERE IS AT LEAST ONE OTHER SUB-DOMAIN SHARING
!     A SEGMENT WITH THIS ONE
!
      IF(nb_neighb_seg.GT.0) THEN
!
!       LOOP ON ALL NEIGHBOURING SUB-DOMAINS
!
        DO iproc=1,nb_neighb_seg
!
!         ONLY THE PROCESSOR WITH HIGHEST RANK WILL KEEP ITS VALUES
!         OTHERS ARE CANCELLED
          IF(ipid.LT.list_send(iproc)) THEN
!           LOOP ON ALL SEGMENTS SHARED WITH THIS SUB-DOMAIN
!           WHICH CANNOT BE SHARED WITH ANOTHER SUB-DOMAIN (UNLIKE POINTS)
            DO iseg=1,nb_neighb_pt_seg(iproc)
!             ADDRESS IN SEGMENT NUMBERING
              iadseg=nh_com_seg(iseg,iproc)
              fseg(iadseg)=0.d0
            ENDDO
          ENDIF
!
        ENDDO
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END