mt07cc.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mt07cc
!                   *****************
!
     &( a11 , a12 , a13 , a14 , a15 , a16 ,
     &        a22 , a23 , a24 , a25 , a26 ,
     &              a33 , a34 , a35 , a36 ,
     &                    a44 , a45 , a46 ,
     &                          a55 , a56 ,
     &                                a66 ,
     &  xmul,sf,f,surfac,nelem,nelmax)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    BUILDS THE FOLLOWING MATRIX
!+                FOR P2 TRIANGLES:
!code
!+            T*M + (1-T) *DM
!+
!+            M  IS THE MASS MATRIX P2*P2
!+            DM IS MASS-LUMPED M
!+            T IS A VECTOR CONSTANT BY ELEMENT
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  A FROEHLY (MATMECA)
!+        01/08/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A11            |<--| ELEMENTS OF MATRIX
!| ...            |<--| ELEMENTS OF MATRIX
!| A66            |<--| ELEMENTS OF MATRIX
!| F              |-->| FUNCTION USED IN THE FORMULA
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| STRUCTURE OF FUNCTIONS F
!| SURFAC         |-->| AREA OF TRIANGLES
!| XMUL           |-->| MULTIPLICATION FACTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief!, EX_MT07CC => MT07CC
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
!
      DOUBLE PRECISION, INTENT(INOUT) :: A11(*),A12(*),A13(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A14(*),A15(*),A16(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A22(*),A23(*),A24(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A25(*),A26(*),A33(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A34(*),A35(*),A36(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A44(*),A45(*),A46(*)
      DOUBLE PRECISION, INTENT(INOUT) :: A55(*),A56(*),A66(*)
!
      DOUBLE PRECISION, INTENT(IN) :: XMUL
      DOUBLE PRECISION, INTENT(IN) :: F(*)
!
!     STRUCTURE OF F
      TYPE(bief_obj), INTENT(IN) :: SF
!
      DOUBLE PRECISION, INTENT(IN) :: SURFAC(nelmax)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     DECLARATIONS SPECIFIC TO THIS SUBROUTINE
!
      DOUBLE PRECISION T,XSUR30,XSUR45,XSUR180
      INTEGER IELEM
!
!=======================================================================
!
      xsur30 = xmul/30.d0
      xsur45 = xmul/45.d0
      xsur180 = xmul/180.d0
!
!-----------------------------------------------------------------------
!
      IF(sf%ELM.EQ.10) THEN
!
!-----------------------------------------------------------------------
!
!   P0 DISCRETISATION OF F:
!
      DO ielem = 1 , nelem
!
!   INITIALISES THE INTERMEDIATE VARIABLES
!
        t = f(ielem)
!
!  DIAGONAL TERMS
!
!  FOR P2 ELEMENTS, DM(1) = DM(2) = DM(3) = 0
!               AND DM(4) = DM(5) = DM(6) = S/3
        a11(ielem) = t*surfac(ielem)*xsur30
        a22(ielem) = a11(ielem)
        a33(ielem) = a11(ielem)
        a44(ielem) = (15.d0-7.d0*t)*surfac(ielem)*xsur45
        a55(ielem) = a44(ielem)
        a66(ielem) = a44(ielem)
!
!  EXTRADIAGONAL TERMS
!
        a12(ielem) = -surfac(ielem)*t*xsur180
        a13(ielem) = a12(ielem)
        a14(ielem) = 0.d0
        a15(ielem) = -surfac(ielem)*t*xsur45
        a16(ielem) = 0.d0
        a23(ielem) = a12(ielem)
        a24(ielem) = 0.d0
        a25(ielem) = 0.d0
        a26(ielem) = a15(ielem)
        a34(ielem) = a15(ielem)
        a35(ielem) = 0.d0
        a36(ielem) = 0.d0
        a45(ielem) = (15.d0-11.d0*t)*surfac(ielem)*xsur45
        a46(ielem) = a45(ielem)
        a56(ielem) = a45(ielem)
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
!  ANOTHER DISCRETISATION OF F
!      ELSEIF(SF%ELM.EQ.XX) THEN
!
!-----------------------------------------------------------------------
!
      ELSE
!
        WRITE(lu,101) sf%ELM,sf%NAME
101     FORMAT(1x,'MT07CC (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F NOT AVAILABLE:',1i6,
     &         1x,'REAL NAME: ',a6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END