v8p2r0/html/mt02aa_8f_source.html

 !                   *****************
                     SUBROUTINE mt02aa
 !                   *****************
 !
      &( a11 , a12 , a13 ,
      &        a22 , a23 ,
      &              a33 ,
      &  xmul,su,u,sv,v,
      &  xel,yel,surfac,ikle1,ikle2,ikle3,nelem,nelmax,formul)
 !
 !***********************************************************************
 ! BIEF   V6P1                                   21/08/2010
 !***********************************************************************
 !
 !brief    BUILDS THE DIFFUSION MATRIX FOR P1 TRIANGLES.
 !+
 !+            VISCOSITY CAN BE ISOTROPIC IF U IS A VECTOR WITH 1
 !+                DIMENSION. IT CAN BE ALSO TENSORIAL IF U IS A VECTOR
 !+                WITH 3 DIMENSIONS, THEN REPRESENTING NUXX, NUYY, NUXY.
 !
 !warning  THE JACOBIAN MUST BE POSITIVE
 !
 !history  J-M HERVOUET (LNH)    ; F  LEPEINTRE (LNH)
 !+        16/07/07
 !+        V5P8
 !+
 !
 !history  N.DURAND (HRW), S.E.BOURBAN (HRW)
 !+        13/07/2010
 !+        V6P0
 !+   Translation of French comments within the FORTRAN sources into
 !+   English comments
 !
 !history  N.DURAND (HRW), S.E.BOURBAN (HRW)
 !+        21/08/2010
 !+        V6P0
 !+   Creation of DOXYGEN tags for automated documentation and
 !+   cross-referencing of the FORTRAN sources
 !
 !~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 !| A11            |<--| ELEMENTS OF MATRIX
 !| A12            |<--| ELEMENTS OF MATRIX
 !| A13            |<--| ELEMENTS OF MATRIX
 !| A22            |<--| ELEMENTS OF MATRIX
 !| A23            |<--| ELEMENTS OF MATRIX
 !| A33            |<--| ELEMENTS OF MATRIX
 !| FORMUL         |-->| FORMULA DESCRIBING THE MATRIX
 !| IKLE1          |-->| FIRST POINTS OF TRIANGLES
 !| IKLE2          |-->| SECOND POINTS OF TRIANGLES
 !| IKLE3          |-->| THIRD POINTS OF TRIANGLES
 !| NELEM          |-->| NUMBER OF ELEMENTS
 !| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
 !| SU             |-->| BIEF_OBJ STRUCTURE OF U
 !| SURFAC         |-->| AREA OF TRIANGLES
 !| SV             |-->| BIEF_OBJ STRUCTURE OF V
 !| U              |-->| FUNCTION U USED IN THE FORMULA
 !| V              |-->| FUNCTION V USED IN THE FORMULA
 !| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
 !| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
 !| XMUL           |-->| MULTIPLICATION FACTOR
 !~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 !
       USE bief, ex_mt02aa => mt02aa
 !
       USE declarations_special
       IMPLICIT NONE
 !
 !+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 !
       INTEGER, INTENT(IN) :: NELEM,NELMAX
       INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
 !
       DOUBLE PRECISION, INTENT(INOUT) :: A11(*),A12(*),A13(*)
       DOUBLE PRECISION, INTENT(INOUT) ::        A22(*),A23(*)
       DOUBLE PRECISION, INTENT(INOUT) ::               A33(*)
       DOUBLE PRECISION, INTENT(IN)    :: XMUL
       DOUBLE PRECISION, INTENT(IN)    :: U(*),V(*)
 !     STRUCTURE OF U
       TYPE(bief_obj), INTENT(IN)      :: SU,SV
       DOUBLE PRECISION, INTENT(IN)    :: XEL(nelmax,3),YEL(nelmax,3)
       DOUBLE PRECISION, INTENT(IN)    :: SURFAC(nelmax)
       CHARACTER(LEN=16), INTENT(IN)   :: FORMUL
 !
 !+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 !
 !     DECLARATIONS SPECIFIC TO THIS SUBROUTINE
 !
       INTEGER IELMNU,IELMNV,IELEM,ISO,IAD2,IAD3,I1,I2,I3
 !
       DOUBLE PRECISION X2,X3,Y2,Y3,S2D,VISC1,VISC2,VISC3,BPE,CPF,APD
       DOUBLE PRECISION AUX,X2X3,Y2Y3,X2AUX,Y2AUX,X3AUX,Y3AUX,X2MX3,Y2MY3
       DOUBLE PRECISION SOMVX,SOMVY,SOMVZ,XSUR12,XSUR48
       DOUBLE PRECISION G1,G2,G3,COEF1,COEF2,G123
 !
 !=======================================================================
 !
       xsur12 = xmul / 12.d0
       xsur48 = xmul / 48.d0
 !
 !     EXTRACTS THE TYPE OF ELEMENT FOR VISCOSITY
 !
       ielmnu=su%ELM
       ielmnv=sv%ELM
       iso = su%DIM2
 !
       IF(ielmnu.EQ.10.AND.iso.EQ.1) THEN
 !
 !-----------------------------------------------------------------------
 !
 !  P0 DISCRETISATION FOR ISOTROPIC VISCOSITY:
 !
       DO ielem = 1 , nelem
 !
 !   INITIALISES THE GEOMETRICAL VARIABLES
 !
         x2  =  xel(ielem,2)
         x3  =  xel(ielem,3)
 !
         y2  =  yel(ielem,2)
         y3  =  yel(ielem,3)
 !
 !   INITIALISES THE INTERMEDIATE VARIABLES
 !
         s2d   = xmul*0.25d0/surfac(ielem)
         visc1 = u(ielem)*s2d
         bpe   = visc1*(y3**2 + x3**2)
         cpf   = visc1*(y2*y3 + x2*x3)
         apd   = visc1*(y2**2 + x2**2)
 !
 !  DIAGONAL TERMS
 !
         a11(ielem)= apd+bpe-2*cpf
         a22(ielem)= bpe
         a33(ielem)= apd
 !
 !  EXTRADIAGONAL TERMS
 !
         a12(ielem)= cpf-bpe
         a13(ielem)= cpf-apd
         a23(ielem)=-cpf
 !
 !   END OF THE LOOP ON THE ELEMENTS
 !
       ENDDO ! IELEM
 !
 !-----------------------------------------------------------------------
 !
 !  P0 DISCRETISATIO FOR NONISOTROPIC VISCOSITY
 !
       ELSEIF(ielmnu.EQ.10.AND.iso.EQ.3) THEN
 !
 !-----------------------------------------------------------------------
 !
 !  P0 DISCRETISATION FOR ISOTROPIC VISCOSITY:
 !
       DO ielem = 1 , nelem
 !
 !   INITIALISES THE GEOMETRICAL VARIABLES
 !
         x2  =  xel(ielem,2)
         x3  =  xel(ielem,3)
 !
         y2  =  yel(ielem,2)
         y3  =  yel(ielem,3)
 !
 !  INITIALISES THE INTERMEDIATE VARIABLES
 !
         s2d   = xmul*0.25d0/surfac(ielem)
         visc1 = u(         ielem)*s2d
         visc2 = u(  nelmax+ielem)*s2d
         visc3 = u(2*nelmax+ielem)*s2d
         bpe   = visc1*y3**2 + visc2*x3**2
         cpf   = visc1*y2*y3 + visc2*x2*x3
         apd   = visc1*y2**2 + visc2*x2**2
         x2mx3  = x2-x3
         y2my3  = y2-y3
 !
 !  EXTRADIAGONAL TERMS
 !
         a12(ielem)= cpf-bpe   - ( y2my3*x3 + x2mx3*y3 ) * visc3
         a13(ielem)= cpf-apd   + ( y2my3*x2 + x2mx3*y2 ) * visc3
         a23(ielem)= -cpf      + ( x2*y3    + x3*y2    ) * visc3
 !
 !  DIAGONAL TERMS
 !
         a11(ielem) = - a12(ielem) - a13(ielem)
         a22(ielem) = - a12(ielem) - a23(ielem)
         a33(ielem) = - a13(ielem) - a23(ielem)
 !
 !   END OF THE LOOP ON THE ELEMENTS
 !
       ENDDO ! IELEM
 !
 !-----------------------------------------------------------------------
 !
       ELSEIF(ielmnu.EQ.11.AND.iso.EQ.1) THEN
 !
 !-----------------------------------------------------------------------
 !
       IF(formul(7:8).EQ.'UV'.AND.
      &   ielmnu.EQ.11.AND.ielmnv.EQ.11) THEN
 !
 !-----------------------------------------------------------------------
 !
       DO ielem = 1 , nelem
 !
 !   INITIALISES THE GEOMETRICAL VARIABLES
 !
         x2  =  xel(ielem,2)
         x3  =  xel(ielem,3)
 !
         y2  =  yel(ielem,2)
         y3  =  yel(ielem,3)
 !
 !   INITIALISES THE INTERMEDIATE VARIABLES
 !
         i1=ikle1(ielem)
         i2=ikle2(ielem)
         i3=ikle3(ielem)
 !
         g1=v(i1)
         g2=v(i2)
         g3=v(i3)
 !
         coef1=xsur48/surfac(ielem)
         g123=g1+g2+g3
         coef2=u(i1)*(g1+g123)+u(i2)*(g2+g123)+u(i3)*(g3+g123)
 !
 !  EXTRADIAGONAL TERMS
 !
         a12(ielem)= (y3*(y2-y3)+x3*(x2-x3))*coef2*coef1
         a13(ielem)=-(y2*(y2-y3)+x2*(x2-x3))*coef2*coef1
         a23(ielem)=-(y2*    y3 +x2*    x3 )*coef2*coef1
 !
 !  DIAGONAL TERMS
 !
         a11(ielem) = - a12(ielem) - a13(ielem)
         a22(ielem) = - a12(ielem) - a23(ielem)
         a33(ielem) = - a13(ielem) - a23(ielem)
 !
       ENDDO
 !
 !   END OF THE LOOP ON THE ELEMENTS
 !
       ELSE
 !
 !  P1 DISCRETISATION FOR VISCOSITY:
 !
       DO ielem = 1 , nelem
 !
 !   INITIALISES THE GEOMETRICAL VARIABLES
 !
         x2  =  xel(ielem,2)
         x3  =  xel(ielem,3)
 !
         y2  =  yel(ielem,2)
         y3  =  yel(ielem,3)
 !
 !   INITIALISES THE INTERMEDIATE VARIABLES
 !
         somvx = ( u(ikle1(ielem))
      &           +u(ikle2(ielem))
      &           +u(ikle3(ielem)) ) * xsur12 / surfac(ielem)
         x2x3  = x2 * x3  + y2 * y3
         x2aux = x2*(-x2+x3)+y2*(-y2+y3)
         x3aux = x3*(-x2+x3)+y3*(-y2+y3)
 !
 !  EXTRADIAGONAL TERMS
 !
         a12(ielem) = - somvx * x3aux
         a13(ielem) =   somvx * x2aux
         a23(ielem) = - somvx * x2x3
 !
 !  DIAGONAL TERMS
 !
         a11(ielem) = - a12(ielem) - a13(ielem)
         a22(ielem) = - a12(ielem) - a23(ielem)
         a33(ielem) = - a13(ielem) - a23(ielem)
 !
       ENDDO ! IELEM
 !
       ENDIF
 !
 !-----------------------------------------------------------------------
 !
 !  LINEAR DISCRETISATION FOR NONISOTROPIC VISCOSITY
 !
       ELSEIF(ielmnu.EQ.11.AND.iso.EQ.3) THEN
 !
 !-----------------------------------------------------------------------
 !
 !  P1 DISCRETISATION FOR VISCOSITY:
 !
       iad2 = su%MAXDIM1
       iad3 = 2*iad2
 !
       DO ielem = 1 , nelem
 !
 !  INITIALISES THE GEOMETRICAL VARIABLES
 !
         x2  =  xel(ielem,2)
         x3  =  xel(ielem,3)
 !
         y2  =  yel(ielem,2)
         y3  =  yel(ielem,3)
 !
 !  INITIALISES THE INTERMEDIATE VARIABLES
 !
         somvx = u(ikle1(ielem)     )
      &        + u(ikle2(ielem)     )
      &        + u(ikle3(ielem)     )
         somvy = u(ikle1(ielem)+iad2)
      &        + u(ikle2(ielem)+iad2)
      &        + u(ikle3(ielem)+iad2)
         somvz = u(ikle1(ielem)+iad3)
      &        + u(ikle2(ielem)+iad3)
      &        + u(ikle3(ielem)+iad3)
 !
 !   INITIALISES THE INTERMEDIATE VARIABLES
 !
         aux = xsur12 / surfac(ielem)
         x2x3 = x2 * x3
         y2y3 = y2 * y3
         x2aux = x2*(-x2+x3)
         y2aux = y2*(-y2+y3)
         x3aux = x3*(-x2+x3)
         y3aux = y3*(-y2+y3)
         x2mx3 = x2-x3
         y2my3 = y2-y3
 !
 !  EXTRADIAGONAL TERMS
 !
         a12(ielem) = (   - somvx * y3aux
      &                   - somvy * x3aux
      &                   - y2my3*x3*somvz
      &                   - x2mx3*y3*somvz ) * aux
 !
         a13(ielem) = (     somvx * y2aux
      &                   + somvy * x2aux
      &                   + y2my3*x2*somvz
      &                   + x2mx3*y2*somvz ) * aux
 !
         a23(ielem) = (   - somvx * y2y3
      &                   - somvy * x2x3
      &                   + somvz*x3*y2+somvz*x2*y3 ) * aux
 !
 !  DIAGONAL TERMS
 !
         a11(ielem) = - a12(ielem) - a13(ielem)
         a22(ielem) = - a12(ielem) - a23(ielem)
         a33(ielem) = - a13(ielem) - a23(ielem)
 !
       ENDDO ! IELEM
 !
 !-----------------------------------------------------------------------
 !
       ELSE
 !
         WRITE(lu,11) ielmnu,iso
 11      FORMAT(1x,
      &  'MT02AA (BIEF) : TYPE OF VISCOSITY NOT AVAILABLE : ',2i6)
         CALL plante(1)
         stop
 !
       ENDIF
 !
 !-----------------------------------------------------------------------
 !
       IF(formul(14:16).EQ.'MON') THEN
         IF(xmul.GT.0.d0) THEN
           DO ielem=1,nelem
             a12(ielem)=min(a12(ielem),0.d0)
             a13(ielem)=min(a13(ielem),0.d0)
             a23(ielem)=min(a23(ielem),0.d0)
 !           DIAGONAL TERMS REDONE
             a11(ielem) = - a12(ielem) - a13(ielem)
             a22(ielem) = - a12(ielem) - a23(ielem)
             a33(ielem) = - a13(ielem) - a23(ielem)
           ENDDO
         ELSE
           DO ielem=1,nelem
             a12(ielem)=max(a12(ielem),0.d0)
             a13(ielem)=max(a13(ielem),0.d0)
             a23(ielem)=max(a23(ielem),0.d0)
 !           DIAGONAL TERMS REDONE
             a11(ielem) = - a12(ielem) - a13(ielem)
             a22(ielem) = - a12(ielem) - a23(ielem)
             a33(ielem) = - a13(ielem) - a23(ielem)
           ENDDO
         ENDIF
       ENDIF
 !
 !-----------------------------------------------------------------------
 !
       RETURN
       END
declarations_special
Definition: declarations_special.F:3

mt02aa
subroutine mt02aa(A11, A12, A13, A22, A23, A33, XMUL, SU, U, SV, V, XEL, YEL, SURFAC, IKLE1, IKLE2, IKLE3, NELEM, NELMAX, FORMUL)
Definition: mt02aa.f:11

declarations_special::lu
integer lu
Definition: declarations_special.F:45

bief
Definition: bief.f:3