limwac.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE limwac
!                   *****************
!
     &(f     , fbor  , nptfr , ndire , nf   ,  npoin2,
     & kent  , prive , npriv , imp_file)
!
!***********************************************************************
! TOMAWAC   V7P3                                   23/02/2017
!***********************************************************************
!
!brief    BOUNDARY CONDITIONS.
!
!warning  BY DEFAULT, THE BOUNDARY CONDITIONS SPECIFIED IN THE FILE
!+            DYNAM ARE DUPLICATED ON ALL THE DIRECTIONS AND FREQUENCIES
!
!history  F. MARCOS (LNH)
!+        01/02/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        20/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!history  E. GAGNAIRE-RENOU & J.-M. HERVOUET (EDF R&D, LNHE)
!+        12/03/2013
!+        V6P3
!+   A line IF(LIMSPE.EQ.0...) RETURN removed.
!
!history  A. JOLY (EDF R&D, LNHE)
!+        23/02/2017
!+        V7P3
!+   SPECTRA READ FROM AN EXTERNAL MESH CAN NOW BE IMPOSED ON THE
!+   OPEN BOUNDARIES.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| APHILL         |-->| BOUNDARY PHILLIPS CONSTANT
!| AT             |-->| COMPUTATION TIME
!| BOUNDARY_COLOUR|-->| COLOUR OF BOUNDARY POINT (DEFAULT: ITS RANK)
!| DDC            |-->| DATE OF COMPUTATION BEGINNING
!| DEPTH          |-->| WATER DEPTH
!| F              |-->| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!| FBOR           |<->| SPECTRAL VARIANCE DENSITY AT THE BOUNDARIES
!| FETCHL         |-->| BOUNDARY MEAN FETCH VALUE
!| FPICL          |-->| BOUNDARY PEAK FREQUENCY
!| FPMAXL         |-->| BOUNDARY MAXIMUM PEAK FREQUENCY
!| FRA            |<--| DIRECTIONAL SPREADING FUNCTION VALUES
!| FRABL          |-->| BOUNDARY ANGULAR DISTRIBUTION FUNCTION
!| FREQ           |-->| DISCRETIZED FREQUENCIES
!| GAMMAL         |-->| BOUNDARY PEAK FACTOR
!| GRAVIT         |-->| GRAVITY ACCELERATION
!| HM0L           |-->| BOUNDARY SIGNIFICANT WAVE HEIGHT
!| IMP_FILE       |-->| MESH FILE WITH THE IMPOSED SPECTRA
!| KENT           |-->| B.C.: A SPECTRUM IS PRESCRIBED AT THE BOUNDARY
!| LIFBOR         |-->| TYPE OF BOUNDARY CONDITION ON F
!| LIMSPE         |-->| TYPE OF BOUNDARY DIRECTIONAL SPECTRUM
!| LT             |-->| NUMBER OF THE TIME STEP CURRENTLY SOLVED
!| NBI1           |-->| LOGICAL UNIT NUMBER OF THE USER BINARY FILE
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NF             |-->| NUMBER OF FREQUENCIES
!| NFO1           |-->| LOGICAL UNIT NUMBER OF THE USER FORMATTED FILE
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| NPRIV          |-->| NUMBER OF PRIVATE ARRAYS
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| PRIVE          |-->| USER WORK TABLE
!| SIGMAL         |-->| BOUNDARY SPECTRUM VALUE OF SIGMA-A
!| SIGMBL         |-->| BOUNDARY SPECTRUM VALUE OF SIGMA-B
!| SPEC           |<--| VARIANCE DENSITY FREQUENCY SPECTRUM
!| SPEULI         |-->| INDICATES IF B.C. SPECTRUM IS MODIFIED BY USER
!| SPRE1L         |-->| BOUNDARY DIRECTIONAL SPREAD 1
!| SPRE2L         |-->| BOUNDARY DIRECTIONAL SPREAD 2
!| TETA1L         |-->| BOUNDARY MAIN DIRECTION 1
!| TETA2L         |-->| BOUNDARY MAIN DIRECTION 2
!| UV, VV         |-->| WIND VELOCITIES AT THE MESH POINTS
!| VENSTA         |-->| INDICATES IF THE WIND IS STATIONARY
!| VENT           |-->| INDICATES IF WIND IS TAKEN INTO ACCOUNT
!| X              |-->| ABSCISSAE OF POINTS IN THE MESH
!| XLAMDL         |-->| BOUNDARY WEIGHTING FACTOR FOR ANGULAR
!|                |   | DISTRIBUTION FUNCTION
!| Y              |-->| ORDINATES OF POINTS IN THE MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_tomawac, ex_limwac => limwac
      USE declarations_tomawac, ONLY : uv2d,vv2d,prof,fb_cte,npb,
     &     limspe, fpmaxl, fetchl, sigmal, sigmbl, gammal, fpicl ,
     &     hm0l  , aphill, teta1l, spre1l, teta2l, spre2l, xlamdl,
     &     speuli, vent  , vensta, depth , spec  , fra   , frabl ,
     &     at    , lt    , uv    , vv    , lifbor, nbor

      USE declarations_special
      USE bnd_spectra
      USE bief_def, ONLY : bief_file
      IMPLICIT NONE
