mt07bb.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mt07bb
!                   *****************
!
     &( a11 , a12 , a13 , a14 ,
     &        a22 , a23 , a24 ,
     &              a33 , a34 ,
     &                    a44 ,
     &  xmul,sf,f,surfac,nelem,nelmax)
!
!***********************************************************************
! BIEF   V6P0                                   21/08/2010
!***********************************************************************
!
!brief    BUILDS THE FOLLOWING MATRIX
!+                FOR QUASI-BUBBLE TRIANGLES:
!code
!+            T*M + (1-T) *DM
!+
!+            M  IS THE MASS MATRIX QB*QB
!+            DM IS MASS-LUMPED M
!+            T IS A VECTOR CONSTANT BY ELEMENT
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  J-M HERVOUET (LNH)    ; C MOULIN (LNH)
!+        10/01/95
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A11            |<--| ELEMENTS OF MATRIX
!| A12            |<--| ELEMENTS OF MATRIX
!| A13            |<--| ELEMENTS OF MATRIX
!| A14            |<--| ELEMENTS OF MATRIX
!| A22            |<--| ELEMENTS OF MATRIX
!| A23            |<--| ELEMENTS OF MATRIX
!| A24            |<--| ELEMENTS OF MATRIX
!| A33            |<--| ELEMENTS OF MATRIX
!| A34            |<--| ELEMENTS OF MATRIX
!| A44            |<--| ELEMENTS OF MATRIX
!| F              |-->| FUNCTION USED IN THE FORMULA
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| STRUCTURE OF FUNCTIONS F
!| SURFAC         |-->| AREA OF TRIANGLES
!| XMUL           |-->| MULTIPLICATION FACTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mt07bb => mt07bb
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
!
      DOUBLE PRECISION, INTENT(INOUT) :: A11(*),A12(*),A13(*),A14(*)
      DOUBLE PRECISION, INTENT(INOUT) ::        A22(*),A23(*),A24(*)
      DOUBLE PRECISION, INTENT(INOUT) ::               A33(*),A34(*)
      DOUBLE PRECISION, INTENT(INOUT) ::                      A44(*)
!
      DOUBLE PRECISION, INTENT(IN) :: XMUL
      DOUBLE PRECISION, INTENT(IN) :: F(*)
!
!     STRUCTURE OF F
      TYPE(bief_obj), INTENT(IN) :: SF
!
      DOUBLE PRECISION, INTENT(IN) :: SURFAC(nelmax)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     DECLARATIONS SPECIFIC TO THIS SUBROUTINE
!
      DOUBLE PRECISION T,XSUR06,XSUR09,XSUR36
      INTEGER IELEM
!
!=======================================================================
!
      xsur06 = xmul/6.d0
      xsur09 = xmul/9.d0
      xsur36 = xmul/36.d0
!
!-----------------------------------------------------------------------
!
      IF(sf%ELM.EQ.10) THEN
!
!-----------------------------------------------------------------------
!
!   P0 DISCRETISATION OF F:
!
      DO ielem = 1 , nelem
!
!   INITIALISES THE INTERMEDIATE VARIABLES
!
        t = f(ielem)
!
!  DIAGONAL TERMS
!
        a11(ielem) = -(t-2)*surfac(ielem)*xsur09
        a22(ielem) = a11(ielem)
        a33(ielem) = a11(ielem)
        a44(ielem) = -(t-2)*surfac(ielem)*xsur06
!
!  EXTRADIAGONAL TERMS
!
        a12(ielem) = surfac(ielem)*t*xsur36
        a13(ielem) = a12(ielem)
        a14(ielem) = 2*a12(ielem)
        a23(ielem) = a12(ielem)
        a24(ielem) = a14(ielem)
        a34(ielem) = a14(ielem)
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
!  ANOTHER DISCRETISATION OF F
!      ELSEIF(SF%ELM.EQ.XX) THEN
!
!-----------------------------------------------------------------------
!
      ELSE
!
        WRITE(lu,101) sf%ELM,sf%NAME
101     FORMAT(1x,'MT07BB (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F NOT AVAILABLE:',1i6,
     &         1x,'REAL NAME: ',a6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END