mer21.f

Go to the documentation of this file.

!                   ****************
                    SUBROUTINE mer21
!                   ****************
!
     &(x, xa1,xa2,xa3,xa4,xa5,xa6 , ikle1,ikle2,ikle3,ikle4,
     & nelem,nelmax,npoin,lv)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    PRODUCT X = U B (BEWARE: ELEMENT BY ELEMENT).
!+
!+            HERE: Q1 ELEMENT OR ELEMENT WITH 4 POINTS.
!+
!+            REVERSE OPERATION FROM THAT IN SUBROUTINE REMONT,
!+                HENCE THE NAME.
!code
!+        THE MATRIX U IS HERE THE RESULT OF A DECOMPOSITION
!+        DONE IN SUBROUTINE DECLDU.
!+
!+        EACH ELEMENTARY MATRIX HAS BEEN FACTORISED IN THE FORM :
!+
!+        LE X DE X UE
!+
!+        LE : LOWER TRIANGULAR WITH 1S ON THE DIAGONAL
!+        DE : DIAGONAL
!+        UE : UPPER TRIANGULAR WITH 1S ON THE DIAGONAL
!+
!+                                            T
!+        IF THE MATRIX IS SYMMETRICAL : LE =  UE
!
!history  J-M HERVOUET (LNH)    ; F LEPEINTRE (LNH)
!+        05/02/91
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE1          |-->| FIRST POINTS OF QUADRILATERALS
!| IKLE2          |-->| SECOND POINTS OF QUADRILATERALS
!| IKLE3          |-->| THIRD POINTS OF QUADRILATERALS
!| IKLE4          |-->| FOURTH POINTS OF QUADRILATERALS
!| LV             |-->| VECTOR LENGTH OF THE MACHINE
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!| X              |<--| RESULTING VECTOR
!| XA1            |-->| OFF-DIAGONAL TERM
!| XA2            |-->| OFF-DIAGONAL TERM
!| XA3            |-->| OFF-DIAGONAL TERM
!| XA4            |-->| OFF-DIAGONAL TERM
!| XA5            |-->| OFF-DIAGONAL TERM
!| XA6            |-->| OFF-DIAGONAL TERM
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NPOIN,NELEM,NELMAX,LV
      INTEGER, INTENT(IN)             :: IKLE1(nelmax),IKLE2(nelmax)
      INTEGER, INTENT(IN)             :: IKLE3(nelmax),IKLE4(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: X(npoin)
      DOUBLE PRECISION, INTENT(IN) :: XA1(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: XA2(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: XA3(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: XA4(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: XA5(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: XA6(nelmax)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IB
!
      INTRINSIC min
!
!-----------------------------------------------------------------------
!
! RESUMES INVERSION OF THE LOWER TRIANGULAR MATRICES
!
!-----------------------------------------------------------------------
! LOOP IN SCALAR MODE (LV=1) OR WITH FORCED VECTORISATION
!-----------------------------------------------------------------------
!
      IF(lv.EQ.1) THEN
!
!  SCALAR MODE
!
      DO ielem = 1 , nelem
          x(ikle1(ielem))=x(ikle1(ielem))+xa3(ielem)*x(ikle4(ielem))
     &                                   +xa2(ielem)*x(ikle3(ielem))
     &                                   +xa1(ielem)*x(ikle2(ielem))
          x(ikle2(ielem))=x(ikle2(ielem))+xa5(ielem)*x(ikle4(ielem))
     &                                   +xa4(ielem)*x(ikle3(ielem))
          x(ikle3(ielem))=x(ikle3(ielem))+xa6(ielem)*x(ikle4(ielem))
      ENDDO ! IELEM
!
      ELSE
!
!  VECTOR MODE
!
      DO ib = 1,(nelem+lv-1)/lv
!VOCL LOOP,NOVREC
!DIR$ IVDEP
      DO ielem = 1+(ib-1)*lv , min(nelem,ib*lv)
          x(ikle1(ielem))=x(ikle1(ielem))+xa3(ielem)*x(ikle4(ielem))
     &                                   +xa2(ielem)*x(ikle3(ielem))
     &                                   +xa1(ielem)*x(ikle2(ielem))
          x(ikle2(ielem))=x(ikle2(ielem))+xa5(ielem)*x(ikle4(ielem))
     &                                   +xa4(ielem)*x(ikle3(ielem))
          x(ikle3(ielem))=x(ikle3(ielem))+xa6(ielem)*x(ikle4(ielem))
      ENDDO ! IELEM
      ENDDO ! IB
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END