meteo_telemac.f

Go to the documentation of this file.

!                       ********************
                        MODULE meteo_telemac
!                       ********************
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Module containing all subroutines to deal with atmospheric
!+        exchange, whether its dynamics (wind, pressure, etc.) or its
!+        thermal budget (air temperature, solar radiation, cloud, etc.)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_special
      IMPLICIT NONE
!
      PRIVATE
      PUBLIC :: point_meteo,sync_meteo,dealloc_meteo,
     &   meteo_offset,meteo_ref_date, 
     &   windx,windy,windz,winds,windd,modelz, alphsd,alphrd,
     &   tair,tdew,cldc,visbi,rainfall,patmos,pvap,ray3,hrel,
     &   cst_windx,cst_windy,cst_winds,cst_windd,cst_patmos,
     &   cst_tair,cst_tdew,cst_cldc,cst_visbi,cst_rainfall,cst_hrel,
     &   cst_ray3,cst_pvap
!
!=======================================================================
!
!       1) METEOROLOGICAL DRIVERS
!
!     NOTE: A METEOROLOGICAL VARIBALE (SAY TAIR) IS ASSOCIATED WITH
!     A DOUBLE PRECISION CONSTANT (CST_TAIR, TAKEN FROM THE STEERING
!     FILE, OR THE DICO DEFAULT) AND A LOGICAL, INC_TAIR, WHETHER THE
!     VARIABLE WAS FOUND IN ANY OF THE METEO FILES (ASCII OR BINARY)
!
!-----------------------------------------------------------------------

!     TAIR: AIR TEMPERATURE
!     > Measured in degrees oC
!
      TYPE(bief_obj), TARGET :: tair
      DOUBLE PRECISION       :: cst_tair
      LOGICAL                :: inc_tair
!
!     TDEW: DEWPOINT TEMPERATURE
!     > Measured in degrees oC
!
!     The dewpoint temperature is the temperature at which the air can
!     no longer "hold" all of the water vapor which is mixed with it,
!     and some of the water vapor must condense into liquid water.
!     The dew point is always lower than (or equal to) the air
!     temperature.
!     If the air temperature cools to the dew point, or if the dew point
!     rises to equal the air temperature, then dew, fog or clouds begin
!     to form. At this point where the dew point temperature equals the
!     air temperature, the relative humidity is 100%.
!
      TYPE(bief_obj), TARGET :: tdew
      DOUBLE PRECISION       :: cst_tdew
      LOGICAL                :: inc_tdew
!
!     CLDC: CLOUD COVER
!     > Measured in tenth
!
!     Clouds produce significant changes in the evolution of the other
!     meteorological components (the duration of the sun shine, solar
!     radiation, temperature, air humidity, atmospheric precipitation,
!     water  drops  or  ice  crystals  etc.), through  their  size  and
!     form, life duration and their constitution.
!     Cloud cover estimated percentages:
!     -      0%: No clouds
!     -   1-10%: Clear
!     -  11-25%: Isolated
!     -  26-50%: Scattered
!     -  51-90%: Broken
!     -   0>90%: Overcast
!     Cloud cover can also be referred to as nebulosity, or the
!     ambiguous nature of clouds, or cloud-like-ness, and therefore is
!     directly related to the humidity. The more significant the
!     extension and the vertical thickness of the clouds, the higher
!     the value of the nebulosity will be.
!
      TYPE(bief_obj), TARGET :: cldc
      DOUBLE PRECISION       :: cst_cldc
      LOGICAL                :: inc_cldc
!
!     VISBI: VISIBILITY
!     > Measured in meters
!
!     Visibility is a measure of the distance at which an object or
!     light can be clearly discerned. Note that in the dark,
!     meteorological visibility is still the same as in daylight for
!     the same air.
!
      TYPE(bief_obj), TARGET :: visbi
      DOUBLE PRECISION       :: cst_visbi
      LOGICAL                :: inc_visbi
!
!     RAINFALL: RAIN
!     > Measured in meters
      TYPE(bief_obj), TARGET :: rainfall
      DOUBLE PRECISION       :: cst_rainfall
      LOGICAL                :: inc_rainfall
!
!     SNOW: SNOW
!     > Measured in meters
      TYPE(bief_obj), TARGET :: snow
      DOUBLE PRECISION       :: cst_snow
      LOGICAL                :: inc_snow
!
!     ALPHSD: SUN SET ANGLE
!     > Measured in degrees, 180 degrees for the horizontal
      DOUBLE PRECISION    alphsd
!
!     ALPHRD: SUN RISE ANGLE
!     > Measured in degrees, 0 degrees for the horizontal
      DOUBLE PRECISION    alphrd
!
!
!     WINDX,WINDY : WIND
!     > Measured in m/s at WINDZ above the water surface
! or  WINDS,WINDD : WIND
!     > Measured in m/s and degree angle clockwise from north
!
      TYPE(bief_obj), TARGET :: windx,windy
      DOUBLE PRECISION       :: cst_windx,cst_windy
      LOGICAL                :: inc_windx,inc_windy
      TYPE(bief_obj), TARGET :: winds,windd
      DOUBLE PRECISION       :: cst_winds,cst_windd
      LOGICAL                :: inc_winds,inc_windd
!
!     WINDZ
!     > Heigh above the water surface at which the wind is measured
      DOUBLE PRECISION       :: windz
!
!
      TYPE(bief_obj), TARGET :: patmos
      DOUBLE PRECISION       :: cst_patmos
      LOGICAL                :: inc_patmos
!
!     PVAP: SATURATED VAPOR PRESSURE
!     > Measured in hPa
      TYPE(bief_obj), TARGET :: pvap
      DOUBLE PRECISION       :: cst_pvap
      LOGICAL                :: inc_pvap
!
!     RAY3: SOLAR RADIATION
!     > Measured in W/m^2
      TYPE(bief_obj), TARGET :: ray3
      DOUBLE PRECISION       :: cst_ray3
      LOGICAL                :: inc_ray3
!
!     MODELZ
!     > Elevation of the model domain relative to mean sea levels
      DOUBLE PRECISION       :: modelz
!
!     HREL: RELAVITE HUMIDITY
!     > Measured in %
      TYPE(bief_obj), TARGET :: hrel
      DOUBLE PRECISION       :: cst_hrel
      LOGICAL                :: inc_hrel
!
!
!=======================================================================
!
!       2) METEOROLOGICAL CONSTANTS
!
!-----------------------------------------------------------------------
!
!
!
!=======================================================================
!
!       3) METEOROLOGICAL FILE INPUTS
!
!-----------------------------------------------------------------------
!
!     ONLY TWO METEOROLOGY FILES FOR NOW - A:ASCII AND B:BINARY
!     TO RECORD TEMPORAL AND SPATIAL VARIATIONS
!
!     TYPE BIEF_FILE
!       INTEGER LU               : LOGICAL UNIT TO OPEN THE FILE
!       CHARACTER(LEN=PATH_LEN) NAME  : NAME OF FILE
!       CHARACTER(LEN=6) TELNAME : NAME OF FILE IN TEMPORARY DIRECTORY
!       CHARACTER(LEN=8) FMT     : FORMAT (SERAFIN, MED, ETC.)
!       CHARACTER(LEN=9) ACTION  : READ, WRITE OR READWRITE
!       CHARACTER(LEN=3) BINASC  : ASC FOR ASCII OR BIN FOR BINARY
!       CHARACTER(LEN=12) TYPE   : KIND OF FILE
!     TYPE BIEF_FILE
!
      TYPE(bief_file)  :: meteo_files(2)
!
!     READING THE FILES IN FULL ONLY ONCE
      LOGICAL          :: meteo_deja(2)
!
!-----------------------------------------------------------------------
!
!     COMMON TO BOTH ASCII AND BINARY FILES
!
!     MAXIMUM NUMBER OF VALUE ON EACH LINE (VARIABLES FOR EACH POINT)
      INTEGER, PARAMETER :: meteo_maxvalue = 210
      CHARACTER(LEN=16), TARGET  :: meteo_choix(2,meteo_maxvalue)
      CHARACTER(LEN=16), TARGET  :: meteo_units(2,meteo_maxvalue)
!
!-----------------------------------------------------------------------
!
!     SPECIFICS FOR THE ASCII FILE
!
!     INTERPOLATION IN TIME AND IN SPACE FOR MULTIPLE VALUES
      INTEGER          :: ntimea,nvaluea,npoina
      INTEGER          :: itimea1,itimea2
      DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE ::
     &                    timea, xpoina,ypoina
      DOUBLE PRECISION, DIMENSION(:,:), ALLOCATABLE ::
     &                    valuea1,valuea2
      DOUBLE PRECISION dummy
!
!     MAXIMUM NUMBER OF CHARACTERS PER LIGNE (MAY BE CHANGED)
      INTEGER, PARAMETER :: sizelign = 30000
!
!-----------------------------------------------------------------------
!
!     SPECIFICS FOR THE BINARY FILE
!
!     INTERPOLATION IN TIME AND IN SPACE FOR MULTIPLE VALUES
      INTEGER          :: ntimeb,nvalueb,npoinb
      INTEGER          :: itimeb1,itimeb2
      DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE ::
     &                    timeb, xpoinb,ypoinb, valueb0
      DOUBLE PRECISION, DIMENSION(:,:), ALLOCATABLE ::
     &                    valueb1,valueb2
