mt01tt.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE mt01tt
!                   *****************
!
     &( t,xm,xmul,x,y,z,ikle,nelem,nelmax)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    BUILDS THE MASS MATRIX FOR TETRAHEDRONS.
!code
!+     STORAGE CONVENTION FOR EXTRA-DIAGONAL TERMS:
!+
!+     XM(IELEM, 1)  ---->  M(1,2) = M(2,1)
!+     XM(IELEM, 2)  ---->  M(1,3) = M(3,1)
!+     XM(IELEM, 3)  ---->  M(1,4) = M(4,1)
!+     XM(IELEM, 4)  ---->  M(2,3) = M(3,2)
!+     XM(IELEM, 5)  ---->  M(2,4) = M(4,2)
!+     XM(IELEM, 6)  ---->  M(3,4) = M(4,3)
!
!history  J-M HERVOUET (LNH)
!+        04/01/02
!+        V5P3
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE           |-->| CONNECTIVITY TABLE.
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SURFAC         |-->| AREA OF TRIANGLES
!| T              |<--| NON ASSEMBLED DIAGONAL
!| XM             |<--| NON ASSEMBLED OFF-DIAGONAL TERMS
!| XMUL           |-->| MULTIPLICATION FACTOR
!| X              |-->| ABSCISSAE OF POINTS IN THE MESH
!| Y              |-->| ORDINATES OF POINTS IN THE MESH
!| Z              |-->| ELEVATIONS OF POINTS IN THE MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_mt01tt => mt01tt
!
      USE declarations_special
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NELEM,NELMAX
      INTEGER, INTENT(IN)             :: IKLE(nelmax,4)
      DOUBLE PRECISION, INTENT(INOUT) :: T(nelmax,4),XM(nelmax,6)
      DOUBLE PRECISION, INTENT(IN)    :: XMUL
      DOUBLE PRECISION, INTENT(IN)    :: X(*),Y(*),Z(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     SPECIFIC DECLARATIONS
!
      DOUBLE PRECISION X2,Y2,Z2,X3,Y3,Z3,X4,Y4,Z4,VOLSUR20
      INTEGER I1,I2,I3,I4,IELEM
!
      DOUBLE PRECISION XSUR120
!
!***********************************************************************
!
      xsur120=xmul/120.d0
!
!-----------------------------------------------------------------------
!
!     LOOP ON THE TETRAHEDRONS
!
      DO ielem=1,nelem
!
      i1=ikle(ielem,1)
      i2=ikle(ielem,2)
      i3=ikle(ielem,3)
      i4=ikle(ielem,4)
!
!-----------------------------------------------------------------------
!
      x2=x(i2)-x(i1)
      y2=y(i2)-y(i1)
      z2=z(i2)-z(i1)
      x3=x(i3)-x(i1)
      y3=y(i3)-y(i1)
      z3=z(i3)-z(i1)
      x4=x(i4)-x(i1)
      y4=y(i4)-y(i1)
      z4=z(i4)-z(i1)
!
!     EXTRA-DIAGONAL TERMS
!
!     VOLUME OF THE TETRAHEDRON:
!
!     (Z2*(X3*Y4-X4*Y3)+Y2*(X4*Z3-X3*Z4)+X2*(Y3*Z4-Y4*Z3))/6
!
!     XM(IELEM,1) = VOLUME / 20
!
!     SUMS UP THE TERMS (INC. SYMMETRIC ONES) TO YIELD VOLUME OF THE TETRAHEDRON
!
      volsur20 =
     &(z2*(x3*y4-x4*y3)+y2*(x4*z3-x3*z4)+x2*(y3*z4-y4*z3))*xsur120
      xm(ielem,1) = max(volsur20,1.d-4)
      xm(ielem,2) = xm(ielem,1)
      xm(ielem,3) = xm(ielem,1)
      xm(ielem,4) = xm(ielem,1)
      xm(ielem,5) = xm(ielem,1)
      xm(ielem,6) = xm(ielem,1)
!
!     DIAGONAL TERMS
!
      t(ielem,1) = 2 * xm(ielem,1)
      t(ielem,2) = t(ielem,1)
      t(ielem,3) = t(ielem,1)
      t(ielem,4) = t(ielem,1)
!
!-----------------------------------------------------------------------
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
      RETURN
      END