lecsim.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE lecsim
!                       *****************
!
     &( x , y , ikle , ncolor , titre , nop5 , ngeo )
!
!***********************************************************************
! PROGICIEL : STBTEL V5.2         25/02/92    J-C GALLAND  (LNH)
!***********************************************************************
!
!     FONCTION  :  LECTURE DU FICHIER DE LA GEOMETRIE CREE PAR SIMAIL
!
!-----------------------------------------------------------------------
!                             ARGUMENTS
! .________________.____.______________________________________________
! |      NOM       |MODE|                   ROLE
! |________________|____|______________________________________________
! |   X,Y          |<-- | COORDONNEES DU MAILLAGE .
! |   X1,Y1        |<-- | COORDONNEES DU MAILLAGE LUES EN SIMPLE
! |                |    | PRECISION DANS LE FICHIER SIMAIL
! |   IKLE         |<-- | LISTE DES POINTS DE CHAQUE ELEMENT
! |   NCOLOR       |<-- | TABLEAU DES COULEURS DES POINTS DU MAILLAGE
! |   TITRE        |<-- | TITRE DU MAILLAGE
! |   NOP5         | -->| TABLEAU DE TRAVAIL POUR LA LECTURE DE LA SD
! |________________|____|______________________________________________
! | COMMON:        |    |
! |  GEO:          |    |
! |    MESH        | -->| TYPE DES ELEMENTS DU MAILLAGE
! |    NDP         | -->| NOMBRE DE NOEUDS PAR ELEMENTS
! |    NPOIN       | -->| NOMBRE TOTAL DE NOEUDS DU MAILLAGE
! |    NELEM       | -->| NOMBRE TOTAL D'ELEMENTS DU MAILLAGE
! |    NPMAX       | -->| DIMENSION EFFECTIVE DES TABLEAUX X ET Y
! |                |    | (NPMAX = NPOIN + 0.1*NELEM)
! |    NELMAX      | -->| DIMENSION EFFECTIVE DES TABLEAUX CONCERNANT
! |                |    | LES ELEMENTS (NELMAX = NELEM + 0.2*NELEM)
! |  FICH:         |    |
! |    NRES        | -->| NUMERO DU CANAL DU FICHIER DE SERAFIN
! |    NGEO       | -->| NUMERO DU CANAL DU FICHIER MAILLEUR
! |    NLIM      | -->| NUMERO DU CANAL DU FICHIER DYNAM DE TELEMAC
! |    NFO1      |--> | NUMERO DU CANAL DU FICHIER TRIANGLE TRIGRID
! |________________|____|______________________________________________
! MODE : -->(DONNEE NON MODIFIEE), <--(RESULTAT), <-->(DONNEE MODIFIEE)
!----------------------------------------------------------------------
! APPELE PAR : STBTEL
! APPEL DE : -
!***********************************************************************
!
!    LISTE DES ENREGISTREMENTS DU FICHIER GEOMETRIQUE:
!             (DOCUMENTION: NOTICE SIMAIL)
!
!***********************************************************************
!
      USE declarations_special
      USE declarations_stbtel, ONLY: nelem,mesh,npoin,nelmax
      IMPLICIT NONE
!
      DOUBLE PRECISION, INTENT(INOUT) :: X(*) , Y(*)
      INTEGER, INTENT(INOUT) :: IKLE(nelmax,4) , NCOLOR(*)
      CHARACTER(LEN=80), INTENT(INOUT) :: TITRE
      INTEGER, INTENT(INOUT) :: NOP5(*)
      INTEGER, INTENT(IN) :: NGEO
!
      INTEGER ERR
      INTEGER I,J,K
      INTEGER LONG, NTASD
      INTEGER NCGE, NMAE , NDSDE , NNO , NCOPNP ,NPO
      INTEGER INING, NBEGM , INDIC
!
      REAL, DIMENSION(:), ALLOCATABLE :: X1,Y1
!
!
      INTRINSIC dble
!
!-----------------------------------------------------------------------
!
      ALLOCATE(x1(npoin),stat=err)
      ALLOCATE(y1(npoin),stat=err)
!
      IF(err.NE.0) THEN
        WRITE(lu,8000) err
8000    FORMAT(1x,'LECSIM: ERROR DURING ALLOCATION OF MEMORY: ',/,1x,
     &            'ERROR CODE: ',1i6)
      ENDIF
!
!=======================================================================
!   INITIALISATION
!=======================================================================
!
      rewind ngeo
!
      DO i=1,npoin
        x(i) = 9999999.d0
        y(i) = 9999999.d0
        ncolor(i) = 99999
      ENDDO
!
!=======================================================================
! LECTURE SEQUENTIELLE DU FICHIER (1ER ENRGISTREMENT DE LA SD)
! POUR LES LECTURES BIDON, ON UTILISE NOP5
!=======================================================================
!
      READ(ngeo,err=110,end=120) long,(nop5(i),i=1,long)
