mt13ca.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mt13ca
!                   *****************
!
     &(  a11 , a12 , a13 ,
     &   a21 , a22 , a23 ,
     &   a31 , a32 , a33 ,
     &   a41 , a42 , a43 ,
     &   a51 , a52 , a53 ,
     &   a61 , a62 , a63 ,
     &   xmul,xel,yel,nelem,nelmax,icoord)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COEFFICIENTS OF THE FOLLOWING MATRIX:
!code
!+  EXAMPLE WITH ICOORD = 1
!+
!+                  /           D
!+ A(I,J)= XMUL *  /  PSI1(I) * --( PSI2(J) ) D(OMEGA)
!+                /OMEGA        DX
!+
!+  ICOORD=2 WOULD GIVE A DERIVATIVE WRT Y
!+
!+  PSI1: BASES OF TYPE P2 TRIANGLE
!+  PSI2: BASES OF TYPE P1 TRIANGLE
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  ALGIANE FROEHLY
!+        09/07/2008
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A11            |<--| ELEMENTS OF MATRIX
!| ...            |<--| ELEMENTS OF MATRIX
!| A63            |<--| ELEMENTS OF MATRIX
!| ICOORD         |-->| 1: DERIVATIVE ALONG X, 2: ALONG Y
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!| XMUL           |-->| MULTIPLICATION FACTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief!, EX_MT13CA => MT13CA
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX,ICOORD
!
      DOUBLE PRECISION, INTENT(INOUT) :: A11(*),A12(*),A13(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A21(*),A22(*),A23(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A31(*),A32(*),A33(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A41(*),A42(*),A43(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A51(*),A52(*),A53(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A61(*),A62(*),A63(*)
!
      DOUBLE PRECISION, INTENT(IN) :: XMUL
!
      DOUBLE PRECISION, INTENT(IN) :: XEL(nelmax,3),YEL(nelmax,3)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM
      DOUBLE PRECISION X2,X3,Y2,Y3
      DOUBLE PRECISION XSUR6
!
!-----------------------------------------------------------------------
!
      xsur6 = xmul/6.d0
!
!================================
!  DERIVATIVE WRT X  =
!================================
!
        IF(icoord.EQ.1) THEN
!
!   LOOP ON THE ELEMENTS
!
        DO ielem = 1 , nelem
!
!   INITIALISES THE GEOMETRICAL VARIABLES
!
        y2 = yel(ielem,2)
        y3 = yel(ielem,3)
!
!   EXTRADIAGONAL TERMS
!
        a12(ielem) = 0.d0
        a13(ielem) = 0.d0
        a21(ielem) = 0.d0
        a23(ielem) = 0.d0
        a31(ielem) = 0.d0
        a32(ielem) = 0.d0
        a42(ielem) =   y3*xsur6
        a43(ielem) = - y2*xsur6
        a41(ielem) = - a42(ielem) - a43(ielem)
        a51(ielem) =   a41(ielem)
        a52(ielem) =   a42(ielem)
        a53(ielem) =   a43(ielem)
        a61(ielem) =   a41(ielem)
        a62(ielem) =   a42(ielem)
        a63(ielem) =   a43(ielem)
!
!   DIAGONAL TERMS
!
        a11(ielem) = 0.d0
        a22(ielem) = 0.d0
        a33(ielem) = 0.d0
!
      ENDDO ! IELEM
!
        ELSEIF(icoord.EQ.2) THEN
!
!================================
!  DERIVATIVE WRT Y  =
!================================
!
        DO ielem = 1 , nelem
!
!   INITIALISES THE GEOMETRICAL VARIABLES
!
        x2  =  xel(ielem,2)
        x3  =  xel(ielem,3)
!
!   EXTRADIAGONAL TERMS
!
        a12(ielem) = 0.d0
        a13(ielem) = 0.d0
        a21(ielem) = 0.d0
        a23(ielem) = 0.d0
        a31(ielem) = 0.d0
        a32(ielem) = 0.d0
        a42(ielem) = - x3*xsur6
        a43(ielem) =   x2*xsur6
        a41(ielem) = - a42(ielem) - a43(ielem)
        a51(ielem) =   a41(ielem)
        a52(ielem) =   a42(ielem)
        a53(ielem) =   a43(ielem)
        a61(ielem) =   a41(ielem)
        a62(ielem) =   a42(ielem)
        a63(ielem) =   a43(ielem)
!
!   DIAGONAL TERMS
!
        a11(ielem) = 0.d0
        a22(ielem) = 0.d0
        a33(ielem) = 0.d0
!
        ENDDO ! IELEM
!
        ELSE
!
          WRITE(lu,201) icoord
          CALL plante(1)
!
        ENDIF
!
201     FORMAT(1x,'MT13CA (BIEF) : IMPOSSIBLE COMPONENT ',
     &         1i6,' CHECK ICOORD')
!
!-----------------------------------------------------------------------
!
      RETURN
      END