lecsui.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE lecsui
!                   *****************
!
     &(f,ndire,nf,npoin2,vent, couran,npre,fformat,maree,tra01)
!
!***********************************************************************
! TOMAWAC   V7P1
!***********************************************************************
!
!brief    READS THE DATA FOR A CONTINUATION OF COMPUTATION.
!
!warning  Parameters MAREE, COURAN or VENT must not be changed between
!+        2 runs. This would require an extra implementation consisting
!+        of checking the names of variables.
!
!history  F MARCOS (LNH)
!+        01/02/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        20/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!history  J-M HERVOUET (EDF - LNHE)
!+        26/11/2012
!+        V6P3
!+   Correction of bugs and double precision. Changing file format
!+   for domain decomposition.
!
!history Y AUDOUIN (LNHE)
!+       25/05/2015
!+       V7P0
!+       Modification to comply with the hermes module
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COURAN         |-->| LOGICAL INDICATING IF THERE IS A CURRENT
!| F              |<--| DIRECTIONAL SPECTRUM
!| MAREE          |-->| LOGICAL INDICATING CONSIDERATION OF TIDE
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| NPRE           |-->| LOIGCAL UNIT NUMBER OF PREVIOUS COMPUTATION FILE
!| TRA01          |<--| DOUBLE PRECISION WORK TABLE OF SIZE NPOIN2*NDIRE
!| VENT           |-->| LOGICAL INDICATING IF THERE IS A WIND
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE interface_hermes
!
      USE declarations_special
      USE declarations_tomawac, ONLY : namveb, namvef,
     & at, tv1, tv2, tc1, tc2, tm1, tm2, zm1 ,zm2, depth, dzhdt,
     & uc, vc, uv, vv,  uv1, vv1, uv2, vv2, uc1, vc1, uc2, vc2
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NPRE,NF,NDIRE,NPOIN2
      DOUBLE PRECISION, INTENT(INOUT) :: F(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(INOUT) :: TRA01(npoin2*ndire)
      LOGICAL, INTENT(IN)             :: COURAN,VENT,MAREE
      CHARACTER(LEN=8), INTENT(IN)    :: FFORMAT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,ISTAT,NPOIN,NVAR,NPL
      INTEGER NELEM, NPTFR, NPTIR2, NDP, TYP_ELEM
      INTEGER NTIMESTEP, X_ORIG, Y_ORIG
      CHARACTER(LEN=80) CAR
!
      INTEGER NVA3
      CHARACTER(LEN=16),ALLOCATABLE :: VAR_NAME(:),VAR_UNIT(:)
!
!***********************************************************************
!
      CALL read_mesh_info(fformat,npre,car,nvar,npoin,typ_elem,
     &                    nelem,nptfr,nptir2,ndp,npl,x_orig,y_orig)
!
      IF(npl.NE.ndire) THEN
        WRITE(lu,*) 'LECSUI: BAD NUMBER OF PLANES IN THE PREVIOUS'
        WRITE(lu,*) '        COMPUTATION FILE : ',npl,' FOUND'
        WRITE(lu,*) '                           ',ndire,' EXPECTED'
        CALL plante(1)
        stop
      ENDIF
!
      IF(npoin.NE.ndire*npoin2) THEN
        WRITE(lu,*)'LECSUI: BAD NUMBER OF POINTS IN THE PREVIOUS'
        WRITE(lu,*)'        COMPUTATION FILE : ',npoin,' FOUND'
        WRITE(lu,*)'                           ',npoin2,' EXPECTED'
        CALL plante(1)
        stop
      ENDIF
!
      IF(couran.OR.vent) THEN
        i=nvar-2
      ELSE
        i=nvar-1
      ENDIF
!
      IF(i.NE.nf) THEN
        WRITE(lu,*) 'LECSUI : BAD NUMBER OF FREQUENCIES'
        WRITE(lu,*) '         IN THE PREVIOUS'
        WRITE(lu,*) '         COMPUTATION FILE : ',i,' FOUND'
        WRITE(lu,*) '                            ',nf,' EXPECTED'
        CALL plante(1)
        stop
      ENDIF
!
!     PRINTS TITLE
!
      WRITE(lu,*) ' '
      WRITE(lu,*) '**** FOLLOWING COMPUTATION ****'
      WRITE(lu,*) ' '
      WRITE(lu,*) 'TITLE OF THE PREVIOUS COMPUTATION :',car
!
!     READS TIME
!
      CALL get_data_ntimestep(fformat,npre,ntimestep,istat)
      CALL check_call(istat,'LECSUI:GET_DATA_NTIMESTEP')
      CALL get_data_time(fformat,npre,ntimestep-1,at,istat)
      CALL check_call(istat,'LECSUI:GET_DATA_TIME')
!
      WRITE(lu,*) '- COMPUTATIONAL RESUMPTION AT TIME ',at
!
!
! Get the number of variables
      CALL get_data_nvar(fformat,npre,nva3,istat)
      CALL check_call(istat,'LECSUI:GET_DATA_NVAR')

      ALLOCATE(var_name(nva3),stat=istat)
      CALL check_allocate(istat,'LECSUI:VAR_NAME')
      ALLOCATE(var_unit(nva3),stat=istat)
      CALL check_allocate(istat,'LECSUI:VAR_UNIT')
!
      CALL get_data_var_list(fformat,npre,nva3,var_name,var_unit,istat)
      CALL check_call(istat,'LECSUI:GET_DATA_VAR_LIST')
!READS F
!

      DO i=1,nf
        CALL find_variable(fformat,npre,var_name(i),f(1,1,i),npoin,
     &                 istat,record=-1)
        CALL check_call(istat,'LECSUI:FIND_VARIABLE')
      ENDDO
!
!     READS DEPTH (ALWAYS WRITTEN, EVEN IF NOT RELEVANT)
!
      IF(maree) THEN
!        CALL FIND_VARIABLE(FFORMAT,NPRE,VAR_NAME(I),F(1,1,I),NPOIN2,
        CALL find_variable(fformat,npre,var_name(nf+1),tra01,npoin,
     &                 istat,record=-1)
        CALL ov('X=Y     ', x=depth, y=tra01(1:npoin2), dim1=npoin2)

!       SETS TRIPLETS U,V,TV1 AND 2 TO UV,VV,AT
        tm1=at
        tm2=at
        CALL ov('X=Y     ', x=zm1, y=depth, dim1=npoin2)
        CALL ov('X=Y     ', x=zm2, y=depth, dim1=npoin2)
        CALL ov('X=C     ', x=dzhdt, c=0.d0, dim1=npoin2)
      ELSE
        CALL find_variable(fformat,npre,var_name(nf+1),tra01,npoin,
     &                 istat,record=-1)
        CALL check_call(istat,'LECSUI:FIND_VARIABLE')
      ENDIF
!
!     READS UC,VC,UV,VV IF HAS TO
!
      IF(couran.OR.vent) THEN
        IF(vent) THEN
          CALL find_variable(fformat,npre,var_name(nf+2),tra01,4*npoin2,
     &                   istat,record=-1)
          CALL check_call(istat,'LECSUI:FIND_VARIABLE')
        ELSE
          CALL find_variable(fformat,npre,var_name(nf+2),tra01,2*npoin2,
     &                   istat,record=-1)
          CALL check_call(istat,'LECSUI:FIND_VARIABLE')
        ENDIF
      ENDIF
!
      IF(couran) THEN
        CALL ov('X=Y     ', x=uc, y=tra01(       1:  npoin2),
     &          dim1=npoin2)
        CALL ov('X=Y     ', x=vc, y=tra01(npoin2+1:2*npoin2),
     &          dim1=npoin2)
!       SETS TRIPLETS U,V,TV1 AND 2 TO UV,VV,AT
        tc1=at
        tc2=at
        CALL ov('X=Y     ', x=uc1, y=uc, dim1=npoin2)
        CALL ov('X=Y     ', x=uc2, y=uc, dim1=npoin2)
        CALL ov('X=Y     ', x=vc1, y=vc, dim1=npoin2)
        CALL ov('X=Y     ', x=vc2, y=vc, dim1=npoin2)
      ENDIF
!
      IF(vent) THEN
        CALL ov('X=Y     ', x=uv, y=tra01(2*npoin2+1:3*npoin2),
     &          dim1=npoin2)
        CALL ov('X=Y     ', x=vv, y=tra01(3*npoin2+1:4*npoin2),
     &          dim1=npoin2)
!       SETS TRIPLETS U,V,TV1 AND 2 TO UV,VV,AT
        tv1=at
        tv2=at
        IF (namveb.NE.' '.OR.namvef.NE.' ') THEN
          CALL ov('X=Y     ', x=uv1, y=uv, dim1=npoin2)
          CALL ov('X=Y     ', x=uv2, y=uv, dim1=npoin2)
          CALL ov('X=Y     ', x=vv1, y=vv, dim1=npoin2)
          CALL ov('X=Y     ', x=vv2, y=vv, dim1=npoin2)
        ENDIF
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END