!
!
!=======================================================================
!
!       4) WORTH SAVING
!
      INTEGER, DIMENSION(6) :: meteo_ref_date
      DOUBLE PRECISION meteo_offset,tel_offset2
!
!
!-----------------------------------------------------------------------
      SAVE
!
!=======================================================================
!
!       5) METEOROLOGICAL SUBROUTINES
!
      CONTAINS
!
!=======================================================================
!
!                   **********************
                    SUBROUTINE point_meteo
!                   **********************
!
     &( files,atmfilea,atmfileb,mesh,ielmt,avent,aatmos,awater_quality,
     &  aice)
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Memory allocation of structures, aliases, blocks...
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ATMFILEA   |-->| LOGICAL UNIT OF THE ASCII ATMOSPHERIC FILE
!| ATMFILEB   |-->| LOGICAL UNIT OF THE BINARY ATMOSPHERIC FILE
!| ATMOS      |-->| YES IF ATMOSPHERIC PRESSURE TAKEN INTO ACCOUNT
!| FILES      |-->| BIEF_FILES STRUCTURES OF ALL FILES
!| ICE        |-->| YES IF ICE IS TAKEN INTO ACCOUNT
!| IELMT      |-->| NUMBER OF ELEMENTS
!| MESH       |-->| MESH STRUCTURE
!| VENT       |-->| YES IF WIND TAKEN INTO ACCOUNT
!| WATER_QUALITY |-->| YES IF COUPLED WITH WATER QUALITY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      TYPE(bief_file), INTENT(IN) :: FILES(*)
      INTEGER,         INTENT(IN) :: ATMFILEA,ATMFILEB
      INTEGER,         INTENT(IN) :: IELMT
      TYPE(bief_mesh), INTENT(IN) :: MESH
      LOGICAL, INTENT(IN), OPTIONAL :: AVENT,AATMOS,AWATER_QUALITY,AICE
!
      LOGICAL VENT,ATMOS,WATER_QUALITY,ICE
!
      INTEGER I,J
!
      CHARACTER(LEN=16), ALLOCATABLE  :: CHOIX(:)
!
!-----------------------------------------------------------------------
!
!     DEFAULT VALUES OF PARAMETERS WHEN THEY ARE NOT GIVEN
!
      water_quality=.false.
      IF(PRESENT(awater_quality)) water_quality=awater_quality
      vent=.false.
      IF(PRESENT(avent)) vent=avent
      atmos=.false.
      IF(PRESENT(aatmos)) atmos=aatmos
      ice=.false.
      IF(PRESENT(aice)) ice=aice
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     GATHER THE SKELETON OF THE METEO THERMIC FILES
!
!     A: ASCII FILE
      meteo_deja(1) = .false.
      npoina = 0
      IF( files(atmfilea)%NAME(1:1).NE.' ' ) THEN
        CALL init_fic_ascii( files,atmfilea )
        meteo_deja(1) = .true.
      ENDIF
!
!     B: BINARY FILE
      meteo_deja(2) = .false.
      npoinb = 0
      IF( files(atmfileb)%NAME(1:1).NE.' ' ) THEN
        CALL init_fic_binary( files,atmfileb )
        meteo_deja(2) = .true.
      ENDIF
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     ALLOCATE MEMORY
!
!     WORKING ARRAY
!
      IF(ice) THEN
        CALL bief_allvec(1,tdew  ,'TDEW  ',ielmt,1,1,mesh)
        CALL bief_allvec(1,visbi ,'VISBI ',ielmt,1,1,mesh)
        CALL bief_allvec(1,snow  ,'SNOW  ',ielmt,1,1,mesh)
      ELSE
        CALL bief_allvec(1,tdew  ,'TDEW  ',    0,1,0,mesh)
        CALL bief_allvec(1,visbi ,'VISBI ',    0,1,0,mesh)
        CALL bief_allvec(1,snow  ,'SNOW  ',    0,1,0,mesh)
      ENDIF
!
!     METEOROLOGY
!
      IF(water_quality.OR.ice) THEN
        CALL bief_allvec(1,tair  ,'TAIR  ',ielmt,1,1,mesh)
        CALL bief_allvec(1,rainfall ,'RAINFA',ielmt,1,1,mesh)
        CALL bief_allvec(1,ray3  ,'RAY3  ',ielmt,1,1,mesh)
        CALL bief_allvec(1,cldc  ,'CLDC  ',ielmt,1,1,mesh)
        CALL bief_allvec(1,pvap  ,'PVAP  ',ielmt,1,1,mesh)
        CALL bief_allvec(1,hrel  ,'HREL  ',ielmt,1,1,mesh)
      ELSE
        CALL bief_allvec(1,tair  ,'TAIR  ',    0,1,0,mesh)
        CALL bief_allvec(1,rainfall ,'RAINFA',    0,1,0,mesh)
        CALL bief_allvec(1,ray3  ,'RAY3  ',    0,1,0,mesh)
        CALL bief_allvec(1,cldc  ,'CLDC  ',    0,1,0,mesh)
        CALL bief_allvec(1,pvap  ,'PVAP  ',    0,1,0,mesh)
        CALL bief_allvec(1,hrel  ,'HREL  ',    0,1,0,mesh)
      ENDIF
      CALL os('X=C     ', x=tair, c=cst_tair )
      inc_tair = .false.
      CALL os('X=C     ', x=rainfall, c=cst_rainfall )
      inc_rainfall = .false.
      CALL os('X=C     ', x=ray3, c=cst_ray3 )
      inc_ray3 = .false.
      CALL os('X=C     ', x=cldc, c=cst_cldc )
      inc_cldc = .false.
      CALL os('X=C     ', x=pvap, c=cst_pvap )
      inc_pvap = .false.
      CALL os('X=C     ', x=hrel, c=cst_hrel )
      inc_hrel = .false.
!
      CALL os('X=C     ', x=tdew, c=cst_tdew )
      inc_tdew = .false.
!
      IF(vent.OR.water_quality.OR.ice) THEN
        CALL bief_allvec(1,windx,'WINDX ',ielmt,1,1,mesh)
        CALL bief_allvec(1,windy,'WINDY ',ielmt,1,1,mesh)
        CALL bief_allvec(1,winds,'WINDS ',ielmt,1,1,mesh)
        CALL bief_allvec(1,windd,'WINDD ',ielmt,1,1,mesh)
      ELSE
        CALL bief_allvec(1,windx,'WINDX ',    0,1,0,mesh)
        CALL bief_allvec(1,windy,'WINDY ',    0,1,0,mesh)
        CALL bief_allvec(1,winds,'WINDS ',    0,1,0,mesh)
        CALL bief_allvec(1,windd,'WINDD ',    0,1,0,mesh)
      ENDIF
      CALL os('X=C     ', x=windx, c=cst_windx )
      CALL os('X=C     ', x=windy, c=cst_windy )
      inc_windx = .false.
      inc_windy = .false.
!     ONLY WINDS AND WINDD ARE CONVERTED INOT WINDX AND WINDY
      CALL os('X=C     ', x=winds, c=cst_winds )
      CALL os('X=C     ', x=windd, c=cst_windd )
      inc_winds = .false.
      inc_windd = .false.
!
      CALL os('X=C     ', x=visbi, c=cst_visbi )
      inc_visbi = .false.
!
      CALL os('X=C     ', x=snow, c=cst_snow )
      inc_snow = .false.
!
      IF(atmos.OR.water_quality.OR.ice) THEN
        CALL bief_allvec(1,patmos,'PATMOS',ielmt,1,1,mesh)
      ELSE
        CALL bief_allvec(1,patmos,'PATMOS',    0,1,0,mesh)
      ENDIF
      CALL os('X=C     ', x=patmos, c=cst_patmos )
      inc_patmos = .false.
!
!     1: ASCII FILE
!     2: BINARY FILE
!
      ALLOCATE(choix(meteo_maxvalue))
      DO i = 1,2
        IF( meteo_deja(i) ) THEN
          choix(1:meteo_maxvalue) = meteo_choix(i,1:meteo_maxvalue)
!
          j = find_name( 'TAIR', choix, meteo_maxvalue )
          inc_tair = inc_tair .OR. ( j.NE.0 )
!
          j = find_name( 'TDEW', choix, meteo_maxvalue )
          inc_tdew = inc_tdew .OR. ( j.NE.0 )
!
          j = find_name( 'WINDX', choix, meteo_maxvalue )
          inc_windx = inc_windx .OR. ( j.NE.0 )
          j = find_name( 'WINDY', choix, meteo_maxvalue )
          inc_windy = inc_windy .AND. ( j.NE.0 )
          j = find_name( 'WINDS', choix, meteo_maxvalue )
          inc_winds = inc_winds .OR. ( j.NE.0 )
          j = find_name( 'WINDD', choix, meteo_maxvalue )
          inc_windd = inc_windd .OR. ( j.NE.0 )
!
          j = find_name( 'CLDC', choix, meteo_maxvalue )
          inc_cldc = inc_cldc .OR. ( j.NE.0 )
!
          j = find_name( 'VISBI', choix, meteo_maxvalue )
          inc_visbi = inc_visbi .OR. ( j.NE.0 )
!
          j = find_name( 'RAINI', choix, meteo_maxvalue )
     &      + find_name( 'RAINC', choix, meteo_maxvalue )
          inc_rainfall = inc_rainfall .OR. ( j.NE.0 )
!
          j = find_name( 'SNOW', choix, meteo_maxvalue )
          inc_snow = inc_snow .OR. ( j.NE.0 )
