v8p2r0/html/mt11ba_8f_source.html

 !                   *****************
                     SUBROUTINE mt11ba
 !                   *****************
 !
      &(  a11 , a12 , a13 ,
      &   a21 , a22 , a23 ,
      &   a31 , a32 , a33 ,
      &   a41 , a42 , a43 ,
      &   xmul,sf,f,xel,yel,ikle1,ikle2,ikle3,ikle4,
      &   nelem,nelmax,icoord)
 !
 !***********************************************************************
 ! BIEF   V6P1                                   21/08/2010
 !***********************************************************************
 !
 !brief    COMPUTES THE COEFFICIENTS OF THE FOLLOWING MATRIX:
 !code
 !+  EXAMPLE WITH ICOORD=1
 !+
 !+                   /           D
 !+  A(I,J)= -XMUL   /  PSI2(J) * --( F * PSI1(I) ) D(OMEGA)
 !+                 /OMEGA        DX
 !+
 !+
 !+  BEWARE THE MINUS SIGN !!
 !+
 !+  PSI1: BASES OF TYPE QUASI-BUBBLE TRIANGLE
 !+  PSI2: BASES OF TYPE P1 TRIANGLE
 !+
 !+  IT WOULD BE A DERIVATIVE WRT Y WITH ICOORD=2
 !
 !warning  THE JACOBIAN MUST BE POSITIVE
 !
 !history  J-M HERVOUET (LNH)    ; C MOULIN (LNH)
 !+        09/12/94
 !+        V5P1
 !+
 !
 !history  N.DURAND (HRW), S.E.BOURBAN (HRW)
 !+        13/07/2010
 !+        V6P0
 !+   Translation of French comments within the FORTRAN sources into
 !+   English comments
 !
 !history  N.DURAND (HRW), S.E.BOURBAN (HRW)
 !+        21/08/2010
 !+        V6P0
 !+   Creation of DOXYGEN tags for automated documentation and
 !+   cross-referencing of the FORTRAN sources
 !
 !~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 !| A11            |<--| ELEMENTS OF MATRIX
 !| A12            |<--| ELEMENTS OF MATRIX
 !| A13            |<--| ELEMENTS OF MATRIX
 !| A21            |<--| ELEMENTS OF MATRIX
 !| A22            |<--| ELEMENTS OF MATRIX
 !| A23            |<--| ELEMENTS OF MATRIX
 !| A31            |<--| ELEMENTS OF MATRIX
 !| A32            |<--| ELEMENTS OF MATRIX
 !| A33            |<--| ELEMENTS OF MATRIX
 !| A41            |<--| ELEMENTS OF MATRIX
 !| A42            |<--| ELEMENTS OF MATRIX
 !| A43            |<--| ELEMENTS OF MATRIX
 !| F              |-->| FUNCTION USED IN THE FORMULA
 !| ICOORD         |-->| 1: DERIVATIVE ALONG X, 2: ALONG Y
 !| IKLE1          |-->| FIRST POINTS OF TRIANGLES
 !| IKLE2          |-->| SECOND POINTS OF TRIANGLES
 !| IKLE3          |-->| THIRD POINTS OF TRIANGLES
 !| IKLE4          |-->| FOURTH POINTS OF TRIANGLES (QUADRATIC)
 !| IKLE5          |-->| FIFTH POINTS OF TRIANGLES (QUADRATIC)
 !| IKLE6          |-->| SIXTH POINTS OF TRIANGLES (QUADRATIC)
 !| NELEM          |-->| NUMBER OF ELEMENTS
 !| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
 !| SF             |-->| STRUCTURE OF FUNCTIONS F
 !| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
 !| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
 !| XMUL           |-->| MULTIPLICATION FACTOR
 !~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 !
       USE bief, ex_mt11ba => mt11ba
 !
       USE declarations_special
       IMPLICIT NONE
 !
 !+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 !
       INTEGER, INTENT(IN) :: NELEM,NELMAX,ICOORD
       INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax)
       INTEGER, INTENT(IN) :: IKLE3(nelmax),IKLE4(nelmax)
 !
       DOUBLE PRECISION, INTENT(INOUT) :: A11(*),A12(*),A13(*)
       DOUBLE PRECISION, INTENT(INOUT) :: A21(*),A22(*),A23(*)
       DOUBLE PRECISION, INTENT(INOUT) :: A31(*),A32(*),A33(*)
       DOUBLE PRECISION, INTENT(INOUT) :: A41(*),A42(*),A43(*)
 !
       DOUBLE PRECISION, INTENT(IN) :: XMUL
       DOUBLE PRECISION, INTENT(IN) :: F(*)
 !
 !     STRUCTURE OF F
       TYPE(bief_obj), INTENT(IN) :: SF
 !
       DOUBLE PRECISION, INTENT(IN) :: XEL(nelmax,3),YEL(nelmax,3)
 !
 !+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 !
       INTEGER IELEM,IELMF
       DOUBLE PRECISION X2,X3,Y2,Y3,F1,F2,F3,F4,XSUR72,XSUR36,XSUR18
       DOUBLE PRECISION XSU216
 !
 !-----------------------------------------------------------------------
 !
       ielmf=sf%ELM
 !
       xsu216 = xmul /216.d0
       xsur72 = xmul / 72.d0
       xsur36 = xmul / 36.d0
       xsur18 = xmul / 18.d0
 !
 !-----------------------------------------------------------------------
 !  CASE WHERE F IS OF TYPE P1
 !-----------------------------------------------------------------------
 !
       IF(ielmf.EQ.11) THEN
 !
 !================================
 !  DERIVATIVE WRT X  =
 !================================
 !
         IF(icoord.EQ.1) THEN
 !
 !   LOOP ON THE ELEMENTS
 !
         DO ielem = 1 , nelem
 !
 !   INITIALISES THE GEOMETRICAL VARIABLES
 !
         y2 = yel(ielem,2)
         y3 = yel(ielem,3)
 !
         f1  =  f(ikle1(ielem))
         f2  =  f(ikle2(ielem))
         f3  =  f(ikle3(ielem))
 !
 !   EXTRADIAGONAL TERMS
 !
         a12(ielem)=(5*y3*f3+5*y3*f2+14*y3*f1-18*y2*f2-18*y2*f1)*xsu216
         a13(ielem)=(18*y3*f3+18*y3*f1-5*y2*f3-5*y2*f2-14*y2*f1)*xsu216
         a21(ielem)=-(5*y3*f3+14*y3*f2+5*y3*f1-5*y2*f3+4*y2*
      &                                               f2+13*y2*f1)*xsu216
         a23(ielem)=-(18*y3*f3+18*y3*f2-13*y2*f3-4*y2*f2+5*y2*f1)*xsu216
         a31(ielem)=(4*y3*f3-5*y3*f2+13*y3*f1+14*y2*f3+5*y2*
      &                                               f2+5*y2*f1)*xsu216
         a32(ielem)=-(4*y3*f3+13*y3*f2-5*y3*f1-18*y2*f3-18*y2*f2)*xsu216
         a41(ielem)=-(y3-y2)*(f3+f2+f1)*xsur18
         a42(ielem)=y3*(f3+f2+f1)*xsur18
         a43(ielem)=-y2*(f3+f2+f1)*xsur18
 !
 !   DIAGONAL TERMS
 !
         a11(ielem)=(13*y3*f3-5*y3*f2+40*y3*f1+5*y2*f3-13*y2*
      &                                               f2-40*y2*f1)*xsu216
         a22(ielem)=-(13*y3*f3+40*y3*f2-5*y3*f1-18*y2*f3+18*y2*f1)*xsu216
         a33(ielem)=-(18*y3*f2-18*y3*f1-40*y2*f3-13*y2*f2+5*y2*f1)*xsu216
 !
       ENDDO ! IELEM
 !
         ELSEIF(icoord.EQ.2) THEN
 !
 !================================
 !  DERIVATIVE WRT Y  =
 !================================
 !
         DO ielem = 1 , nelem
 !
 !   INITIALISES THE GEOMETRICAL VARIABLES
 !
         x2  =  xel(ielem,2)
         x3  =  xel(ielem,3)
 !
         f1  =  f(ikle1(ielem))
         f2  =  f(ikle2(ielem))
         f3  =  f(ikle3(ielem))
 !
 !   EXTRADIAGONAL TERMS
 !
         a12(ielem)=(18*x2*f2+18*x2*f1-5*x3*f3-5*x3*f2-14*x3*f1)*xsu216
         a13(ielem)=(5*x2*f3+5*x2*f2+14*x2*f1-18*x3*f3-18*x3*f1)*xsu216
         a21(ielem)=-(5*x2*f3-4*x2*f2-13*x2*f1-5*x3*f3-14*x3*
      &   f2-5*x3*f1)*xsu216
         a23(ielem)=-(13*x2*f3+4*x2*f2-5*x2*f1-18*x3*f3-18*x3*f2)*xsu216
         a31(ielem)=-(14*x2*f3+5*x2*f2+5*x2*f1+4*x3*f3-5*x3*
      &   f2+13*x3*f1)*xsu216
         a32(ielem)=-(18*x2*f3+18*x2*f2-4*x3*f3-13*x3*f2+5*x3*f1)*xsu216
         a41(ielem)=-(x2-x3)*(f3+f2+f1)*xsur18
         a42(ielem)=-x3*(f3+f2+f1)*xsur18
         a43(ielem)=x2*(f3+f2+f1)*xsur18
 !
 !   DIAGONAL TERMS
 !
         a11(ielem)=-(5*x2*f3-13*x2*f2-40*x2*f1+13*x3*f3-5*x3
      &                *f2+40*x3*f1)*xsu216
         a22(ielem)=-(18*x2*f3-18*x2*f1-13*x3*f3-40*x3*f2+5*x3*f1)*xsu216
         a33(ielem)=-(40*x2*f3+13*x2*f2-5*x2*f1-18*x3*f2+18*x3*f1)*xsu216
 !
         ENDDO ! IELEM
 !
         ELSE
 !
           WRITE(lu,201) icoord
           CALL plante(0)
           stop
         ENDIF
 !
 !
 !-----------------------------------------------------------------------
 !  CASE WHERE F IS OF TYPE QUASI-BUBBLE
 !-----------------------------------------------------------------------
 !
       ELSEIF(ielmf.EQ.12) THEN
 !
 !================================
 !  DERIVATIVE WRT X  =
 !================================
 !
         IF(icoord.EQ.1) THEN
 !
 !   LOOP ON THE ELEMENTS
 !
         DO ielem = 1 , nelem
 !
 !   INITIALISES THE GEOMETRICAL VARIABLES
 !
         y2 = yel(ielem,2)
         y3 = yel(ielem,3)
 !
         f1  =  f(ikle1(ielem))
         f2  =  f(ikle2(ielem))
         f3  =  f(ikle3(ielem))
         f4  =  f(ikle4(ielem))
 !
 !   EXTRADIAGONAL TERMS
 !
         a12(ielem)=(y3*f3+2*y3*f4+y3*f2+4*y3*f1-6*y2*f2-6*y2*f1)*xsur72
         a13(ielem)=(6*y3*f3+6*y3*f1-y2*f3-2*y2*f4-y2*f2-4*y2*f1)*xsur72
         a21(ielem)=-(y3*f3+2*y3*f4+4*y3*f2+y3*f1-y2*f3-2*y2*f4
      &                                         +2*y2*f2+5*y2*f1)*xsur72
         a23(ielem)=-(6*y3*f3+6*y3*f2-5*y2*f3+2*y2*f4-2*y2*f2
      &                                                   +y2*f1)*xsur72
         a31(ielem)=(2*y3*f3-2*y3*f4-y3*f2+5*y3*f1+4*y2*f3+2*
      &                                        y2*f4+y2*f2+y2*f1)*xsur72
         a32(ielem)=-(2*y3*f3-2*y3*f4+5*y3*f2-y3*f1-6*y2*f3-6
      &                                                   *y2*f2)*xsur72
         a41(ielem)=-(y3-y2)*(f3+3*f4+f2+f1)*xsur36
         a42(ielem)=y3*(f3+3*f4+f2+f1)*xsur36
         a43(ielem)=-y2*(f3+3*f4+f2+f1)*xsur36
 !
 !   DIAGONAL TERMS
 !
         a11(ielem)=(5*y3*f3-2*y3*f4-y3*f2+14*y3*f1+y2*f3+2*y2
      &                                     *f4-5*y2*f2-14*y2*f1)*xsur72
         a22(ielem)=-(5*y3*f3-2*y3*f4+14*y3*f2-y3*f1-6*y2*f3+
      &                                                  6*y2*f1)*xsur72
         a33(ielem)=-(6*y3*f2-6*y3*f1-14*y2*f3+2*y2*f4-5*y2*
      &                                                 f2+y2*f1)*xsur72
 !
         ENDDO ! IELEM
 !
         ELSEIF(icoord.EQ.2) THEN
 !
 !================================
 !  DERIVATIVE WRT Y  =
 !================================
 !
         DO ielem = 1 , nelem
 !
 !   INITIALISES THE GEOMETRICAL VARIABLES
 !
         x2  =  xel(ielem,2)
         x3  =  xel(ielem,3)
 !
         f1  =  f(ikle1(ielem))
         f2  =  f(ikle2(ielem))
         f3  =  f(ikle3(ielem))
         f4  =  f(ikle4(ielem))
 !
 !   EXTRADIAGONAL TERMS
 !
         a12(ielem)=(6*x2*f2+6*x2*f1-x3*f3-2*x3*f4-x3*f2-4*x3*f1)*xsur72
         a13(ielem)=(x2*f3+2*x2*f4+x2*f2+4*x2*f1-6*x3*f3-6*x3*f1)*xsur72
         a21(ielem)=-(x2*f3+2*x2*f4-2*x2*f2-5*x2*f1-x3*f3-2*x3
      &                                        *f4-4*x3*f2-x3*f1)*xsur72
         a23(ielem)=-(5*x2*f3-2*x2*f4+2*x2*f2-x2*f1-6*x3*f3-6
      &                                                   *x3*f2)*xsur72
         a31(ielem)=-(4*x2*f3+2*x2*f4+x2*f2+x2*f1+2*x3*f3-2*x3
      &                                        *f4-x3*f2+5*x3*f1)*xsur72
         a32(ielem)=-(6*x2*f3+6*x2*f2-2*x3*f3+2*x3*f4-5*x3*f2
      &                                                   +x3*f1)*xsur72
         a41(ielem)=-(x2-x3)*(f3+3*f4+f2+f1)*xsur36
         a42(ielem)=-x3*(f3+3*f4+f2+f1)*xsur36
         a43(ielem)=x2*(f3+3*f4+f2+f1)*xsur36
 !
 !   DIAGONAL TERMS
 !
         a11(ielem)=-(x2*f3+2*x2*f4-5*x2*f2-14*x2*f1+5*x3*f3-
      &                                   2*x3*f4-x3*f2+14*x3*f1)*xsur72
         a22(ielem)=-(6*x2*f3-6*x2*f1-5*x3*f3+2*x3*f4-14*x3*
      &                                                 f2+x3*f1)*xsur72
         a33(ielem)=-(14*x2*f3-2*x2*f4+5*x2*f2-x2*f1-6*x3*f2+
      &                                                  6*x3*f1)*xsur72
 !
         ENDDO ! IELEM
 !
         ELSE
 !
           WRITE(lu,201) icoord
           CALL plante(0)
           stop
         ENDIF
 !
 !-----------------------------------------------------------------------
 !
       ELSE
         WRITE(lu,101) ielmf
 101     FORMAT(1x,'MT11BA (BIEF) :',/,
      &         1x,'DISCRETIZATION OF F : ',1i6,' NOT AVAILABLE')
         CALL plante(0)
         stop
       ENDIF
 !
 201   FORMAT(1x,'MT11BA (BIEF) : IMPOSSIBLE COMPONENT ',
      &          1i6,' CHECK ICOORD')
 !
 !-----------------------------------------------------------------------
 !
       RETURN
       END
declarations_special
Definition: declarations_special.F:3

mt11ba
subroutine mt11ba(A11, A12, A13, A21, A22, A23, A31, A32, A33, A41, A42, A43, XMUL, SF, F, XEL, YEL, IKLE1, IKLE2, IKLE3, IKLE4, NELEM, NELMAX, ICOORD)
Definition: mt11ba.f:12

declarations_special::lu
integer lu
Definition: declarations_special.F:45

bief
Definition: bief.f:3