!
!
      INTEGER, INTENT(IN)            :: NPTFR,NDIRE,NF,NPOIN2,NPRIV
      INTEGER, INTENT(IN)            :: KENT
      DOUBLE PRECISION, INTENT(IN)   :: PRIVE(npoin2,npriv)
      TYPE(bief_file), INTENT(IN)    :: IMP_FILE
      DOUBLE PRECISION, INTENT(INOUT):: F(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(INOUT):: FBOR(nptfr,ndire,nf)
!
      INTEGER IFF,IDIRE,IPTFR
!
      LOGICAL FLAG
!
!
!***********************************************************************
!
!     MODIFIES THE TYPE OF BOUNDARY CONDITION (OPTIONAL)
!
!     CAN BE CODED BY THE USER (SPEULI=.TRUE.)
!
!     LIFBOR(IPTFR)=KENT OR KSORT
!
      flag=.false.
      IF (vent .AND. (limspe.EQ.1 .OR. limspe.EQ.2 .OR. limspe.EQ.3
     & .OR. limspe.EQ.5)) flag=.true.
!
!     THE FIRST TIME, ALLOCATES MEMORY FOR THE USEFUL ARRAYS
!     ---------------------------------------------------------------
!
      IF(lt.LT.1) THEN
        npb=1
        IF(flag) THEN
          ALLOCATE(uv2d(1:nptfr),vv2d(1:nptfr))
          npb=nptfr
        ENDIF
        IF(limspe.EQ.7 .OR. speuli) THEN
          IF (.NOT.ALLOCATED(prof)) ALLOCATE(prof(1:nptfr))
          npb=nptfr
        ENDIF
        IF(npb.EQ.1) THEN
          IF (.NOT.ALLOCATED(fb_cte)) ALLOCATE(fb_cte(1:ndire,1:nf))
        ENDIF
      ENDIF
      IF (.NOT.ALLOCATED(uv2d)) ALLOCATE(uv2d(nptfr))
!     MEMCHECK DO NOT LIKE FOR DEFERL_BJ78
      IF (.NOT.ALLOCATED(vv2d)) ALLOCATE(vv2d(nptfr))
      IF (.NOT.ALLOCATED(prof)) ALLOCATE(prof(nptfr))
      IF (.NOT.ALLOCATED(fb_cte)) ALLOCATE(fb_cte(1:ndire,1:nf))
!
!     THE FIRST TIME (AND POSSIBLY SUBSEQUENTLY IF THE WIND IS NOT
!     STATIONARY AND IF THE BOUNDARY SPECTRUM DEPENDS ON IT),
!     COMPUTES THE BOUNDARY SPECTRUM
!
      IF(lt.LT.1 .OR. (.NOT.vensta.AND.flag) .OR. speuli .OR.
     &   (imp_file%NAME(1:1).NE.' ')) THEN
        IF(flag) THEN
          DO iptfr=1,nptfr
            uv2d(iptfr)=uv(nbor(iptfr))
            vv2d(iptfr)=vv(nbor(iptfr))
          ENDDO
        ENDIF
        IF(limspe.EQ.7 .OR. speuli) THEN
          DO iptfr=1,nptfr
            prof(iptfr)=depth(nbor(iptfr))
          ENDDO
        ENDIF
!
!       WHEN NPB=1 FBOR ONLY FILLED FOR FIRST POINT
!
!       SPECTRUM ON BOUNDARIES
!
        IF(npb.EQ.nptfr) THEN
          CALL speini
     &(   fbor  ,spec  ,fra   ,uv2d  ,vv2d  ,fpmaxl,fetchl,
     &    sigmal,sigmbl,gammal,fpicl ,hm0l  ,aphill,teta1l,
     &    spre1l,teta2l,spre2l,xlamdl,npb   ,ndire ,nf    ,
     &    limspe,prof  ,frabl )
        ELSE
          CALL speini
     &(   fb_cte,spec  ,fra   ,uv2d  ,vv2d  ,fpmaxl,fetchl,
     &    sigmal,sigmbl,gammal,fpicl ,hm0l  ,aphill,teta1l,
     &    spre1l,teta2l,spre2l,xlamdl,npb   ,ndire ,nf    ,
     &    limspe,prof  ,frabl )
        ENDIF
!
!       IF THERE IS A MESHED FILE WITH THE BOUNDARY SPECTRA
!       THEY NEED TO BE IMPOSED
!
        IF(imp_file%NAME(1:1).NE.' ')THEN
          CALL impose_bnd_spectra(imp_file,lt,at,fbor,nptfr,ndire,nf)
        ENDIF
      ENDIF
!
!     ===========================================================
!     TO BE MODIFIED BY USER - RESU CAN BE CHANGED
!     ===========================================================
!
      IF(speuli) THEN
        CALL user_limwac
     &(f     , fbor  , nptfr , ndire , nf    , npoin2,
     & kent  , prive , npriv ,  imp_file)
!
!     ===========================================================
!     END OF USER MODIFICATIONS
!     ===========================================================
!
      ELSE
!
!     -----------------------------------------------------------------
!     DUPLICATES THE BOUNDARY CONDITION FROM DYNAM ON ALL THE
!     DIRECTIONS AND FREQUENCIES, IF LIQUID BOUNDARY
!     -----------------------------------------------------------------
!
        IF(flag.OR.limspe.EQ.7.OR.
     &   (imp_file%NAME(1:1).NE.' ')) THEN
          DO iptfr=1,nptfr
            IF(lifbor(iptfr).EQ.kent) THEN
              DO iff=1,nf
                DO idire=1, ndire
                  f(nbor(iptfr),idire,iff)=fbor(iptfr,idire,iff)
                ENDDO
              ENDDO
            ENDIF
          ENDDO
        ELSE
          DO iptfr=1,nptfr
            IF(lifbor(iptfr).EQ.kent) THEN
              DO iff=1,nf
                DO idire=1, ndire
                  f(nbor(iptfr),idire,iff)=fb_cte(idire,iff)
                ENDDO
              ENDDO
            ENDIF
          ENDDO
        ENDIF
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END