!
          j = find_name( 'PATM', choix, meteo_maxvalue )
          inc_patmos = inc_patmos .OR. ( j.NE.0 )
!
          j = find_name( 'PVAP', choix, meteo_maxvalue )
          inc_pvap = inc_pvap .OR. ( j.NE.0 )
!
          j = find_name( 'HREL', choix, meteo_maxvalue )
          inc_hrel = inc_hrel .OR. ( j.NE.0 )
!
          j = find_name( 'RAY3', choix, meteo_maxvalue )
          inc_ray3 = inc_ray3 .OR. ( j.NE.0 )
!
        ENDIF
      ENDDO
      DEALLOCATE(choix)

!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!                   ************************
                    SUBROUTINE dealloc_meteo
!                   ************************
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Memory de-allocation of structures, aliases, blocks...
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     DE-ALLOCATE FILE RELATED VARIABLES (SEE INIT_FIC_*)
!
!     A: ASCII FILE
      IF( ALLOCATED(timea) )   DEALLOCATE(timea)
      IF( ALLOCATED(xpoina) )  DEALLOCATE(xpoina)
      IF( ALLOCATED(ypoina) )  DEALLOCATE(ypoina)
      IF( ALLOCATED(valuea1) ) DEALLOCATE(valuea1)
      IF( ALLOCATED(valuea2) ) DEALLOCATE(valuea2)
!
!     B: BINARY FILE
      IF( ALLOCATED(timeb) )   DEALLOCATE(timeb)
      IF( ALLOCATED(xpoinb) )  DEALLOCATE(xpoinb)
      IF( ALLOCATED(ypoinb) )  DEALLOCATE(ypoinb)
      IF( ALLOCATED(valueb0) ) DEALLOCATE(valueb0)
      IF( ALLOCATED(valueb1) ) DEALLOCATE(valueb1)
      IF( ALLOCATED(valueb2) ) DEALLOCATE(valueb2)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     DE-ALLOCATE METEOROLOGICAL OBJECTS (SEE POINT_METEO)
!
      CALL bief_deallobj(tair)
      CALL bief_deallobj(tdew)
      CALL bief_deallobj(windx)
      CALL bief_deallobj(windy)
      CALL bief_deallobj(winds)
      CALL bief_deallobj(windd)
      CALL bief_deallobj(cldc)
      CALL bief_deallobj(visbi)
      CALL bief_deallobj(rainfall)
      CALL bief_deallobj(snow)
      CALL bief_deallobj(pvap)
      CALL bief_deallobj(ray3)
      CALL bief_deallobj(patmos)
      CALL bief_deallobj(hrel)
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!                   *********************
                    SUBROUTINE sync_meteo
!                   *********************
!
     &( when )
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Synchronise the ASCII and the BINARY file for spatial and
!         temporal interpolation
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| WHEN           |-->| CURRENT TIME
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      DOUBLE PRECISION, INTENT(IN) :: WHEN
!
      INTEGER          :: IPOIN
      DOUBLE PRECISION :: DTR
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     SYNCHRONISE BOTH THE ASCII AND THE BINARY FILES
!
!     A: ASCII FILE
      IF( meteo_deja(1) ) CALL sync_fic_ascii( when )
!
!     B: BINARY FILE
      IF( meteo_deja(2) ) CALL sync_fic_binary( when )
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      dtr = atan(1.d0) / 45.d0
!
!     UPDATE METEOROLOGICAL VARIABLES
!
!     TAIR: AIR TEMPERATURE
      CALL os('X=C     ', x=tair, c=cst_tair )
      IF( inc_tair ) THEN
        CALL interp_meteo(when,'TAIR',tair%R,tair%DIM1)
      ENDIF
!
!     TDEW: DEWPOINT TEMPERATURE
      CALL os('X=C     ', x=tdew, c=cst_tdew )
      IF( inc_tdew ) THEN
        CALL interp_meteo(when,'TDEW',tdew%R,tdew%DIM1)
      ENDIF
!
!     CLDC: CLOUD COVER
      CALL os('X=C     ', x=cldc, c=cst_cldc )
      IF( inc_cldc ) THEN
        CALL interp_meteo(when,'CLDC',cldc%R,cldc%DIM1)
      ENDIF
!
!     VISBI: VISIBILITY
      CALL os('X=C     ', x=visbi, c=cst_visbi )
      IF( inc_visbi ) THEN
        CALL interp_meteo(when,'VISBI',visbi%R,visbi%DIM1)
      ENDIF
!
!     RAINFALL: RAIN
      CALL os('X=C     ', x=rainfall, c=cst_rainfall )
      IF( inc_rainfall ) THEN
        CALL interp_meteo(when,'RAINI',rainfall%R,rainfall%DIM1)
        CALL interp_meteo(when,'RAINC',rainfall%R,rainfall%DIM1)
      ENDIF
!
!     SNOW: SNOW
      CALL os('X=C     ', x=snow, c=cst_snow )
      IF( inc_snow ) THEN
        CALL interp_meteo(when,'SNOW',snow%R,snow%DIM1)
      ENDIF
!
!     WINDX,WINDY, OR WINDS,WINDD : WIND
      CALL os('X=C     ', x=windx, c=cst_windx )
      IF( inc_windx ) THEN
        CALL interp_meteo(when,'WINDX',windx%R,windx%DIM1)
      ENDIF
      CALL os('X=C     ', x=windy, c=cst_windy )
      IF( inc_windy ) THEN
        CALL interp_meteo(when,'WINDY',windy%R,windy%DIM1)
      ENDIF
      CALL os('X=C     ', x=winds, c=cst_winds )
      IF( inc_winds ) THEN
        CALL interp_meteo(when,'WINDS',winds%R,winds%DIM1)
      ENDIF
      CALL os('X=C     ', x=windd, c=cst_windd )
      IF( inc_windd ) THEN
        CALL interp_meteo(when,'WINDD',windd%R,windd%DIM1)
      ENDIF
      IF( ( inc_winds.AND.inc_windd ).AND.
     &    .NOT.( inc_windx.AND.inc_windy ) ) THEN
        CALL interp_windxy(when,windx%R,windy%R,windd%DIM1)
        DO ipoin = 1,winds%DIM1
          winds%R(ipoin) = sqrt(windy%R(ipoin)**2+windy%R(ipoin)**2)
        ENDDO
      ELSEIF( ( inc_winds.OR.inc_windd ).AND.
     &    .NOT.( inc_windx.AND.inc_windy ) ) THEN
        DO ipoin = 1,windx%DIM1
          windx%R(ipoin) = - winds%R(ipoin)*sin( windd%R(ipoin)*dtr )
          windy%R(ipoin) = - winds%R(ipoin)*cos( windd%R(ipoin)*dtr )
        ENDDO
      ENDIF
!
!     ATMOSPHERIC PRESSURE
      CALL os('X=C     ', x=patmos, c=cst_patmos )
      IF( inc_patmos ) THEN
        CALL interp_meteo(when,'PATM',patmos%R,patmos%DIM1)
      ENDIF
!
!     PVAP: PVAP
      CALL os('X=C     ', x=pvap, c=cst_pvap )
      IF( inc_pvap ) THEN
        CALL interp_meteo(when,'PVAP',pvap%R,pvap%DIM1)
      ENDIF
!
!     HREL: HREL
      CALL os('X=C     ', x=hrel, c=cst_hrel )
      IF( inc_hrel ) THEN
        CALL interp_meteo(when,'HREL',hrel%R,hrel%DIM1)
      ENDIF
!
!     RAY3: RAY3
      CALL os('X=C     ', x=ray3, c=cst_ray3 )
      IF( inc_ray3 ) THEN
        CALL interp_meteo(when,'RAY3',ray3%R,ray3%DIM1)
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!                     ***********************
                      SUBROUTINE interp_meteo
!                     ***********************
!
     &( when,what,valeurs,npoin )
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Spatial and temporal interpolation of variables from either
!+        the ASCII or the BINARY file
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NPOIN          |-->| NUMBER OF NODES
!| VALEURS        |<->| VALUES CONTAINED IN THE VARIABLE
!| WHAT           |-->| VARIABLE TO CONSIDER
!| WHEN           |-->| CURRENT TIME
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      INTEGER,             INTENT(IN) :: NPOIN
      CHARACTER(LEN=*),    INTENT(IN) :: WHAT
      DOUBLE PRECISION,    INTENT(IN) :: WHEN
      DOUBLE PRECISION, INTENT(INOUT) :: VALEURS(npoin)
!
      INTEGER           J,IPOIN
      DOUBLE PRECISION  ALPHA,DELTA
      DOUBLE PRECISION  X1,Y1,Z1,X2,Y2,Z2,X3,Y3,Z3,NX,NY,NZ,MX,MY
      CHARACTER(LEN=16), ALLOCATABLE  :: CHOIX(:)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     A: ASCII FILE
      ALLOCATE(choix(meteo_maxvalue))
      IF( meteo_deja(1) ) THEN
        choix(1:meteo_maxvalue) = meteo_choix(1,1:meteo_maxvalue)
        j = find_name( what, choix, meteo_maxvalue )
        IF( j.NE.0 .AND. what.NE.'RAINC') THEN
!         ______________________________________________________________
!         TEMPORAL INTERPOLATION
          delta = ( timea(itimea2)-timea(itimea1) )
          alpha = ( when+tel_offset2-timea(itimea1) )/delta
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - NO INTERPOLATION
          IF( npoina.EQ.1 ) THEN
            DO ipoin = 1,npoin
              valeurs(ipoin) =
     &          ( 1.d0-alpha )*valuea1(j,1) + alpha*valuea2(j,1)
