maskto.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE maskto
!                   *****************
!
     &(maskel,maskpt,ifamas,ikle,ifabor,eltseg,nseg,
     & nelem,ielm,mesh)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    CALLED AFTER MASKEL HAS BEEN FILLED IN.
!+
!+          - FILLS IN MASKPT (A POINT IS MASKED IF SURROUNDED BY
!+                MASKED ELEMENTS).
!+
!+          - FILLS IN IFAMAS (SIMILAR ARRAY TO IFABOR, BUT
!+                CONSIDERS ANY FACE SEPARATING A MASKED FROM A
!+                NON-MASKED ELEMENT SUCH AS A SOLID BOUNDARY).
!+
!+          - COMPUTES THE NEW COMPATIBLE NORMALS XNEBOR AND
!+                YNEBOR FOR PRISMS.
!
!history  J-M HERVOUET (LNHE)
!+        21/10/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ELTSEG         |-->| SEGMENTS GIVEN PER ELEMENT
!| IELM           |-->| TYPE OF ELEMENT.
!| IFABOR         |-->| ELEMENTS BEHIND THE EDGES OF A TRIANGLE
!|                |   | IF NEGATIVE OR ZERO, THE EDGE IS A LIQUID
!|                |   | BOUNDARY
!| IFAMAS         |<--| LIKE IFABOR BUT WITH MASK
!| IKLE           |-->| CONNECTIVITY TABLE.
!| MASKEL         |-->| MASKING OF ELEMENTS
!|                |   | =1. : NORMAL   =0. : MASKED ELEMENT
!| MASKPT         |-->| MASKING PER POINT.
!|                |   | =1. : NORMAL   =0. : MASKED
!| MESH           |-->| MESH STRUCTURE
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NSEG           |-->| NUMBER OF SEGMENTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_maskto => maskto
!
      USE declarations_special
      IMPLICIT NONE
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER, INTENT(IN)    :: NELEM,IELM,NSEG
      INTEGER, INTENT(IN)    :: IKLE(nelem,3),IFABOR(nelem,3)
      INTEGER, INTENT(IN)    :: ELTSEG(nelem,3)
      INTEGER, INTENT(INOUT) :: IFAMAS(nelem,3)
!
      DOUBLE PRECISION, INTENT(IN)    :: MASKEL(nelem)
      TYPE(bief_obj), INTENT(INOUT)   :: MASKPT
      TYPE(bief_mesh), INTENT(INOUT)  :: MESH
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER IELEM,N,I1,I2,I3
      DOUBLE PRECISION, POINTER, DIMENSION(:) :: WSEG
!
      INTRINSIC max
!
!-----------------------------------------------------------------------
!
      wseg => mesh%MSEG%X%R
!
      CALL os('X=0     ',x=maskpt)
!
      IF(ielm.EQ.11.OR.ielm.EQ.41) THEN
!
! 1) MASKS THE POINTS WHICH DO NOT BELONG TO NON-FROZEN ELEMENTS
!    (THOSE WHICH BELONG TO A 'NORMAL' ELEMENT ARE SET BACK TO 1)
!
        DO ielem = 1,nelem
          i1 = ikle(ielem,1)
          i2 = ikle(ielem,2)
          i3 = ikle(ielem,3)
          maskpt%R(i1) = max(maskpt%R(i1),maskel(ielem))
          maskpt%R(i2) = max(maskpt%R(i2),maskel(ielem))
          maskpt%R(i3) = max(maskpt%R(i3),maskel(ielem))
        ENDDO
!
!       IN PARALLEL MODE FOR INTERFACE POINTS, MAXIMUM RETAINED
!
        IF(ncsize.GT.1) CALL parcom(maskpt,3,mesh)
!
! 2) COPIES IFABOR IN IFAMAS
!
        DO ielem = 1,nelem
          ifamas(ielem,1) = ifabor(ielem,1)
          ifamas(ielem,2) = ifabor(ielem,2)
          ifamas(ielem,3) = ifabor(ielem,3)
        ENDDO
!
! 3) IDENTIFIES THE EDGES OF FROZEN ELEMENTS WITH 0 (LIQUID BOUNDARY)
!    TO STOP THE CHARACTERISTIC CURVES
!
!    USES AN ARRAY DEFINED BY SEGMENT TO COMMUNICATE IN PARALLEL MODE
!
!       WSEG SET TO 1
!
        DO n=1,nseg
          wseg(n)=1.d0
        ENDDO
!
!       THEN WSEG PUT TO 0 FOR DRY ELEMENTS
!
        DO ielem=1,nelem
          IF(maskel(ielem).LT.0.5d0) THEN
            wseg(eltseg(ielem,1))=0.d0
            wseg(eltseg(ielem,2))=0.d0
            wseg(eltseg(ielem,3))=0.d0
          ENDIF
        ENDDO
!
!       IN PARALLEL MODE FOR INTERFACE EDGES, MINIMUM RETAINED
!
        IF(ncsize.GT.1) THEN
          CALL parcom2_seg(wseg,wseg,wseg,nseg,1,4,1,mesh,1,11)
        ENDIF
!
!       WSEG = 0.D0 TRANSLATED INTO IFAMAS = 0
!
        DO ielem=1,nelem
          IF(wseg(eltseg(ielem,1)).LT.0.5d0) ifamas(ielem,1)=0
          IF(wseg(eltseg(ielem,2)).LT.0.5d0) ifamas(ielem,2)=0
          IF(wseg(eltseg(ielem,3)).LT.0.5d0) ifamas(ielem,3)=0
        ENDDO
!
      ELSE
!
        WRITE(lu,1100) ielm
1100    FORMAT(1x,'MASKTO: UNKNOWN TYPE OF ELEMENT :',1i6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END