limite.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE limite
!                       *****************
     &( f     , freq  , npoin2, ndire , nf    )
!
!***********************************************************************
! TOMAWAC   V7P0                                 30/07/2014
!***********************************************************************
!
!brief     EQUILIBRIUM RANGE SPECTRUM OF PHILLIPS APPLIED AS AN UPPER
!+         LIMIT FOR THE SPECTRUM : E(F)=ALFA*G**2/(2.PI)**4 F**(-5)
!
!
!history  E. GAGNAIRE-RENOU AND M.BENOIT (EDF/LNHE)
!+        09/2014
!+        V7P0
!+        NEW SUBROUTINE CREATED / IMPLEMENTED
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!| F              |-->| DIRECTIONAL SPECTRUM
!| FREQ           |-->| DISCRETIZED FREQUENCIES
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!
!
      USE declarations_tomawac, ONLY : deupi,gravit
!
      USE declarations_special
      USE interface_tomawac, ex_limite => limite
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NF,NDIRE,NPOIN2
      DOUBLE PRECISION, INTENT(IN)    :: FREQ(nf)
      DOUBLE PRECISION, INTENT(INOUT) :: F(npoin2,ndire,nf)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER          IP    , JP    , JF
      DOUBLE PRECISION EDEF  , COEF  , DTETAR, EMAX  , REDUC
!
!-----------------------------------------------------------------------
!
      dtetar=deupi/dble(ndire)
      coef=0.0081d0*gravit**2/deupi**4
!
      DO ip=1, npoin2
        DO jf=1, nf
          edef=0.0d0
          DO jp=1, ndire
            edef=edef+f(ip,jp,jf)
          ENDDO
          edef=edef*dtetar
          emax=coef/freq(jf)**5
          IF (edef.GT.emax) THEN
            reduc=emax/edef
            DO jp=1, ndire
              f(ip,jp,jf)=f(ip,jp,jf)*reduc
            ENDDO
          ENDIF
        ENDDO
      ENDDO
!
      RETURN
      END