!             INTERPOLATION LIKE IN OLD INTERPMETEO
!     &          VALUEA1(J,1) + (VALUEA2(J,1)-VALUEA1(J,1))*ALPHA
            ENDDO
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - TWO POINTS
          ELSEIF( npoina.EQ.2 ) THEN
!           THE PROJECTION OF THE POINT TO THE LINE WILL GIVE YOU THE Z
            x1 = xpoina(1)
            y1 = ypoina(1)
            x2 = xpoina(2)
            y2 = ypoina(2)
!           BEFORE
            z1 = valuea1(j,1)
            z2 = valuea1(j,2)
            z3 = 0.d0
            IF( abs(x2-x1).GT.abs(y2-y1) ) THEN
              z3 = ( z2-z1 )/( x2-x1 )
              DO ipoin = 1,npoin
                valeurs(ipoin) =
     &            ( 1.d0-alpha )*( z1+z3*(xpoina(ipoin)-x1) )
              ENDDO
            ELSEIF( abs(y2-y1).GT.abs(x2-x1) ) THEN
              z3 = ( z2-z1 )/( y2-y1 )
              DO ipoin = 1,npoin
                valeurs(ipoin) =
     &            ( 1.d0-alpha )*( z1+z3*(ypoina(ipoin)-y1) )
              ENDDO
            ELSE
              DO ipoin = 1,npoin
                valeurs(ipoin) = ( 1.d0-alpha )*( z1 )
              ENDDO
            ENDIF
!           AFTER
            z1 = valuea2(j,1)
            z2 = valuea2(j,2)
            z3 = 0.d0
            IF( abs(x2-x1).GT.abs(y2-y1) ) THEN
              z3 = ( z2-z1 )/( x2-x1 )
              DO ipoin = 1,npoin
                valeurs(ipoin) = valeurs(ipoin)
     &                         + alpha*( z1+z3*(xpoina(ipoin)-x1) )
              ENDDO
            ELSEIF( abs(y2-y1).GT.abs(x2-x1) ) THEN
              z3 = ( z2-z1 )/( y2-y1 )
              DO ipoin = 1,npoin
                valeurs(ipoin) = valeurs(ipoin)
     &                         + alpha*( z1+z3*(ypoina(ipoin)-y1) )
              ENDDO
            ELSE
              DO ipoin = 1,npoin
                valeurs(ipoin) = valeurs(ipoin) + alpha*( z1 )
              ENDDO
            ENDIF
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - THREE POINTS
          ELSEIF( npoina.EQ.3 ) THEN
!           THE NORMAL VECTOR AND THE FIRST POINT DEFINE THE PLAN
            x1 = xpoina(1)
            y1 = ypoina(1)
            x2 = xpoina(2)
            y2 = ypoina(2)
            x3 = xpoina(3)
            y3 = ypoina(3)
!           BEFORE
            z1 = valuea1(j,1)
            z2 = valuea1(j,2)
            z3 = valuea1(j,3)
            nx = ( y2-y1 )*( z3-z1 ) - ( z2-z1 )*( y3-y1 )
            ny = ( z2-z1 )*( x3-x1 ) - ( x2-x1 )*( z3-z1 )
            nz = ( x2-x1 )*( y3-y1 ) - ( y2-y1 )*( x3-x1 )
            DO ipoin = 1,npoin
              mx = ( xpoina(ipoin)-x1 )*nx
              my = ( ypoina(ipoin)-y1 )*ny
              valeurs(ipoin) = ( 1.d0-alpha )*( z1-(mx+my)/nz )
            ENDDO
!           AFTER
            z1 = valuea2(j,1)
            z2 = valuea2(j,2)
            z3 = valuea2(j,3)
            nx = ( y2-y1 )*( z3-z1 ) - ( z2-z1 )*( y3-y1 )
            ny = ( z2-z1 )*( x3-x1 ) - ( x2-x1 )*( z3-z1 )
            nz = ( x2-x1 )*( y3-y1 ) - ( y2-y1 )*( x3-x1 )
            DO ipoin = 1,npoin
              mx = ( xpoina(ipoin)-x1 )*nx
              my = ( ypoina(ipoin)-y1 )*ny
              valeurs(ipoin) = valeurs(ipoin) + alpha*( z1-(mx+my)/nz )
            ENDDO
          ENDIF
!       ________________________________________________________________
        ELSEIF( j.NE.0 .AND. what.EQ.'RAINC') THEN
!         ______________________________________________________________
!         TEMPORAL INTERPOLATION
          delta = ( timea(itimea2)-timea(itimea1) )
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - NO INTERPOLATION
          IF( npoina.EQ.1 ) THEN
            DO ipoin = 1,npoin
              valeurs(ipoin) = valuea2(j,1)/delta
            ENDDO
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - TWO POINTS
          ELSEIF( npoina.EQ.2 ) THEN
!           THE PROJECTION OF THE POINT TO THE LINE WILL GIVE YOU THE Z
            x1 = xpoina(1)
            y1 = ypoina(1)
            x2 = xpoina(2)
            y2 = ypoina(2)
!           AFTER
            z1 = valuea2(j,1)
            z2 = valuea2(j,2)
            z3 = 0.d0
            IF( abs(x2-x1).GT.abs(y2-y1) ) THEN
              z3 = ( z2-z1 )/( x2-x1 )
              DO ipoin = 1,npoin
                valeurs(ipoin) = ( z1+z3*(xpoina(ipoin)-x1) ) / delta
              ENDDO
            ELSEIF( abs(y2-y1).GT.abs(x2-x1) ) THEN
              z3 = ( z2-z1 )/( y2-y1 )
              DO ipoin = 1,npoin
                valeurs(ipoin) = ( z1+z3*(ypoina(ipoin)-y1) ) / delta
              ENDDO
            ELSE
              DO ipoin = 1,npoin
                valeurs(ipoin) = z1 / delta
              ENDDO
            ENDIF
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - THREE POINTS
          ELSEIF( npoina.EQ.3 ) THEN
!           THE NORMAL VECTOR AND THE FIRST POINT DEFINE THE PLAN
            x1 = xpoina(1)
            y1 = ypoina(1)
            x2 = xpoina(2)
            y2 = ypoina(2)
            x3 = xpoina(3)
            y3 = ypoina(3)
!           AFTER
            z1 = valuea2(j,1)
            z2 = valuea2(j,2)
            z3 = valuea2(j,3)
            nx = ( y2-y1 )*( z3-z1 ) - ( z2-z1 )*( y3-y1 )
            ny = ( z2-z1 )*( x3-x1 ) - ( x2-x1 )*( z3-z1 )
            nz = ( x2-x1 )*( y3-y1 ) - ( y2-y1 )*( x3-x1 )
            DO ipoin = 1,npoin
              mx = ( xpoina(ipoin)-x1 )*nx
              my = ( ypoina(ipoin)-y1 )*ny
              valeurs(ipoin) = ( z1-(mx+my)/nz ) / delta
            ENDDO
          ENDIF
!       ________________________________________________________________
        ENDIF
      ENDIF
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     B: BINARY FILE
      IF( meteo_deja(2) ) THEN
        choix(1:meteo_maxvalue) = meteo_choix(2,1:meteo_maxvalue)
        j = find_name( what, choix, meteo_maxvalue )
        IF( j.NE.0 .AND. what.NE.'RAINC') THEN
!         ______________________________________________________________
!         TEMPORAL INTERPOLATION
          delta = ( timeb(itimeb2)-timeb(itimeb1) )
          alpha = ( when+tel_offset2-timeb(itimeb1) )/delta
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - NO INTERPOLATION
          DO ipoin = 1,npoin
            valeurs(ipoin) =
     &         ( 1.d0-alpha )*valueb1(j,ipoin) + alpha*valueb2(j,ipoin)
          ENDDO
!
        ELSEIF( j.NE.0 .AND. what.EQ.'RAINC') THEN
!         ______________________________________________________________
!         TEMPORAL INTERPOLATION
          delta = ( timeb(itimeb2)-timeb(itimeb1) )
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - NO INTERPOLATION
          DO ipoin = 1,npoin
            valeurs(ipoin) = valueb2(j,ipoin) / delta
          ENDDO
!
        ENDIF
      ENDIF
      DEALLOCATE(choix)
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!                     ************************
                      SUBROUTINE interp_windxy
!                     ************************
!
     &( when,vitx,vity,npoin )
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Spatial and temporal interpolation of X and Y wind components
!+        from either the ASCII or the BINARY file + magnitude+direction
!+        of velocity
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NPOIN          |-->| NUMBER OF NODES
!| VITX           |<->| VALUES CONTAINED IN THE VARIABLE X WIND COMPONENT
!| VITY           |<->| VALUES CONTAINED IN THE VARIABLE Y WIND COMPONENT
!| WHAT           |-->| VARIABLE TO CONSIDER
!| WHEN           |-->| CURRENT TIME
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      INTEGER,             INTENT(IN) :: NPOIN
      DOUBLE PRECISION,    INTENT(IN) :: WHEN
      DOUBLE PRECISION, INTENT(INOUT) :: VITX(npoin),VITY(npoin)
