mod_compute_boundary_and_interface.f

Go to the documentation of this file.

!     *****************************************
      MODULE mod_compute_boundary_and_interface
!     *****************************************
!
!***********************************************************************
! PARTEL
!***********************************************************************
!
!BRIEF    Computing boundary and interface for partel
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        IMPLICIT NONE
        CONTAINS
!     *****************************************
      SUBROUTINE compute_boundary_and_interface
!     *****************************************
     &        (nparts, ndp_2d, npoin_p,
     &         nptfr_p, elelg, nelem_p, ikles, knogl,
     &         cut_p, ef_i, ef_ii, nptir_p, nbre_ef_i, knolg, irand,
     &         part_p, nbre_ef)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NPARTS         |<--| Number of partitions
!| NDP_2D         |<--| Number of points per element
!| NPOIN_P        |<->| Number of point in partition
!| NPTFR_P        |<->| Number of boundary points in partition
!| ELELG          |<--| Local to global numbering for elements
!| NELEM_P        |<--| Number of elements in partition
!| IKLES          |<->| Connectivity array
!| KNOGL          |<--| Global to local numbering array
!| CUT_P          |<->| Global to local numbering for interface points
!| EF_I           |<->| EF_I(E) is the global label of the interface
!|                |   | finite element number e
!| EF_II          |<->| EF_II(E) is the local label of the interface
!|                |   | finite element number e
!| NPTIR_P        |<->| Number of interface points in the partition
!| NBRE_EF_I      |<->| Number of interface element on the subdomain
!| KNOLG          |<->| Local to global numbering array
!| IRAND          |<--| Ipobo array for the partition
!| PART_P         |<->| List of subdomain each node belongs to
!| NBRE_EF        |<->| Number of finite element containing I
!|                |   | I is a global label
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
        USE declarations_special
        USE bief, ONLY : nbmaxnshare
        USE mod_hash_table
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
        INTEGER, ALLOCATABLE, INTENT(INOUT) :: NPOIN_P(:),NPTFR_P(:),
     &    ikles(:), part_p(:,:), ef_i(:,:), ef_ii(:,:),
     &    nptir_p(:), nbre_ef_i(:), knolg(:,:), nbre_ef(:)
!
        TYPE(hash_table), INTENT(INOUT) :: CUT_P
!
        INTEGER, ALLOCATABLE, INTENT(IN) :: ELELG(:,:), NELEM_P(:)
        INTEGER, ALLOCATABLE, INTENT(IN) :: IRAND(:)
        INTEGER, INTENT(IN) :: NPARTS, NDP_2D
        TYPE(hash_table), INTENT(IN) :: KNOGL
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!
        INTEGER :: I, J, K, POSI, TEMP, EF, NOEUD
        INTEGER :: MAX_NPOIN_P, IERR
        LOGICAL :: INTERFCE
        INTEGER, ALLOCATABLE :: NBRE_EF_LOC(:)

        max_npoin_p=maxval(npoin_p)
!
!     NBRE_EF_LOC(I) : NUMBER OF FINITE ELEMENTS CONTAINING THE POINT I
!                      ON SUBMESH I
!     I IS THE LOCAL LABEL ON SUBMESH I
        ALLOCATE (nbre_ef_loc(max_npoin_p),stat=ierr)
        CALL check_allocate(ierr, 'NBRE_EF_LOC')

        DO i=1,nparts
          DO j=1,npoin_p(i)
            nbre_ef_loc(j)=0
          ENDDO
!
          npoin_p(i)=0
          nptfr_p(i)=0
!
          DO j=1,nelem_p(i)
            ef=elelg(j,i)
            DO k=1,ndp_2d
              noeud=ikles((ef-1)*3+k)
              temp=hash_table_get(knogl, noeud, i)
              nbre_ef_loc(temp)=nbre_ef_loc(temp)+1
              IF(nbre_ef_loc(temp) .EQ. 1) THEN
!               THE POINT NOEUD IS ENCOUNTERED FOR THE FIRST TIME
                npoin_p(i)=npoin_p(i)+1
!               IS NOEUD A BOUNDARY POINT ?
                IF(irand(noeud) .NE. 0) THEN
                  nptfr_p(i)= nptfr_p(i)+1
                ENDIF
!               MODIFICATION OF KNOGL
                knolg(npoin_p(i),i)=noeud
              ENDIF
            ENDDO
          ENDDO
!
          nptir_p(i)=0
!
!         NOMBRE DE NOEUD INTERFACE DU SDI
!
          nbre_ef_i(i)=0            ! NOMBRE D'ELEMENTS FINIS INTERFACES DU SDI
          DO j=1,nelem_p(i)      ! ON PARCOURS A NOUVEAU LES ELEMENTS FINIS DU SDI
            interfce=.false.
            ef=elelg(j,i)
            DO k=1,ndp_2d
              noeud=ikles((ef-1)*3+k)
              temp=hash_table_get(knogl, noeud, i)
              IF(abs(nbre_ef_loc(temp)).NE.nbre_ef(noeud)) THEN
                interfce=.true.
              ENDIF
              IF(nbre_ef_loc(temp).NE. nbre_ef(noeud).AND.
     &           nbre_ef_loc(temp).GT.0) THEN
!               NOEUD EST INTERFACE CAR IL RESTE DES ELEMENTS FINIS
!               HORS DE SDI QUI LE CONTIENT
                interfce=.true.
                nptir_p(i)=nptir_p(i)+1
                CALL hash_table_insert(cut_p, nptir_p(i), i, noeud)
                part_p(noeud,0)=part_p(noeud,0)+1
                posi=part_p(noeud,0)
                IF(posi.GT.nbmaxnshare-1) THEN
                  WRITE(lu,*)  'ERROR : AN INTERFACE NODE BELONGS TO
     &                  MORE THAN NBMAXNSHARE-1 SUBDOMAINS'
                  CALL plante(1)
                  stop
                ENDIF
                part_p(noeud,posi)=i
                nbre_ef_loc(temp)=-nbre_ef_loc(temp)
              ENDIF
            ENDDO
            IF(interfce) THEN
              nbre_ef_i(i)=nbre_ef_i(i)+1 ! L'ELEMENT FINI EST DONC AUSSI INTERFACE
              ef_i(i, nbre_ef_i(i))=ef
              ef_ii(i, nbre_ef_i(i))=j
            ENDIF
          ENDDO
        ENDDO
      END SUBROUTINE
      END MODULE mod_compute_boundary_and_interface