!
!=======================================================================
! LECTURE SEQUENTIELLE DU FICHIER (TABLEAU NOP0) . LECTURE DU TITRE
! POUR LES LECTURES BIDON, ON UTILISE NOP5
!=======================================================================
!
      READ(ngeo,err=110,end=120) long,titre,(nop5(i),i=1,11),ntasd
!
!=======================================================================
! LECTURE SEQUENTIELLE DU FICHIER (TABLEAUX NOP1 ET ASSOCIES)
! POUR LES LECTURES BIDON, ON UTILISE NOP5
!=======================================================================
!
      IF (ntasd.GT.0) THEN
        READ(ngeo,err=110,end=120) long,(nop5(i),i=1,long)
        DO i=1,ntasd
          READ(ngeo,err=110,end=120) long,(nop5(j),j=1,long)
        ENDDO
      ENDIF
!
!=======================================================================
! LECTURE SEQUENTIELLE DU FICHIER (TABLEAU NOP2)
! POUR LES LECTURES BIDON, ON UTILISE NOP5
!=======================================================================
!
      READ(ngeo,err=110,end=120) long,(nop5(i),i=1,long)
      ncopnp = nop5(4)
      nbegm  = nop5(25)
!
!=======================================================================
! LECTURE SEQUENTIELLE DU FICHIER (TABLEAU NOP3)
! POUR LES LECTURES BIDON, ON UTILISE NOP5
!=======================================================================
!
      IF (nbegm.NE.0) THEN
        READ(ngeo,err=110,end=120) long,(nop5(i),i=1,long)
      ENDIF
!
!=======================================================================
! LECTURE SEQUENTIELLE DES COORDONNEES DES NOEUDS (TABLEAU NOP4)
!=======================================================================
!
      READ(ngeo,err=110,end=120) long,(x1(i),y1(i),i=1,npoin)
      DO i=1,npoin
        x(i) = dble(x1(i))
        y(i) = dble(y1(i))
      ENDDO
!
!=======================================================================
! LECTURE SEQUENTIELLE DES IKLE (TABLEAU NOP5)
! POUR LES LECTURE BIDON, ON UTILISE NOP5 ET LONG
!=======================================================================
!
      indic = 0
      READ(ngeo,err=110,end=120) long,(nop5(i),i=1,long)
      DO i=1,nelem
        indic = indic +1
        ncge  = nop5(indic)
        indic = indic +1
        nmae  = nop5(indic)
        indic = indic +1
        ndsde = nop5(indic)
        indic = indic +1
        nno   = nop5(indic)
! NNO : NOMBRE DE NOEUDS PAR ELEMENT
        IF ( (nno.EQ.4.AND.mesh.NE.2) .OR. (nno.EQ.3.AND.mesh.NE.3) )
     &  THEN
          WRITE(lu,4000)
          CALL plante(1)
          stop
        ENDIF
        DO k=1,nno
          indic = indic +1
          ikle(i,k) = nop5(indic)
        ENDDO
        IF (ncopnp.NE.1) THEN
          indic = indic +1
          npo = nop5(indic)
          DO k=1,npo
            indic = indic +1
          ENDDO
        ENDIF
!  NMAE :
        IF (nmae.NE.0) THEN
          indic = indic +1
          ining = nop5(indic)
          DO k=2,nmae
            IF (ining.EQ.3) THEN
              indic = indic +1
              ncolor(ikle(i,k-1)) = nop5(indic)
            ELSE IF(ining.EQ.2) THEN
              indic = indic +1
              IF (k.GT.nno+1) ncolor(ikle(i,k-(nno+1))) = nop5(indic)
            ELSE IF(ining.EQ.1) THEN
              indic = indic +1
              IF (k.GT.2*nno+1)
     &        ncolor(ikle(i,k-(2*nno+1))) = nop5(indic)
            ENDIF
          ENDDO
        ENDIF
      ENDDO !I
!
      GOTO 80
!
 110  CONTINUE
      WRITE(lu,4100)
 120  CONTINUE
      WRITE(lu,4200)
!
 80   CONTINUE
!
!=======================================================================
!
      DEALLOCATE (x1)
      DEALLOCATE (y1)
!
!=======================================================================
!
4000  FORMAT(//,'*********************************************',/,
     &          'LECSIM : THERE IS NO LINK BETWEEN THE NUMBER  ',/,
     &          'OF POINTS BY ELEMENT AND THE TYPE OF ELEMENTS ',/,
     &          '**********************************************',//)
4100  FORMAT(//,'**********************************************',/,
     &          'LECSIM : ERROR IN READING FILE SIMAIL         ',/,
     &          '**********************************************',//)
4200  FORMAT(//,'*************************************************',/,
     &          'LECSIM : ATTEMPT TO READ AFTER END OF FILE SIMAIL ',/,
     &          '*************************************************',//)
!
      RETURN
      END