!
      INTEGER           J1,J2,IPOIN
      DOUBLE PRECISION  DTR,TMPX1(3),TMPY1(3),TMPX2(3),TMPY2(3)
      DOUBLE PRECISION  ALPHA,DELTA
      DOUBLE PRECISION  X1,Y1,Z1,X2,Y2,Z2,X3,Y3,Z3,NX,NY,NZ,MX,MY
      CHARACTER(LEN=16), ALLOCATABLE  :: CHOIX(:)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      dtr = atan(1.d0)/45.d0
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     A: ASCII FILE
      ALLOCATE(choix(meteo_maxvalue))
      IF( meteo_deja(1) ) THEN
        choix(1:meteo_maxvalue) = meteo_choix(1,1:meteo_maxvalue)
        j1 = find_name( 'WINDS', choix, meteo_maxvalue )
        j2 = find_name( 'WINDD', choix, meteo_maxvalue )
        IF( j1.NE.0 .AND. j2.NE.0) THEN
!         ______________________________________________________________
!         TEMPORAL INTERPOLATION
          delta = ( timea(itimea2)-timea(itimea1) )
          alpha = ( when+tel_offset2-timea(itimea1) )/delta
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - NO INTERPOLATION
          IF( npoina.EQ.1 ) THEN
            tmpx1(1) = -valuea1(j1,1)*sin(valuea1(j2,1)*dtr)
            tmpy1(1) = -valuea1(j1,1)*cos(valuea1(j2,1)*dtr)
            tmpx2(1) = -valuea2(j1,1)*sin(valuea2(j2,1)*dtr)
            tmpy2(1) = -valuea2(j1,1)*cos(valuea2(j2,1)*dtr)
            DO ipoin = 1,npoin
              vitx(ipoin) = ( 1.d0-alpha )*tmpx1(1) + alpha*tmpx2(1)
              vity(ipoin) = ( 1.d0-alpha )*tmpy1(1) + alpha*tmpy2(1)
!             INTERPOLATION LIKE IN OLD INTERPMETEO
!              VITX(IPOIN) = TMPX1(1) + (TMPX2(1)-TMPX1(1)) *ALPHA
!              VITY(IPOIN) = TMPY1(1) + (TMPY2(1)-TMPY1(1)) *ALPHA
            ENDDO
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - TWO POINTS
          ELSEIF( npoina.EQ.2 ) THEN
!           THE PROJECTION OF THE POINT TO THE LINE WILL GIVE YOU THE Z
            x1 = xpoina(1)
            y1 = ypoina(1)
            x2 = xpoina(2)
            y2 = ypoina(2)
! X WIND VELOCITY COMPONENT
!           BEFORE
            z1 = -valuea1(j1,1)*sin(valuea1(j2,1)*dtr)
            z2 = -valuea1(j1,2)*sin(valuea1(j2,2)*dtr)
            z3 = 0.d0
            IF( abs(x2-x1).GT.abs(y2-y1) ) THEN
              z3 = ( z2-z1 )/( x2-x1 )
              DO ipoin = 1,npoin
                vitx(ipoin) =
     &            ( 1.d0-alpha )*( z1+z3*(xpoina(ipoin)-x1) )
              ENDDO
            ELSEIF( abs(y2-y1).GT.abs(x2-x1) ) THEN
              z3 = ( z2-z1 )/( y2-y1 )
              DO ipoin = 1,npoin
                vitx(ipoin) =
     &            ( 1.d0-alpha )*( z1+z3*(ypoina(ipoin)-y1) )
              ENDDO
            ELSE
              DO ipoin = 1,npoin
                vitx(ipoin) = ( 1.d0-alpha )*( z1 )
              ENDDO
            ENDIF
!           AFTER
            z1 = -valuea2(j1,1)*sin(valuea2(j2,1)*dtr)
            z2 = -valuea2(j1,2)*sin(valuea2(j2,2)*dtr)
            z3 = 0.d0
            IF( abs(x2-x1).GT.abs(y2-y1) ) THEN
              z3 = ( z2-z1 )/( x2-x1 )
              DO ipoin = 1,npoin
                vitx(ipoin) = vitx(ipoin)
     &                         + alpha*( z1+z3*(xpoina(ipoin)-x1) )
              ENDDO
            ELSEIF( abs(y2-y1).GT.abs(x2-x1) ) THEN
              z3 = ( z2-z1 )/( y2-y1 )
              DO ipoin = 1,npoin
                vitx(ipoin) = vitx(ipoin)
     &                         + alpha*( z1+z3*(ypoina(ipoin)-y1) )
              ENDDO
            ELSE
              DO ipoin = 1,npoin
                vitx(ipoin) = vitx(ipoin) + alpha*( z1 )
              ENDDO
            ENDIF
! Y WIND VELOCITY COMPONENT
!           BEFORE
            z1 = -valuea1(j1,1)*cos(valuea1(j2,1)*dtr)
            z2 = -valuea1(j1,2)*cos(valuea1(j2,2)*dtr)
            z3 = 0.d0
            IF( abs(x2-x1).GT.abs(y2-y1) ) THEN
              z3 = ( z2-z1 )/( x2-x1 )
              DO ipoin = 1,npoin
                vity(ipoin) =
     &            ( 1.d0-alpha )*( z1+z3*(xpoina(ipoin)-x1) )
              ENDDO
            ELSEIF( abs(y2-y1).GT.abs(x2-x1) ) THEN
              z3 = ( z2-z1 )/( y2-y1 )
              DO ipoin = 1,npoin
                vity(ipoin) =
     &            ( 1.d0-alpha )*( z1+z3*(ypoina(ipoin)-y1) )
              ENDDO
            ELSE
              DO ipoin = 1,npoin
                vity(ipoin) = ( 1.d0-alpha )*( z1 )
              ENDDO
            ENDIF
!           AFTER
            z1 = -valuea2(j1,1)*cos(valuea2(j2,1)*dtr)
            z2 = -valuea2(j1,2)*cos(valuea2(j2,2)*dtr)
            z3 = 0.d0
            IF( abs(x2-x1).GT.abs(y2-y1) ) THEN
              z3 = ( z2-z1 )/( x2-x1 )
              DO ipoin = 1,npoin
                vity(ipoin) = vity(ipoin)
     &                         + alpha*( z1+z3*(xpoina(ipoin)-x1) )
              ENDDO
            ELSEIF( abs(y2-y1).GT.abs(x2-x1) ) THEN
              z3 = ( z2-z1 )/( y2-y1 )
              DO ipoin = 1,npoin
                vity(ipoin) = vity(ipoin)
     &                         + alpha*( z1+z3*(ypoina(ipoin)-y1) )
              ENDDO
            ELSE
              DO ipoin = 1,npoin
                vity(ipoin) = vity(ipoin) + alpha*( z1 )
              ENDDO
            ENDIF
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - THREE POINTS
          ELSEIF( npoina.EQ.3 ) THEN
!           THE NORMAL VECTOR AND THE FIRST POINT DEFINE THE PLAN
            x1 = xpoina(1)
            y1 = ypoina(1)
            x2 = xpoina(2)
            y2 = ypoina(2)
            x3 = xpoina(3)
            y3 = ypoina(3)
! X WIND VELOCITY COMPONENT
!           BEFORE
            z1 = -valuea1(j1,1)*sin(valuea1(j2,1)*dtr)
            z2 = -valuea1(j1,2)*sin(valuea1(j2,2)*dtr)
            z3 = -valuea1(j1,3)*sin(valuea1(j2,3)*dtr)
            nx = ( y2-y1 )*( z3-z1 ) - ( z2-z1 )*( y3-y1 )
            ny = ( z2-z1 )*( x3-x1 ) - ( x2-x1 )*( z3-z1 )
            nz = ( x2-x1 )*( y3-y1 ) - ( y2-y1 )*( x3-x1 )
            DO ipoin = 1,npoin
              mx = ( xpoina(ipoin)-x1 )*nx
              my = ( ypoina(ipoin)-y1 )*ny
              vitx(ipoin) = ( 1.d0-alpha )*( z1-(mx+my)/nz )
            ENDDO
!           AFTER
            z1 = -valuea2(j1,1)*sin(valuea2(j2,1)*dtr)
            z2 = -valuea2(j1,2)*sin(valuea2(j2,2)*dtr)
            z3 = -valuea2(j1,3)*sin(valuea2(j2,3)*dtr)
            nx = ( y2-y1 )*( z3-z1 ) - ( z2-z1 )*( y3-y1 )
            ny = ( z2-z1 )*( x3-x1 ) - ( x2-x1 )*( z3-z1 )
            nz = ( x2-x1 )*( y3-y1 ) - ( y2-y1 )*( x3-x1 )
            DO ipoin = 1,npoin
              mx = ( xpoina(ipoin)-x1 )*nx
              my = ( ypoina(ipoin)-y1 )*ny
              vitx(ipoin) = vitx(ipoin) + alpha*( z1-(mx+my)/nz )
            ENDDO
! Y WIND VELOCITY COMPONENT
!           BEFORE
            z1 = -valuea1(j1,1)*cos(valuea1(j2,1)*dtr)
            z2 = -valuea1(j1,2)*cos(valuea1(j2,2)*dtr)
            z3 = -valuea1(j1,3)*cos(valuea1(j2,3)*dtr)
            nx = ( y2-y1 )*( z3-z1 ) - ( z2-z1 )*( y3-y1 )
            ny = ( z2-z1 )*( x3-x1 ) - ( x2-x1 )*( z3-z1 )
            nz = ( x2-x1 )*( y3-y1 ) - ( y2-y1 )*( x3-x1 )
            DO ipoin = 1,npoin
              mx = ( xpoina(ipoin)-x1 )*nx
              my = ( ypoina(ipoin)-y1 )*ny
              vity(ipoin) = ( 1.d0-alpha )*( z1-(mx+my)/nz )
            ENDDO
