maskbd.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE maskbd
!                   *****************
!
     &(maskel,zfe,zf,hn,hmin,ikle,ifabor,itra01,nelem,npoin)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    MASKS DRY OR PARTIALLY DRY ELEMENTS.
!code
!+     ALGORITHM:
!+
!+    - AN ELEMENT IS MASKED IF THE BOTTOM ELEVATION ZFE IS HIGHER THAN
!+      THE FREE SURFACE ELEVATION AT ITS BARYCENTRE
!+
!+    - ANY ELEMENT WHICH BOTTOM ELEVATION ZFE IS HIGHER THAN THE
!+      ELEVATION ZFE OF A MASKED NEIGHBOUR IS IN TURN MASKED
!+
!+      WHEN TURNING AROUND A NODE, FUNCTION ZFE ONLY HAS A MIN AND
!+      A MAX (SEE TOPOGR). THE SECOND PHASE OF THE ALGORITHM THUS
!+      ENSURES THAT NO 2 PARTS OF THE DOMAIN ARE ONLY CONNECTED BY
!+      1 VERTEX. THIS TREATMENT ALSO PREVENTS INOPPORTUNE MASKING-
!+      DEMASKING, IN PARTICULAR IN TIDAL FLAT AREAS.
!+
!+
!+      DISADVANTAGES:
!+
!+      THIS ALGORITHM ASSUMES THAT THE FREE SURFACE IS QUASI HORIZONTAL.
!+      IT IS WELL SUITED TO STUDY EVOLUTIONS DUE TO TIDAL EFFECTS, BUT
!+      NOT TO STUDY DAM BREAKS.
!
!history  J-M JANIN (LNH)
!+        11/08/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| HMIN           |-->| MINIMUM VALUE OF DEPTH
!| HN             |-->| WATER DEPTH AT TIME N
!| IFABOR         |-->| ELEMENTS BEHIND THE EDGES OF A TRIANGLE
!|                |   | IF NEGATIVE OR ZERO, THE EDGE IS A LIQUID
!|                |   | BOUNDARY
!| IKLE           |-->| CONNECTIVITY TABLE.
!| ITRA01         |-->| WORK ARRAY OF INTEGERS
!| MASKEL         |<--| MASKING OF ELEMENTS
!|                |   | =1. : NORMAL   =0. : MASKED ELEMENT
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!| ZF             |-->| ELEVATION OF BOTTOM
!| ZFE            |-->| ELEVATION OF BOTTOM, PER ELEMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NELEM,NPOIN
      INTEGER, INTENT(IN)             :: IKLE(nelem,3),IFABOR(nelem,3)
      INTEGER, INTENT(INOUT)          :: ITRA01(nelem)
      DOUBLE PRECISION, INTENT(IN)    :: ZFE(nelem),ZF(npoin),HN(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: HMIN
      DOUBLE PRECISION, INTENT(INOUT) :: MASKEL(nelem)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,I1,I2,I3,N
!
      DOUBLE PRECISION ZSE
!
      LOGICAL FLAG
!
      DOUBLE PRECISION, PARAMETER :: EPSILO = 1.d-6
!
!-----------------------------------------------------------------------
!
      flag = .false.
!
      DO ielem = 1,nelem
        i1 = ikle(ielem,1)
        i2 = ikle(ielem,2)
        i3 = ikle(ielem,3)
        zse = (zf(i1)+hn(i1)+zf(i2)+hn(i2)+zf(i3)+hn(i3))/3.d0
        IF (zfe(ielem)+hmin+epsilo.GT.zse) THEN
          flag = .true.
          maskel(ielem) = 0.d0
        ENDIF
      ENDDO ! IELEM
!
20    CONTINUE
!
      IF (flag) THEN
!
        flag = .false.
        DO ielem = 1,nelem
!
          itra01(ielem) = 0
          IF (maskel(ielem).GT.0.5d0) THEN
!
            n=ifabor(ielem,1)
            IF (n.GT.0) THEN
              IF (maskel(n).LT.0.5d0.AND.zfe(ielem).GT.
     &            zfe(n)-epsilo) itra01(ielem) = 1
            ENDIF
            n=ifabor(ielem,2)
            IF (n.GT.0) THEN
              IF (maskel(n).LT.0.5d0.AND.zfe(ielem).GT.
     &            zfe(n)-epsilo) itra01(ielem) = 1
            ENDIF
            n=ifabor(ielem,3)
            IF (n.GT.0) THEN
              IF (maskel(n).LT.0.5d0.AND.zfe(ielem).GT.
     &            zfe(n)-epsilo) itra01(ielem) = 1
            ENDIF
!
          ENDIF
!
        ENDDO ! IELEM
!
        DO ielem = 1,nelem
          IF (itra01(ielem).EQ.1) THEN
            flag = .true.
            maskel(ielem) = 0.d0
          ENDIF
        ENDDO ! IELEM
!
        GOTO 20
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END