mt06oo.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mt06oo
!                   *****************
!
     &(a11,a12,a22,xmul,sf,f,lgseg,ikle1,ikle2,nbor,nelem,nelmax)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COEFFICIENTS OF THE FOLLOWING MATRIX:
!code
!+                              /
!+                    A    =   /  F (P *P )*J(X,Y) DX
!+                     I J    /L      I  J
!+
!+     BY ELEMENTARY CELL; THE ELEMENT IS THE P1 SEGMENT
!+
!+     J(X,Y): JACOBIAN OF THE ISOPARAMETRIC TRANSFORMATION
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  F  LEPEINTRE (LNH)
!+        04/09/92
!+
!+
!
!history  J-M HERVOUET (LNHE)
!+        20/03/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A11            |<--| ELEMENTS OF MATRIX
!| A12            |<--| ELEMENTS OF MATRIX
!| A13            |<--| ELEMENTS OF MATRIX
!| A22            |<--| ELEMENTS OF MATRIX
!| A23            |<--| ELEMENTS OF MATRIX
!| A33            |<--| ELEMENTS OF MATRIX
!| F              |-->| FUNCTION F USED IN THE FORMULA
!| IKLE1          |-->| FIRST POINTS OF SEGMENTS
!| IKLE2          |-->| SECOND POINTS OF SEGMENTS
!| LGSEG          |-->| LENGTH OF SEGMENTS
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| BIEF_OBJ STRUCTURE OF F
!| SURFAC         |-->| AREA OF TRIANGLES
!| XMUL           |-->| MULTIPLICATION FACTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mt06oo => mt06oo
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(*),IKLE2(*),NBOR(*)
!
      DOUBLE PRECISION, INTENT(IN) :: XMUL
!
      DOUBLE PRECISION, INTENT(IN) :: F(*)
!
!     STRUCTURE OF F
      TYPE(bief_obj), INTENT(IN) :: SF
!
      DOUBLE PRECISION, INTENT(IN)    :: LGSEG(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: A11(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: A12(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: A22(nelmax)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IELMF
      DOUBLE PRECISION SUR12,DET1,F1,F2,F12
!
!-----------------------------------------------------------------------
!
      sur12  = xmul/12.d0
!
!-----------------------------------------------------------------------
!
      ielmf = sf%ELM
!
!     F CONSTANT BY SEGMENT, IN A BOUNDARY ARRAY
!
      IF(ielmf.EQ.0) THEN
!
        DO ielem = 1 , nelem
!         TO BE OPTIMISED...
          f1 = f(ielem)
          f2 = f(ielem)
!
          f12 = f1 + f2
!
          det1 = lgseg(ielem) * sur12
!
          a11(ielem) = det1 * (f12+2*f1)
          a12(ielem) = det1 * f12
          a22(ielem) = det1 * (f12+2*f2)
!
        ENDDO
!
!     F LINEAR BY SEGMENT, IN A BOUNDARY ARRAY
!     NOTE: IKLE IS HERE A BOUNDARY IKLE
!
      ELSEIF(ielmf.EQ.1) THEN
!
        DO ielem = 1 , nelem
!
          f1 = f(ikle1(ielem))
          f2 = f(ikle2(ielem))
          f12 = f1 + f2
          det1 = lgseg(ielem) * sur12
          a11(ielem) = det1 * (f12+2*f1)
          a12(ielem) = det1 * f12
          a22(ielem) = det1 * (f12+2*f2)
!
        ENDDO
!
!     F LINEAR, IN AN ARRAY DEFINED ON THE DOMAIN
!
      ELSEIF(ielmf.EQ.11.OR.ielmf.EQ.21) THEN
!
        DO ielem = 1 , nelem
!
          f1 = f(nbor(ikle1(ielem)))
          f2 = f(nbor(ikle2(ielem)))
          f12 = f1 + f2
          det1 = lgseg(ielem) * sur12
          a11(ielem) = det1 * (f12+2*f1)
          a12(ielem) = det1 * f12
          a22(ielem) = det1 * (f12+2*f2)
!
        ENDDO
!
!     OTHER TYPES OF DISCRETISATION OF F
!
      ELSE
!
        WRITE(lu,101) ielmf,sf%NAME
101     FORMAT(1x,'MT0600 (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F NOT AVAILABLE:',1i6,
     &         1x,'REAL NAME: ',a6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END