!           AFTER
            z1 = -valuea2(j1,1)*cos(valuea2(j2,1)*dtr)
            z2 = -valuea2(j1,2)*cos(valuea2(j2,2)*dtr)
            z3 = -valuea2(j1,3)*cos(valuea2(j2,3)*dtr)
            nx = ( y2-y1 )*( z3-z1 ) - ( z2-z1 )*( y3-y1 )
            ny = ( z2-z1 )*( x3-x1 ) - ( x2-x1 )*( z3-z1 )
            nz = ( x2-x1 )*( y3-y1 ) - ( y2-y1 )*( x3-x1 )
            DO ipoin = 1,npoin
              mx = ( xpoina(ipoin)-x1 )*nx
              my = ( ypoina(ipoin)-y1 )*ny
              vity(ipoin) = vity(ipoin) + alpha*( z1-(mx+my)/nz )
            ENDDO
          ENDIF
!       ________________________________________________________________
        ENDIF
      ENDIF
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     B: BINARY FILE
      IF( meteo_deja(2) ) THEN
        choix(1:meteo_maxvalue) = meteo_choix(2,1:meteo_maxvalue)
        j1 = find_name( 'WINDS', choix, meteo_maxvalue )
        j2 = find_name( 'WINDD', choix, meteo_maxvalue )
        IF( j1.NE.0 .AND. j2.NE.0) THEN
!         ______________________________________________________________
!         TEMPORAL INTERPOLATION
          delta = ( timeb(itimeb2)-timeb(itimeb1) )
          alpha = ( when+tel_offset2-timeb(itimeb1) )/delta
!         ______________________________________________________________
!         SPATIAL INTERPOLATION - NO INTERPOLATION
          DO ipoin = 1,npoin
            tmpx1(1) = -valueb1(j1,ipoin)*sin(valueb1(j2,ipoin)*dtr)
            tmpy1(1) = -valueb1(j1,ipoin)*cos(valueb1(j2,ipoin)*dtr)
            tmpx2(1) = -valueb2(j1,ipoin)*sin(valueb2(j2,ipoin)*dtr)
            tmpy2(1) = -valueb2(j1,ipoin)*cos(valueb2(j2,ipoin)*dtr)
            vitx(ipoin) = ( 1.d0-alpha )*tmpx1(1) + alpha*tmpx2(1)
            vity(ipoin) = ( 1.d0-alpha )*tmpy1(1) + alpha*tmpy2(1)
          ENDDO
!
        ENDIF
      ENDIF
      DEALLOCATE(choix)
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!                   **************************
                    INTEGER FUNCTION find_name
!                   **************************
!
     &( name,choix,maxvalue )
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Search for NAME in a list of CHOIX (variables found in the
!+        METEO files). Return 0 if not found, the index in CHOIX
!+        otherwise.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CHOIX          |-->| LIST OF VARIABLES PRESENT IN THE METEO FILE
!| MAXVALUE       |-->| MAXIMUM SIZE OF THE LIST CHOIX
!| NAME           |-->| MNEMO OF THE VARIABLE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      CHARACTER(LEN=*), INTENT(IN) :: NAME
      INTEGER,          INTENT(IN) :: MAXVALUE
      CHARACTER(LEN=*), INTENT(IN) :: CHOIX(maxvalue)
!
      INTEGER :: I
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     DEFAULT IF NOT FOUND
      find_name = 0
!     LOOP THROUGH
      DO i = 1,maxvalue
        IF( inclus( choix(i), name ) ) find_name = i
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END FUNCTION
!
!=======================================================================
!
!                   **************************
                    SUBROUTINE init_fic_binary
!                   **************************
!
     &( files,atmfileb )
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Scan the ASCII file and prepare skeleton for future calls
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ATMFILEA       |-->| LOGICAL UNIT OF ASCII FILE FOR METEO
!| FILES          |-->| ARRAYS OF ALL FILES
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_hermes
      IMPLICIT NONE
!
      TYPE(bief_file),     INTENT(IN) :: FILES(*)
      INTEGER,             INTENT(IN) :: ATMFILEB
!
      INTEGER :: I,J, NFIC, IERR
      CHARACTER(LEN=8)  :: NFMT
!
      CHARACTER(LEN=16), POINTER  :: CHOIX(:)
      CHARACTER(LEN=16), POINTER  :: UNITS(:)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     SETTING LOCAL ASCII FILE
      meteo_files(2)%LU      = files(atmfileb)%LU
      meteo_files(2)%NAME    = files(atmfileb)%NAME
      meteo_files(2)%TELNAME = files(atmfileb)%TELNAME
      meteo_files(2)%FMT     = files(atmfileb)%FMT
      meteo_files(2)%ACTION  = files(atmfileb)%ACTION
      meteo_files(2)%BINASC  = files(atmfileb)%BINASC
      meteo_files(2)%TYPE    = files(atmfileb)%TYPE
!
!     SIMPLIFYING NOTATIONS
      nfmt     = meteo_files(2)%FMT
      nfic     = meteo_files(2)%LU
      units =>   meteo_units(2,1:meteo_maxvalue)
      choix =>   meteo_choix(2,1:meteo_maxvalue)
!
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     SCAN THE SKELETON
!
!     __________________________________________________________________
!     GET THE NUMBER OF POINTS IN THE METEO FILE
      CALL get_mesh_npoin(nfmt,nfic,triangle_elt_type,npoinb,ierr)
      CALL check_call
     &  (ierr,"METEO,INIT_FIC_BINARY: GET_MESH_NPOIN")
!
!     __________________________________________________________________
!     FIND OUT WHAT VARIABLES ARE GIVEN IN THE FILE
!
      CALL get_data_nvar(nfmt,nfic,nvalueb,ierr)
      CALL check_call
     &  (ierr, 'METEO,INIT_FIC_BINARY:GET_DATA_NVAR')
!
      CALL get_data_var_list(nfmt,nfic,nvalueb,choix,units,ierr)
      CALL check_call
     &  (ierr, 'METEO,INIT_FIC_BINARY:GET_DATA_VAR_LIST')
!
!     __________________________________________________________________
!     GET THE TIME PROFILE FOR FUTURE INTERPOLATION
      CALL get_data_ntimestep(nfmt,nfic,ntimeb,ierr)
      CALL check_call
     &  (ierr,'METEO,INIT_FIC_BINARY:GET_DATA_NTIMESTEP')
!
      ALLOCATE(timeb(ntimeb))
      DO i = 1,ntimeb
        CALL get_data_time(nfmt,nfic,i,timeb(i),ierr)
        CALL check_call
     &    (ierr,'METEO,INIT_FIC_BINARY:GET_DATA_TIME:I')
        timeb(i) = timeb(i) + meteo_offset
      ENDDO
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     PREPARE FOR NEXT ACCESS TO THE FILE
!
      ALLOCATE(valueb1(nvalueb,npoinb),valueb2(nvalueb,npoinb))
      ALLOCATE(valueb0(npoinb))
!     __________________________________________________________________
!     READ ONE TIME FRAME AT LEAST
      itimeb1 = 1
      itimeb2 = 1
      DO i = 1,nvalueb
        CALL get_data_value
     &    (nfmt,nfic,itimeb1,choix(i),valueb0,npoinb,ierr)
        CALL check_call
     &    (ierr,'METEO,INIT_FIC_BINARY:GET_DATA_VALUE:CHOIX')
        DO j = 1,npoinb
          valueb1(i,j) = valueb0(j)
          valueb2(i,j) = valueb0(j)
        ENDDO
      ENDDO
!     __________________________________________________________________
!     READ A SECOND TIME FRAME IF THERE
      IF( ntimeb.GT.1 )THEN
        itimeb2 = 1
        DO i = 1,nvalueb
          CALL get_data_value
     &      (nfmt,nfic,itimeb2,choix(i),valueb0,npoinb,ierr)
          CALL check_call
     &      (ierr,'METEO,INIT_FIC_BINARY:GET_DATA_VALUE:CHOIX')
          DO j = 1,npoinb
            valueb2(i,j) = valueb0(j)
          ENDDO
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!                   *************************
                    SUBROUTINE init_fic_ascii
!                   *************************
!
     &( files,atmfilea )
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Scan the ASCII file and prepare skeleton for future calls
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ATMFILEA       |-->| LOGICAL UNIT OF ASCII FILE FOR METEO
!| FILES          |-->| ARRAYS OF ALL FILES
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      TYPE(bief_file),     INTENT(IN) :: FILES(*)
      INTEGER,             INTENT(IN) :: ATMFILEA
!
      INTEGER :: I,J,K, NFIC, IDEB,IFIN, NPOINX,NPOINY
      CHARACTER(LEN=SIZELIGN) :: LIGNE
      DOUBLE PRECISION :: X1,X2,X3, Y1,Y2,Y3
!
      CHARACTER(LEN=16), POINTER  :: CHOIX(:)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     SETTING LOCAL ASCII FILE
      meteo_deja(1) = .false.
      meteo_files(1)%LU      = files(atmfilea)%LU
      meteo_files(1)%NAME    = files(atmfilea)%NAME
      meteo_files(1)%TELNAME = files(atmfilea)%TELNAME
      meteo_files(1)%FMT     = files(atmfilea)%FMT
      meteo_files(1)%ACTION  = files(atmfilea)%ACTION
      meteo_files(1)%BINASC  = files(atmfilea)%BINASC
      meteo_files(1)%TYPE    = files(atmfilea)%TYPE
