loglu.f

Go to the documentation of this file.

!                   **********************
                    LOGICAL FUNCTION loglu
!                   **********************
!
     &( icol , ligne )
!
!***********************************************************************
! DAMOCLES   V6P3                                   21/08/2010
!***********************************************************************
!
!brief    DECODES A LOGICAL VALUE, FROM COLUMN ICOL+1 OF THE LINE.
!+             IF THE STRING IS NOT COMPLETE, GOES TO THE NEXT LINE
!+             IF NEED BE.
!+             MOVES THE POINTER ICOL TO THE LAST DECODED CHARACTER.
!+             OR TO ICOL=0 IF THE NEXT LINE WAS READ.
!
!warning  ACCEPTED VALUES ARE (UPPER OR LOWER CASE):
!+            VRAI OUI TRUE  YES .TRUE.  1
!+            FAUX NON FALSE NO  .FALSE. 0
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J.M. HERVOUET (EDF R&D, LNHE)
!+        11/03/2013
!+        V6P3
!+   Slight modification for avoiding to read beyong the actual size
!+   of LIGNE.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ICOL           |<->| POSITION COURANTE DU POINTEUR DANS LA LIGNE
!| LIGNE          |<->| LIGNE EN COURS DE DECODAGE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_damocles
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER,       INTENT(INOUT) :: ICOL
      CHARACTER(LEN=*), INTENT(INOUT) :: LIGNE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER  NEXT,PRECAR
      EXTERNAL next,precar
!
!-----------------------------------------------------------------------
!
      INTEGER       I1,I2
      CHARACTER(LEN=1)   TABUL
      CHARACTER(LEN=7)   L
      CHARACTER(LEN=72)  LIGNE2
      LOGICAL       LUFIC,LISUIV
!
!-----------------------------------------------------------------------
!
      INTRINSIC char
!
!***********************************************************************
!                                    RCS AND SCCS MARKING
!
!***********************************************************************
!
      lufic  = .false.
      lisuiv = .false.
      ligne2 = ' '
      tabul  = char(9)
!
      i1 = next( icol+1 , ligne )
      i2 = precar(i1,ligne,' ',';',tabul)
!
!     CASE WHERE WE MIGHT HAVE TO READ THE FOLLOWING LINE
!
      IF(i2.GT.longli.AND.i1+6.GT.longli) THEN
        lufic=.true.
        READ(nfic,end=900,err=998,fmt='(A)') ligne2
        IF(i1.LE.longli) THEN
          l(1:7)=ligne(i1:longli)//ligne2(1:(7-(longli-i1+1)))
        ELSE
          l(1:7)=ligne2(1:7)
        ENDIF
        i2 = 0
        i2 = precar(i2+1,ligne2,' ',';',tabul)
      ELSEIF(i1+6.GT.longli) THEN
        l(2:7) = '      '
        l(1:longli-i1+1)= ligne(i1:longli)
      ELSE
        l(1:7) = ligne(i1:i1+6)
      ENDIF
      CALL majus(l)
      GO TO 910
!
 900  CONTINUE
      retour = .true.
!
 910  CONTINUE
!
! ORDERED IN THE MOST PROBABLE ORDER: NON OUI NO YES 0 1 ...
!
      IF(l(1:3).EQ.'NON') THEN
        loglu = .false.
        icol = i1 + 2
      ELSEIF(l(1:2).EQ.'NO') THEN
        loglu = .false.
        icol = i1 + 1
      ELSEIF(l(1:3).EQ.'OUI' ) THEN
        loglu = .true.
        icol = i1 + 2
      ELSEIF(l(1:3).EQ.'YES' ) THEN
        loglu = .true.
        icol = i1 + 2
      ELSEIF(l(1:1).EQ.'0') THEN
        loglu = .false.
        icol = i1
      ELSEIF(l(1:1).EQ.'1') THEN
        loglu = .true.
        icol = i1
      ELSEIF(l(1:7).EQ.'.FALSE.' ) THEN
        loglu = .false.
        icol = i1 + 6
      ELSEIF(l(1:5).EQ.'FALSE' ) THEN
        loglu = .false.
        icol = i1 + 4
      ELSEIF(l(1:4).EQ.'FAUX') THEN
        loglu = .false.
        icol = i1 + 3
      ELSEIF(l(1:6).EQ.'.TRUE.' ) THEN
        loglu = .true.
        icol = i1 + 5
      ELSEIF(l(1:4).EQ.'TRUE' ) THEN
        loglu = .true.
        icol = i1 + 3
      ELSEIF(l(1:4).EQ.'VRAI' ) THEN
        loglu = .true.
        icol = i1 + 3
      ELSE
!
!       ERROR: NOT A LOGICAL VALUE
!
        erreur = .true.
        WRITE(lu,'(1X,A)') ligne(1:longli)
        IF(lufic) WRITE(lu,'(1X,A)') ligne2(1:longli)
        WRITE(lu,*) ' '
        WRITE(lu,'(1X,A6,I4,A)') 'LOGLU (UTILE) : LINE: ',nlign,
     &                           ' WRONG LOGICAL VALUE'
        loglu = .false.
        GO TO 1000
!
      ENDIF
!
!       //// UPDATES THE POINTER ////
!
      IF (lufic) THEN
        nlign = nlign + 1
        ligne = ligne2
        IF(icol.GT.longli) lisuiv = .true.
        IF(lisuiv) THEN
          icol = i2-1
        ELSE
          icol = 0
        ENDIF
      ELSE
        icol = i2 - 1
      ENDIF
!
1000  CONTINUE
!
!-----------------------------------------------------------------------
!
      RETURN
!
998   CONTINUE
      WRITE(lu,1999) nfic,nlign+1
1999  FORMAT(1x,'LOGICAL UNIT ',1i2,'   ERROR LINE ',1i6)
      retour = .true.
!
!-----------------------------------------------------------------------
!
      RETURN
      END