mt13ba.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mt13ba
!                   *****************
!
     &(  a11 , a12 , a13 ,
     &   a21 , a22 , a23 ,
     &   a31 , a32 , a33 ,
     &   a41 , a42 , a43 ,
     &   xmul,xel,yel,nelem,nelmax,icoord)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COEFFICIENTS OF THE FOLLOWING MATRIX:
!code
!+  EXAMPLE WITH ICOORD = 1
!+
!+                  /           D
!+ A(I,J)= XMUL *  /  PSI1(I) * --( PSI2(J) ) D(OMEGA)
!+                /OMEGA        DX
!+
!+  ICOORD=2 WOULD GIVE A DERIVATIVE WRT Y
!+
!+  PSI1: BASES OF TYPE QUASI-BUBBLE TRIANGLE
!+  PSI2: BASES OF TYPE IELM2
!
!note     THE EXPRESSION OF THIS MATRIX IS THE TRANSPOSE
!+         OF THAT IN MT13BB.
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  J-M HERVOUET (LNH)    ; C MOULIN (LNH)
!+        06/02/95
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A11            |<--| ELEMENTS OF MATRIX
!| A12            |<--| ELEMENTS OF MATRIX
!| A13            |<--| ELEMENTS OF MATRIX
!| A21            |<--| ELEMENTS OF MATRIX
!| A22            |<--| ELEMENTS OF MATRIX
!| A23            |<--| ELEMENTS OF MATRIX
!| A31            |<--| ELEMENTS OF MATRIX
!| A32            |<--| ELEMENTS OF MATRIX
!| A33            |<--| ELEMENTS OF MATRIX
!| A41            |<--| ELEMENTS OF MATRIX
!| A42            |<--| ELEMENTS OF MATRIX
!| A43            |<--| ELEMENTS OF MATRIX
!| ICOORD         |-->| 1: DERIVATIVE ALONG X, 2: ALONG Y
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!| XMUL           |-->| MULTIPLICATION FACTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mt13ba => mt13ba
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX,ICOORD
!
      DOUBLE PRECISION, INTENT(INOUT) :: A11(*),A12(*),A13(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A21(*),A22(*),A23(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A31(*),A32(*),A33(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A41(*),A42(*),A43(*)
!
      DOUBLE PRECISION, INTENT(IN) :: XMUL
!
      DOUBLE PRECISION, INTENT(IN) :: XEL(nelmax,3),YEL(nelmax,3)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM
      DOUBLE PRECISION X2,X3,Y2,Y3
      DOUBLE PRECISION XSUR9,XSUR6
!
!-----------------------------------------------------------------------
!
      xsur6 = xmul/6.d0
      xsur9 = xmul/9.d0
!
!================================
!  DERIVATIVE WRT X  =
!================================
!
        IF(icoord.EQ.1) THEN
!
!   LOOP ON THE ELEMENTS
!
        DO ielem = 1 , nelem
!
!   INITIALISES THE GEOMETRICAL VARIABLES
!
        y2 = yel(ielem,2)
        y3 = yel(ielem,3)
!
!   EXTRADIAGONAL TERMS
!
        a12(ielem) =  y3*xsur9
        a13(ielem) = -y2*xsur9
        a21(ielem) = -(y3-y2)*xsur9
        a23(ielem) = -y2*xsur9
        a31(ielem) = -(y3-y2)*xsur9
        a32(ielem) =  y3*xsur9
        a41(ielem) = -(y3-y2)*xsur6
        a42(ielem) =  y3*xsur6
        a43(ielem) = -y2*xsur6
!
!   DIAGONAL TERMS
!   THE SUM OF THE MATRIX COLUMNS IS 0 (VECTOR)
!
        a11(ielem) = - a12(ielem) - a13(ielem)
        a22(ielem) = - a21(ielem) - a23(ielem)
        a33(ielem) = - a31(ielem) - a32(ielem)
!
      ENDDO ! IELEM
!
        ELSEIF(icoord.EQ.2) THEN
!
!================================
!  DERIVATIVE WRT Y  =
!================================
!
        DO ielem = 1 , nelem
!
!   INITIALISES THE GEOMETRICAL VARIABLES
!
        x2  =  xel(ielem,2)
        x3  =  xel(ielem,3)
!
!   EXTRADIAGONAL TERMS
!
        a12(ielem) = -x3*xsur9
        a13(ielem) =  x2*xsur9
        a21(ielem) = -(x2-x3)*xsur9
        a23(ielem) =  x2*xsur9
        a31(ielem) = -(x2-x3)*xsur9
        a32(ielem) = -x3*xsur9
        a41(ielem) = -(x2-x3)*xsur6
        a42(ielem) = -x3*xsur6
        a43(ielem) =  x2*xsur6
!
!   DIAGONAL TERMS
!   THE SUM OF THE MATRIX COLUMNS IS 0 (VECTOR)
!
        a11(ielem) = - a12(ielem) - a13(ielem)
        a22(ielem) = - a21(ielem) - a23(ielem)
        a33(ielem) = - a31(ielem) - a32(ielem)
!
        ENDDO ! IELEM
!
        ELSE
!
          WRITE(lu,201) icoord
          CALL plante(0)
!
        ENDIF
!
201       FORMAT(1x,'MT13BA (BIEF) : IMPOSSIBLE COMPONENT ',
     &              1i6,' CHECK ICOORD')
!
!-----------------------------------------------------------------------
!
      RETURN
      END