!
!     SIMPLIFYING NOTATIONS
      nfic     = meteo_files(1)%LU
      choix => meteo_choix(1,1:meteo_maxvalue)
!
!     DEFAULT NUMBER OF LOCATIONS
      npoinx = 1
      npoiny = 1
      x1 = 0.d0
      y1 = 0.d0
!
      meteo_ref_date(1) = 0
      meteo_ref_date(2) = 0
      meteo_ref_date(3) = 0
      meteo_ref_date(4) = 0
      meteo_ref_date(5) = 0
      meteo_ref_date(6) = 0
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     READ THE FILE ONE TIME IN FULL TO SIZE UP ITS CONTENT
!     ( TODO: REPLACE GOTO STATEMENTS BY WHILE STATEMENT )
      rewind(nfic)
!
!  READS THE HEADLINE OF THE DATA FILE
!
!       JUMPING TWO LINES OF COMMENTS
      READ(nfic,fmt='(A)',err=103) ligne
      IF(ligne(1:8).EQ.'#REFDATE') THEN
        CALL read_ref_date(ligne, meteo_ref_date)
      ELSE
        backspace(nfic)
      ENDIF
!     __________________________________________________________________
!     SKIP COMMENTS
!
 101  READ(nfic,fmt='(A)',err=103) ligne
      GOTO 102
!
 103  CONTINUE
      WRITE(lu,*) 'ERROR WHILE READING THE ASCII FILE'
      WRITE(lu,*) 'USED FOR THE METEO (THERMAL PROCESSES)'
      WRITE(lu,*) 'PROBABLY A PROBLEM OF FORMAT'
      WRITE(lu,*) 'ANY WINDOWS CARRIAGE RETURNS ON UNIX OR LINUX'
      WRITE(lu,*) 'GUILTY LINE:'
      WRITE(lu,*) ligne
      CALL plante(1)
      stop
!
 102  CONTINUE
!     IF( LIGNE(1:36).EQ.'#SPECIAL ASCII ATMOSPHERIC DATA FILE' ) THEN
!       WRITE(LU,*) 'SPECIAL ASCII ATMOSPHERIC DATA FILE'
!       WRITE(LU,*) 'TREATMENT TO IMPLEMENTED BY THE USER'
!       RETURN
!     ENDIF
!
      IF( ligne(1:1).EQ.':' ) THEN
!       DEFINING X-LOCATIONS IF MORE THAN ONE (UP TO THREE)
        IF( inclus(ligne,':X') )THEN
          ideb = 2
 151      IF( ideb.GE.sizelign ) GOTO 152
          ideb = ideb + 1
          IF( (ligne(ideb:ideb).NE.' ') .AND.
     &         ligne(ideb:ideb).NE.char(9) ) GOTO 151
!         THE REST OF THE LINE SHOULD HAVE AT MOST THREE VALUES
          READ(ligne(ideb:sizelign),*,err=152) x1,x2
          npoinx = npoinx + 1
          READ(ligne(ideb:sizelign),*,err=152) x1,x2,x3
          npoinx = npoinx + 1
 152      CONTINUE
!       DEFINING Y-LOCATIONS IF MORE THAN ONE (UP TO THREE)
        ELSEIF( inclus(ligne,':Y') )THEN
          ideb = 2
 153      IF( ideb.GE.sizelign ) GOTO 154
          ideb = ideb + 1
          IF( (ligne(ideb:ideb).NE.' ') .AND.
     &         ligne(ideb:ideb).NE.char(9) ) GOTO 153
!         THE REST OF THE LINE SHOULD HAVE AT MOST THREE VALUES
          READ(ligne(ideb:sizelign),*,err=154) y1,y2
          npoiny = npoiny + 1
          READ(ligne(ideb:sizelign),*,err=154) y1,y2,y3
          npoiny = npoiny + 1
 154      CONTINUE
        ENDIF
      ENDIF
      IF( ligne(1:1).EQ.'#' .OR.
     &    ligne(1:1).EQ.'!' .OR.
     &    ligne(1:1).EQ.':' ) GOTO 101
!
      IF(any(meteo_ref_date.NE.0)) THEN
        IF(tel_offset.LE.1.d-16) THEN
          WRITE(lu,*) 'REFERENCE DATE IN ASCII ATMOSPHERIC DATA FILE'
          WRITE(lu,*) 'MISSING ORIGINAL DATE OF TIME IN '//
     &                'STEERING FILE'
          CALL plante(1)
          stop
        ENDIF
        meteo_offset = date_mjd2sec(meteo_ref_date(1:3),
     &                              meteo_ref_date(4:6))
        tel_offset2 = tel_offset
        WRITE(lu,*) 'USING REFERENCE DATE FOR METEO:'
        WRITE(lu,666) meteo_ref_date
666     FORMAT(5x,1i4,'-',1i0.2,'-',1i0.2,' ',
     &         1i0.2,':',1i0.2,':',1i0.2)
      ELSE
        tel_offset2 = 0.d0
        meteo_offset = 0.d0
      ENDIF
!
!     __________________________________________________________________
!     FINALISING LOCATIONS
!
      IF( npoinx.NE.npoiny )THEN
        WRITE(lu,*) 'NUMBER OF LOCATIONS X AND Y LOCATIONS READ'
        WRITE(lu,*) 'IN THE ASCII FILE USED FOR THE METEO (THERMAL'
        WRITE(lu,*) 'PROCESSES) DIFFERENT.'
      ENDIF
      npoina = npoinx
      ALLOCATE( xpoina(npoina),ypoina(npoina) )
      IF( npoina.GE.1 ) THEN
        xpoina(1) = x1
        ypoina(1) = y1
      ENDIF
      IF( npoina.GE.2 ) THEN
        xpoina(2) = x2
        ypoina(2) = y2
      ENDIF
      IF( npoina.EQ.3 ) THEN
        xpoina(3) = x3
        ypoina(3) = y3
      ENDIF
!     __________________________________________________________________
!     FIND OUT WHAT AND HOW MANY VALUES ARE GIVEN IN THE FILE
!
      nvaluea = -1
      ifin = 1
 104  ideb = ifin
!
!     IDENTIFY FIRST CHARACTER OF NAME
 105  IF((ligne(ideb:ideb).EQ.' '.OR.ligne(ideb:ideb).EQ.char(9))
     &   .AND.ideb.LT.sizelign) THEN
        ideb = ideb + 1
        GOTO 105
      ENDIF
!     IDENTIFY LAST CHARACTER OF NAME ( TODO: USE A WHILE STATEMENT )
      ifin = ideb
 106  IF( ligne(ifin:ifin).NE.' '.AND.ligne(ifin:ifin).NE.char(9)
     &   .AND.ifin.LT.sizelign) THEN
        ifin = ifin + 1
        GOTO 106
      ENDIF
!
      IF( ideb.EQ.ifin ) GOTO 140  ! IDEB .EQ. IFIN .EQ. SIZELIGN
!
      nvaluea = nvaluea + 1
      IF( nvaluea.EQ.0 ) THEN
!       SPECIAL CASE FOR TIME
        IF(ligne(ideb:ifin-1).NE.'T') THEN
          WRITE(lu,*) 'THE FIRST VARIABLE MUST BE TIME T IN THE'
          WRITE(lu,*) 'ASCII FILE USED FOR THE METEO (THERMAL'
          WRITE(lu,*) 'PROCESSES). OTHER POSSIBLE CAUSE:'
          WRITE(lu,*) 'THERE ARE TABS IN THE FILE'
          WRITE(lu,*) 'CHANGE TABS INTO SPACES'
          CALL plante(1)
          stop
        ENDIF
      ELSEIF( nvaluea.LE.meteo_maxvalue ) THEN
        choix(nvaluea) = '                '
        choix(nvaluea)(1:ifin-ideb+1) = ligne(ideb:ifin-1)
      ELSE
        WRITE(lu,*) 'INCREASE MAXVALUE FOR READ_FIC_ASCII'
        CALL plante(1)
        stop
      ENDIF
      IF(ifin.LT.sizelign) GO TO 104
!
      IF( int(nvaluea/npoina)*npoina .EQ. nvaluea )THEN
        nvaluea = int(nvaluea/npoina)
      ELSE
        WRITE(lu,*) 'NUMBER OF LOCATIONS AND TOTAL NUMBER OF VALUES'
        WRITE(lu,*) 'FOUND IN THE ASCCI FILE FOR METEO (THERMAL'
        WRITE(lu,*) 'PROCESSES) ARE INCOMPATIBLE.'
        WRITE(lu,*) 'ONE VALUE PER VARIABLE SHOULD BE THERE FOR EACH'
        WRITE(lu,*) 'LOCATION.'
        CALL plante(1)
        stop
      ENDIF
!     __________________________________________________________________
!     SKIP THE LINE WITH UNITS AS WELL AS COMMENTS
 140  READ(nfic,fmt='(A)',err=103) ligne
      IF( ligne(1:1).EQ.'#' .OR.
     &    ligne(1:1).EQ.'!' .OR.
     &    ligne(1:1).EQ.':' ) GOTO 140
