mt06aa.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mt06aa
!                   *****************
!
     &( a11 , a12 , a13 ,
     &        a22 , a23 ,
     &              a33 ,
     &  xmul,sf,f,surfac,ikle1,ikle2,ikle3,nelem,nelmax)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COEFFICIENTS OF THE FOLLOWING MATRIX:
!code
!+                              /
!+                    A    =   /  F * (P *P )*J(X,Y) DXDY
!+                     I J    /S        I  J
!+
!+     BY ELEMENTARY CELL; THE ELEMENT IS THE P1 TRIANGLE
!+
!+     J(X,Y): JACOBIAN OF THE ISOPARAMETRIC TRANSFORMATION
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  J-M HERVOUET (LNH)
!+        29/10/99
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A11            |<--| ELEMENTS OF MATRIX
!| A12            |<--| ELEMENTS OF MATRIX
!| A13            |<--| ELEMENTS OF MATRIX
!| A22            |<--| ELEMENTS OF MATRIX
!| A23            |<--| ELEMENTS OF MATRIX
!| A33            |<--| ELEMENTS OF MATRIX
!| F              |-->| FUNCTION F USED IN THE FORMULA
!| IKLE1          |-->| FIRST POINTS OF TRIANGLES
!| IKLE2          |-->| SECOND POINTS OF TRIANGLES
!| IKLE3          |-->| THIRD POINTS OF TRIANGLES
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| BIEF_OBJ STRUCTURE OF F
!| SURFAC         |-->| AREA OF TRIANGLES
!| XMUL           |-->| MULTIPLICATION FACTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mt06aa => mt06aa
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
!
      DOUBLE PRECISION, INTENT(INOUT) :: A11(*),A12(*),A13(*)
      DOUBLE PRECISION, INTENT(INOUT) ::        A22(*),A23(*)
      DOUBLE PRECISION, INTENT(INOUT) ::               A33(*)
!
      DOUBLE PRECISION, INTENT(IN) :: XMUL
      DOUBLE PRECISION, INTENT(IN) :: F(*)
!
!     STRUCTURE OF F
      TYPE(bief_obj), INTENT(IN) :: SF
!
      DOUBLE PRECISION, INTENT(IN) :: SURFAC(nelmax)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     DECLARATIONS SPECIFIC TO THIS SUBROUTINE
!
      INTEGER IELMF,IELEM
!
      DOUBLE PRECISION SUR12,SUR60,DET1,DET2,F123,F1,F2,F3
!
!-----------------------------------------------------------------------
!
      sur60 = xmul/60.d0
      sur12 = xmul/12.d0
!
!-----------------------------------------------------------------------
!
      ielmf = sf%ELM
!
!-----------------------------------------------------------------------
!
!  CASE WHERE F IS LINEAR
!
      IF(ielmf.EQ.11) THEN
!
      DO ielem = 1 , nelem
!
      f1 = f(ikle1(ielem))
      f2 = f(ikle2(ielem))
      f3 = f(ikle3(ielem))
!
      f123 = f1 + f2 + f3
!
      det1 = surfac(ielem) * sur60
      det2 = det1 + det1
!
!***********************************************************************
!
!  ELEMENTS OFF THE DIAGONAL
!
      a12(ielem) = det1 * (f123+f123-f3)
      a13(ielem) = det1 * (f123+f123-f2)
      a23(ielem) = det1 * (f123+f123-f1)
!
!  DIAGONAL TERMS
!
      a11(ielem) = det2 * (f123+f1+f1)
      a22(ielem) = det2 * (f123+f2+f2)
      a33(ielem) = det2 * (f123+f3+f3)
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
!  CASE WHERE F IS LINEAR
!
      ELSEIF(ielmf.EQ.10) THEN
!
      DO ielem = 1 , nelem
!
      f1 = f(ielem)
!
      det1 = surfac(ielem) * sur12
      det2 = det1 + det1
!
!***********************************************************************
!
!  ELEMENTS OFF THE DIAGONAL
!
      a12(ielem) = det1 * f1
      a13(ielem) = det1 * f1
      a23(ielem) = det1 * f1
!
!  DIAGONAL TERMS
!
      a11(ielem) = det2 * f1
      a22(ielem) = det2 * f1
      a33(ielem) = det2 * f1
!
      ENDDO ! IELEM
!
!     OTHER TYPES OF DISCRETISATION OF F
!
!-----------------------------------------------------------------------
!
      ELSE
!
        WRITE(lu,101) ielmf,sf%NAME
101     FORMAT(1x,'MT06AA (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F NOT AVAILABLE:',1i6,
     &         1x,'REAL NAME: ',a6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END