mt11aa.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mt11aa
!                   *****************
!
     &(  a11 , a12 , a13 ,
     &   a21 , a22 , a23 ,
     &   a31 , a32 , a33 ,
     &   xmul,sf,f,xel,yel,ikle1,ikle2,ikle3,nelem,nelmax,icoord)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COEFFICIENTS OF THE FOLLOWING MATRIX:
!code
!+  EXAMPLE WITH ICOORD=1
!+
!+                  /           D
!+  A(I,J)=- XMUL  /  PSI2(J) * -- ( PSI1(I) F ) ) D(OMEGA)
!+                /OMEGA        DX
!+
!+
!+  BEWARE THE MINUS SIGN !!
!+
!+  PSI1: LINEAR
!+  PSI2: LINEAR
!+
!+  IT WOULD BE A DERIVATIVE WRT Y WITH ICOORD=2
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  J-M HERVOUET (LNH)    ; C MOULIN (LNH)
!+        09/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A11            |<--| ELEMENTS OF MATRIX
!| A12            |<--| ELEMENTS OF MATRIX
!| A13            |<--| ELEMENTS OF MATRIX
!| A21            |<--| ELEMENTS OF MATRIX
!| A22            |<--| ELEMENTS OF MATRIX
!| A23            |<--| ELEMENTS OF MATRIX
!| A31            |<--| ELEMENTS OF MATRIX
!| A32            |<--| ELEMENTS OF MATRIX
!| A33            |<--| ELEMENTS OF MATRIX
!| F              |-->| FUNCTION USED IN THE FORMULA
!| ICOORD         |-->| 1: DERIVATIVE ALONG X, 2: ALONG Y
!| IKLE1          |-->| FIRST POINTS OF TRIANGLES
!| IKLE2          |-->| SECOND POINTS OF TRIANGLES
!| IKLE3          |-->| THIRD POINTS OF TRIANGLES
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| STRUCTURE OF FUNCTIONS F
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!| XMUL           |-->| MULTIPLICATION FACTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mt11aa => mt11aa
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX,ICOORD
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
!
      DOUBLE PRECISION, INTENT(INOUT) :: A11(*),A12(*),A13(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A21(*),A22(*),A23(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A31(*),A32(*),A33(*)
!
      DOUBLE PRECISION, INTENT(IN) :: XMUL
      DOUBLE PRECISION, INTENT(IN) :: F(*)
!
!     STRUCTURE OF F
      TYPE(bief_obj), INTENT(IN) :: SF
!
!
      DOUBLE PRECISION, INTENT(IN) :: XEL(nelmax,3),YEL(nelmax,3)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IELMF
!
      DOUBLE PRECISION SUR24,X2,X3,Y2,Y3,F1,F2,F3
!
!-----------------------------------------------------------------------
!
      sur24 = xmul/24.d0
!
!-----------------------------------------------------------------------
!
      ielmf=sf%ELM
!
!  SAME RESULT WHETHER F IS LINEAR OR QUASI-BUBBLE
!
      IF(ielmf.EQ.11.OR.ielmf.EQ.12) THEN
!
!================================
!  CASE OF DERIVATIVE WRT X =
!================================
!
      IF(icoord.EQ.1) THEN
!
!   LOOP ON THE ELEMENTS
!
      DO ielem = 1 , nelem
!
!   INITIALISES THE GEOMETRICAL VARIABLES
!
      y2 = yel(ielem,2)
      y3 = yel(ielem,3)
!
      f1  =  f(ikle1(ielem)) * sur24
      f2  =  f(ikle2(ielem)) * sur24
      f3  =  f(ikle3(ielem)) * sur24
!
!   DIAGONAL TERMS
!
      a11(ielem) =     y2  * (f3-f2-4*f1)  +     y3  * ( f3-f2+4*f1)
      a22(ielem) = (y2+y2) * (f3-f1)       +     y3  * (-f3-4*f2+f1)
      a33(ielem) =     y2  * (4*f3+f2-f1)  + (y3+y3) * (-f2+f1)
!
!   EXTRADIAGONAL TERMS
!
      a12(ielem)  =-(y2+y2) * (f2+f1)        +     y3  * (f3+f2+f1+f1)
      a13(ielem)  =      y2 * (-f3-f2-f1-f1) + (y3+y3) * (f3+f1)
      a23(ielem)  =      y2 * (f3-f1)        - (y3+y3) * (f3+f2)
      a21(ielem)  =      y2 * (f3-f1)        +      y3 * (-f3-f2-f2-f1)
      a31(ielem)  =      y2 * (f3+f3+f2+f1)  +      y3 * (-f2+f1)
      a32(ielem)  = (y2+y2) * (f3+f2)        +      y3 * (-f2+f1)
!
      ENDDO ! IELEM
!
      ELSEIF(icoord.EQ.2) THEN
!
!================================
!  CASE OF DERIVATIVE WRT Y =
!================================
!
      DO ielem = 1 , nelem
!
!   INITIALISES THE GEOMETRICAL VARIABLES
!
      x2  =  xel(ielem,2)
      x3  =  xel(ielem,3)
!
      f1  =  f(ikle1(ielem)) * sur24
      f2  =  f(ikle2(ielem)) * sur24
      f3  =  f(ikle3(ielem)) * sur24
!
!   DIAGONAL TERMS
!
      a11(ielem) =     x2  * (-f3+f2+4*f1) +   x3  * (-f3+f2-4*f1)
      a22(ielem) = (x2+x2) * (-f3+f1)      +   x3  * (f3+4*f2-f1)
      a33(ielem) =     x2  * (-4*f3-f2+f1) + (x3+x3) * (f2-f1)
!
!   EXTRADIAGONAL TERMS
!
      a12(ielem)  = (x2+x2) * (f2+f1)        +     x3  * (-f3-f2-f1-f1)
      a13(ielem)  =      x2 * (f3+f2+f1+f1)  - (x3+x3) * (f3+f1)
      a23(ielem)  =      x2 * (-f3+f1)       + (x3+x3) * (f3+f2)
      a21(ielem)  =      x2 * (-f3+f1)       +      x3 * (f3+f2+f2+f1)
      a31(ielem)  =      x2 * (-f3-f3-f2-f1) +      x3 * (f2-f1)
      a32(ielem)  =-(x2+x2) * (f3+f2)        +      x3 * (f2-f1)
!
      ENDDO ! IELEM
!
        ELSE
!
          WRITE(lu,201) icoord
201       FORMAT(1x,'MT11AA (BIEF) : IMPOSSIBLE COMPONENT ',
     &              1i6,' CHECK ICOORD')
          CALL plante(0)
        ENDIF
!
!     ELSEIF(IELMF.EQ. ) THEN
!     OTHER TYPES OF FUNCTIONS F
!
!-----------------------------------------------------------------------
!
      ELSE
        WRITE(lu,101) ielmf
101     FORMAT(1x,'MT11AA (BIEF) :',/,
     &         1x,'DISCRETISATION OF F: ',1i6,' NOT AVAILABLE')
        CALL plante(0)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END