!     __________________________________________________________________
!     COUNT LINES OF DATA
      ntimea = 0
 201  READ(nfic,*,end=202,err=203) ligne
      IF( ligne(1:1).NE.'#' .AND.
     &    ligne(1:1).NE.'!' .AND.
     &    ligne(1:1).NE.':' ) ntimea = ntimea + 1
      GOTO 201
!
 203  CONTINUE
      WRITE(lu,*) 'ERROR READING THE ASCII FILE USED FOR THE METEO'
      WRITE(lu,*) '(THERMAL PROCESSES) AT LINE: ',ntimea
      WRITE(lu,*) '(COMMENTS EXCLUDED)'
      CALL plante(1)
      stop
!
 202  CONTINUE
      IF( ntimea.LE.1 ) THEN
        WRITE(lu,*) 'TWO TIME STEP AT LEAST SHOULD BE PRESENT IN'
        WRITE(lu,*) 'THE ASCII FILE USED FOR THE METEO (THERMAL'
        WRITE(lu,*) 'PROCESSES)'
        CALL plante(1)
        stop
      ENDIF
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     READ THE FILE A SECOND TIME IN FULL TO KEEP ITS SCKELETON
!     ( TODO: REPLACE GOTO STATEMENTS BY WHILE STATEMENT )
      rewind(nfic)
!     __________________________________________________________________
!     ALLOCATE TIME SCKELETON IN MEMORY
      ALLOCATE(timea(ntimea))
      ALLOCATE(valuea1(nvaluea,npoina),valuea2(nvaluea,npoina))
!     __________________________________________________________________
!     SKIP COMMENTS AND FIRST TWO MANDATORY LINES
 111  READ(nfic,fmt='(A)') ligne
      IF( ligne(1:1).EQ.'#' .OR.
     &    ligne(1:1).EQ.'!' .OR.
     &    ligne(1:1).EQ.':' ) GOTO 111
 112  READ(nfic,fmt='(A)') ligne
      IF( ligne(1:1).EQ.'#' .OR.
     &    ligne(1:1).EQ.'!' .OR.
     &    ligne(1:1).EQ.':' ) GOTO 112
!     __________________________________________________________________
!     SAVE ALL TIMES FOR TEMPORAL INTERPOLATION
      DO i = 1,ntimea
 113    READ(nfic,fmt='(A)') ligne
        IF( ligne(1:1).EQ.'#' .OR.
     &      ligne(1:1).EQ.'!' .OR.
     &      ligne(1:1).EQ.':' ) GOTO 113
        READ(ligne,*) timea(i),((valuea1(j,k),j=1,nvaluea),k=1,npoina)
        timea(i) = timea(i) + meteo_offset
      ENDDO
!
      IF(meteo_offset.LE.1.d-16) THEN
        tel_offset2 = 0.d0
      ELSE
        tel_offset2 = tel_offset
      ENDIF
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     REWIND AND PREPARE FOR NEXT ACCESS TO THE FILE
      rewind(nfic)
!     __________________________________________________________________
!     SKIP COMMENTS AND FIRST TWO MANDATORY LINES
 121  READ(nfic,fmt='(A)') ligne
      IF( ligne(1:1).EQ.'#' .OR.
     &    ligne(1:1).EQ.'!' .OR.
     &    ligne(1:1).EQ.':' ) GOTO 121
 122  READ(nfic,fmt='(A)') ligne
      IF( ligne(1:1).EQ.'#' .OR.
     &    ligne(1:1).EQ.'!' .OR.
     &    ligne(1:1).EQ.':' ) GOTO 122
!     __________________________________________________________________
!     INITIAL TIMES AND VALUES TO THE FIRST TWO LINES
      itimea1 = 1
 123  READ(nfic,fmt='(A)') ligne
      IF( ligne(1:1).EQ.'#' .OR.
     &    ligne(1:1).EQ.'!' .OR.
     &    ligne(1:1).EQ.':' ) GOTO 123
      READ(ligne,*) dummy,   ! TIMEA(ITIMEA1), ALREADY STORED + SHIFTED
     &  ((valuea1(j,k),j=1,nvaluea),k=1,npoina)
      itimea2 = 2
 124  READ(nfic,fmt='(A)') ligne
      IF( ligne(1:1).EQ.'#' .OR.
     &    ligne(1:1).EQ.'!' .OR.
     &    ligne(1:1).EQ.':' ) GOTO 124
      READ(ligne,*) dummy,   ! TIMEA(ITIMEA2), ALREADY STORED + SHIFTED
     &  ((valuea2(j,k),j=1,nvaluea),k=1,npoina)
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!                   **************************
                    SUBROUTINE sync_fic_binary
!                   **************************
!
     &( when )
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Synchronise the BINARY file for spatial and temporal
!         interpolation
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| WHEN           |-->| CURRENT TIME
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      DOUBLE PRECISION, INTENT(IN)    :: WHEN
!
      INTEGER :: I,J, IERR, NFIC
      CHARACTER(LEN=8)  :: NFMT
!
      CHARACTER(LEN=16), POINTER  :: CHOIX(:)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     SIMPLIFYING NOTATIONS
      nfmt     = meteo_files(2)%FMT
      nfic     = meteo_files(2)%LU
      choix =>   meteo_choix(2,1:meteo_maxvalue)
!
!
!     INTERPOLATE IN TIME FOR ONE PARTICULAR VARIABLE
!     __________________________________________________________________
!     TOO EARLY
      IF( when+tel_offset2.LT.timeb(1) ) THEN
        WRITE(lu,*) 'THE TIME REQUESTED IS TOO EARLY COMPARED TO'
        WRITE(lu,*) 'THE PROFIL OF BINARY FILE USED FOR THE METEO'
        WRITE(lu,*) '(THERMAL PROCESSES)'
        CALL plante(1)
        stop
!     __________________________________________________________________
!     TOO LATE
      ELSEIF( when+tel_offset2.GT.timeb(ntimeb) ) THEN
        WRITE(lu,*) 'THE TIME REQUESTED IS TOO LATE COMPARED TO'
        WRITE(lu,*) 'THE PROFIL OF BINARY FILE USED FOR THE METEO'
        WRITE(lu,*) '(THERMAL PROCESSES)'
        CALL plante(1)
        stop
      ENDIF
!     __________________________________________________________________
!     FIND WHEN
      IF( when+tel_offset2.GT.timeb(itimeb2) )THEN
 132    itimeb1 = itimeb2
        DO i = 1,nvalueb
          DO j = 1,npoinb
            valueb1(i,j) = valueb2(i,j)
          ENDDO
        ENDDO
        itimeb2 = itimeb2 + 1
        DO i = 1,nvalueb
          CALL get_data_value
     &      (nfmt,nfic,itimeb2,choix(i),valueb0,npoinb,ierr)
          CALL check_call
     &      (ierr,'METEO,INIT_FIC_BINARY:GET_DATA_VALUE:CHOIX')
          DO j = 1,npoinb
            valueb2(i,j) = valueb0(j)
          ENDDO
        ENDDO
        IF( when+tel_offset2.GT.timeb(itimeb2) ) GOTO 132
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!                   *************************
                    SUBROUTINE sync_fic_ascii
!                   *************************
!
     &( when )
!
!***********************************************************************
! BIEF   V8P2
!***********************************************************************
!
!brief    Synchronise the ASCII file for spatial and temporal
!         interpolation
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| WHEN           |-->| CURRENT TIME
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      DOUBLE PRECISION, INTENT(IN)    :: WHEN
!
      INTEGER :: J,K, NFIC
      CHARACTER(LEN=SIZELIGN) :: LIGNE
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
!     SIMPLIFYING NOTATIONS
      nfic     = meteo_files(1)%LU
!
!
!     INTERPOLATE IN TIME FOR ONE PARTICULAR VARIABLE
!     __________________________________________________________________
!     TOO EARLY
      IF( when+tel_offset2.LT.timea(1) ) THEN
        WRITE(lu,*) 'THE TIME REQUESTED IS TOO EARLY COMPARED TO'
        WRITE(lu,*) 'THE PROFIL OF ASCII FILE USED FOR THE METEO'
        WRITE(lu,*) '(THERMAL PROCESSES)'
        CALL plante(1)
        stop
!     __________________________________________________________________
!     TOO LATE
      ELSEIF( when+tel_offset2.GT.timea(ntimea) ) THEN
        WRITE(lu,*) 'THE TIME REQUESTED IS TOO LATE COMPARED TO'
        WRITE(lu,*) 'THE PROFIL OF ASCII FILE USED FOR THE METEO'
        WRITE(lu,*) '(THERMAL PROCESSES)'
        CALL plante(1)
        stop
      ENDIF
!     __________________________________________________________________
!     FIND WHEN
      IF( when+tel_offset2.GE.timea(itimea2) )THEN
!
 132    itimea1 = itimea2
        DO j = 1,nvaluea
          DO k = 1,npoina
            valuea1(j,k) = valuea2(j,k)
          ENDDO
        ENDDO
        itimea2 = itimea2 + 1
 133    READ(nfic,fmt='(A)') ligne
        IF( ligne(1:1).EQ.'#' .OR.
     &      ligne(1:1).EQ.'!' .OR.
     &      ligne(1:1).EQ.':' ) GOTO 133
        READ(ligne,*) dummy,   ! TIMEA(ITIMEA2), ALREADY STORED + SHIFTED 
     &      ((valuea2(j,k),j=1,nvaluea),k=1,npoina)
        IF( when+tel_offset2.GE.timea(itimea2) ) GOTO 132
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE
!
!=======================================================================
!
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      END MODULE meteo_telemac